terse

我来个  补齐字符方法   效率不怎么样

@echo off&setlocal enabledelayedexpansion
for /f "tokens=*" %%i in (1.txt) do call :lp %%i
for /l %%i in (1 1 %t%) do for /l %%j in (1 1 !%%il!) do set "%%iv=!%%iv! "
for /f "tokens=*" %%i in (1.txt) do call :lp0 %%i
pause&exit
:lp0
set/a n+=1
    if "%1"=="" set n=& echo %str1%&set str1=&goto :eof
    set "str=%1!%n%v!"
    call set "str1=%str1%%%str:~,!%n%l!%%"
shift
goto lp0
:lp
set/a n+=1
if not defined %n%l set %n%l=0
    if "%1"=="" set n=&goto :eof
    for /f "skip=1 delims=:" %%i in ('^(echo %1^&echo.^)^|findstr /o ".*"') do set m=%%i
    set t=%n%
    if %m% gtr !%n%l! set %n%l=%m%
shift
goto lp
复制代码

523066680

我稍微换一下思路，应该说是尽量的通用了……如果某文本太过畸形 那也是没办法的事了……
文本内容更新为：

111111111111111111111                                      98912 张三
222222222222222222    150020 李四四
  333333333333333333333    360000 王五
4444444444444444444321542365445432453243243423432   11111143242342332 赵六六
  555555555555555555    222 田七
666666666666666666666    999999                                   舞吧
复制代码

@echo off
mode con cols=100 lines=20
setlocal enabledelayedexpansion
for /l %%a in (1,1,80) do set kong= !kong!
for /f "eol= tokens=1,2,3" %%a in ('type 1.txt') do (
set lie1-2=%%a%%b%kong%
set lie1-2=!lie1-2:~0,80!
set lie1-2=%%a!lie1-2:%%a%%b=!%%b
echo,!lie1-2!   %%c
)
pause
复制代码

原理：例如文本内容为：
ab******1*d
abc*************2********e
用for获得前面的两列
直接组合 则免去了中间的空格：
ab1
abc2
直接加上80个空格
ab1***************************……
abc2***************************……
然后保存前80位。
ab1*********……***
abc2********……***
把空格前移
ab*********……***1
abc********……***2
这样前面的就基本对齐了。后面的第三列 就不用说了…
我觉得应该可以了……至少我自己用不上太通用的，这个代码自己也没有当工具用过




忽忽……加了中文 或者字符……就被淘汰了……

[ 本帖最后由 523066680 于 2008-8-12 15:49 编辑 ]

523066680

@echo off
setlocal enabledelayedexpansion
set a=0
for /f "eol= tokens=1,2,3" %%a in ('type 1.txt') do (
set /a a+=1
set "lie1=%%a                                      "
set lie1=!lie1:~0,30!
set "lie2=%%b                                      "
set lie2=!lie2:~0,20!
echo,!lie1!!lie2:%%b=!%%b  %%c
)
pause
复制代码

more

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2*" %%a in ('type temp.txt') do (
   set "mo=%%a"&set "niu=%%b"&set "m=0"&set "n=0"&set "very="
   call :ming0 %%a %%b %%c
)
echo.&pause&exit
:ming0
if not "!mo:~%m%,1!"=="" (set "momo=!mo:~%m%,1!"&set /a "m+=1"&goto :ming0)
:ming1
if not "!niu:~%n%,1!"=="" (set "niuniu=!niu:~%n%,1!"&set /a "n+=1"&goto :ming1)
set /a "ming=30-%m%-%n%"
for /l %%i in (1 1 %ming%) do set "very=!very! "
echo %1 %very% %2 %3
复制代码

namejm

　　默认情况下，一个tab键产生的空格相当于8个空格键产生的空格，如果字符串少于8个字符，则一个tab键就足够排版；如果多于8个字符，那么，一个tab键就没法排版了，需要增加tab键的个数，以保证tab键产生的空格个数多于字符串长度。

浅默

使用tab键的都有哪些条件呢?11楼的测试文件不能成功,如果两行差距太大也不成功.

batman

原帖由 风行者 于 2008-7-26 20:03 发表
@echo off & setlocal enabledelayedexpansion
for /f "tokens=1-3 delims= " %%a in (1.txt) do (
set /a n+=1
if !n!==1 echo %%a      %%b   %%c
if !n!==2 echo %%a         %%b  %%c
if !n!==3 echo %%a   ...

这种解法的确是太可爱了，100%的就题解题!

pusofalse

可以直接这样。。
echo 111111111111111111111      98912 张三
echo 222222222222222222        150020 李四四
echo 333333333333333333333     360000 王五
...
...
加分鼓励！一同进步！

风行者

@echo off & setlocal enabledelayedexpansion
for /f "tokens=1-3 delims= " %%a in (1.txt) do (
set /a n+=1
if !n!==1 echo %%a      %%b   %%c
if !n!==2 echo %%a         %%b  %%c
if !n!==3 echo %%a      %%b  %%c
if !n!==4 echo %%a         %%b    %%c
if !n!==5 echo %%a         %%b     %%c
if !n!==6 echo %%a      %%b  %%c
)
pause
复制代码

batman

原帖由 fastslz 于 2008-7-26 18:35 发表
是论坛字符问题
方法其实很简单call标签删除前面及后面的空格字符，替换空格字符为Tab键字符set "str=%str: =这里是Tab键字符%"
附上附件

使用制表符是默认的左对齐分列，主要用来从文本向excel中导数据。

batman

个人认为如本题要充分考虑代码通用性的话，就会是一个相当复杂的过程，
于是，就题解题：

@echo off&setlocal enabledelayedexpansion
set "kong=           "
for /f "delims=" %%a in (1.txt) do (
    for %%i in (%%a) do (
        set "str=%%i"&set /a n+=1
        if !n! equ 2 (
           set "str=%kong%!str!"
           set /p=!str:~-10! <nul
           ) else (
           set "str=!str!%kong%"
           set /p=!str:~,20! <nul
    ))
    set "n=0"&echo.
)
pause>nul
复制代码

pusofalse

原帖由 fastslz 于 2008-7-26 18:35 发表
是论坛字符问题
方法其实很简单call标签删除前面及后面的空格字符，替换空格字符为Tab键字符set "str=%str: =这里是Tab键字符%"
附上附件

测试文本：

1111111    aaaaaaaaaaaa 张三
222222sdf222222222222    150020 李四四
  3333333sfd33333333333333    0 王五
44444444444aa4444444    2332 赵sdfafa六六
  555555555    222 田七
666666666666666666666asaaaaaaaaa    9999999999999 舞
复制代码

fastslz

是论坛字符问题
方法其实很简单call标签删除前面及后面的空格字符，替换空格字符为Tab键字符set "str=%str: =这里是Tab键字符%"
附上附件

pusofalse

原帖由 fastslz 于 2008-7-26 18:11 发表
这个是潜规则默认排版方式
@echo off
for /f "delims=*" %%a in (1.txt) do call :xxx %%a
pause&exit

:xxx
    set "str=%*"
    set "str=%str: =        %"
    echo.%str%
goto:eof

第一次看到如此的方法，还没弄明白怎么回事，在我电脑上测试着不正确。但仍旧学习了！~

fastslz

这个是潜规则默认排版方式

@echo off
for /f "delims=*" %%a in (1.txt) do call :xxx %%a
pause&exit

:xxx
    set "str=%*"
    REM 注意：等号左侧是制表符
    set "str=%str: =	%"
    echo.%str%
goto:eof
复制代码