terse

刚在联盟那边贴了
和batman 兄的代码比较还是不够精炼
本不想贴了但还是献个丑哦
我看到  if %p% equ 0 就可结束  更改下

@echo off&setlocal enabledelayedexpansion
set/p p=输入阶数:
set/a n+=1,o=p
:lp
    set/a b+=2
    for /l %%i in (%n% 1 %p%) do set/a a+=1&set %n%%%i=!a!
    set/a n+=1
    for /l %%i in (%n% 1 %p%) do set/a a+=1&set %%i%p%=!a!
    set/a m=p-1,t+=1
    for /l %%i in (%m% -1 %t%) do set/a a+=1&set %p%%%i=!a!
    set/a p-=1,s+=1
    for /l %%i in (%p% -1 %n%) do set/a a+=1&set %%i%s%=!a!
    if %b% gtr %o% (
    for /l %%i in (1 1 %o%) do (
    for /l %%j in (1 1 %o%) do if !%%i%%j! lss 10 (set /p = !%%i%%j! <nul)else set /p =!%%i%%j! <nul
    echo.)
    pause>nul)else goto lp
复制代码

[ 本帖最后由 terse 于 2008-8-29 02:21 编辑 ]

batman

&&看来螺旋矩阵确实难住了众位新手，同时高手们都不肯冒然出手，
所以只有本人来抛砖引玉了：
----------------------------------------------------------------------------------
首先做下解题说明：
     其实解此题的关键是在找规律，这个螺旋矩阵最大的规律就是在
行、列值的递增递减上，我们就将x变量设为行将y变量设为列，于是
一个y+ x+ y- x-的循环呈现在我们面前，而同时从上一步跳到下一步
的临界值也在变化，不难看出这是个递减的变化，所以只要我们掌握
了以上两点规律，解题的思路便会清晰起来：

@echo off&setlocal enabledelayedexpansion
set /p var=请输入螺旋阵级数(9级内)：
set /a x=1,y=1,total=var*var,tt=1,n=0,m=1,num=var+1
:begin
set /a num-=1,n+=1,m+=1
set "s=y+x+y-x-"&set "ss=%num%%num%%n%%m%"&set "gl=lsslssgtrgtr"
:again
set /a %s:~,2%=1,tt+=1
if %tt% lss 10 set "tt= %tt%"
if not defined _%x%%y% set "_%x%%y%=%tt%"
if !%s:~,1%! %gl:~,3% %ss:~,1% goto again
set "s=%s:~2%"&set "ss=%ss:~1%"&set "gl=%gl:~3%"
if defined s goto again
if %tt% lss %total% goto begin
set "_11= 1"
for /l %%a in (1,1,%var%) do (
    for /l %%i in (1,1,%var%) do (
        set /p=!_%%a%%i! <NUL
    )
    echo.
)
pause>nul
复制代码

ps:期望各位高手贴出更完美的方案。
----------------------------------------------------------------------------------

yslyxqysl

 
@echo off
setlocal ENABLEDELAYEDEXPANSION
:input
set /p num=请输入：
for /l %%i in (1 1 %num%) do (
for /l %%p in (1 1 %num%) do (
set /a tempnum+=1
if !tempnum! lss 10 set /p tp= <nul
set /p tp=!tempnum! <nul
)
echo.
)
pause
goto input
复制代码

[ 本帖最后由 yslyxqysl 于 2008-8-29 18:43 编辑 ]

batman

原帖由 pusofalse 于 2008-8-28 16:52 发表
4　set /a 可以如此连写：set /a a+=1,b+=a,c+=b　，当然前提是开启了变量延迟
不必开启变量延迟啊，set/a 的特性就是这样。

多谢指正，已修改。

pusofalse

4　set /a 可以如此连写：set /a a+=1,b+=a,c+=b　，当然前提是开启了变量延迟
复制代码

不必开启变量延迟啊，set/a 的特性就是这样。

shqf

哦，以为想得很周全了，竟仍还有好多问题。领教了，谢谢。

batman

原帖由 shqf 于 2008-8-28 12:40 发表
batman给我加分，受鼓励，前6步精简了二行代码，再贴出第7步我的解法（第8步实在无从下手了）：@echo off&setlocal enabledelayedexpansion
set ji=1
set /p n=请输入数字（1-9）

for /l %%i in (1,1,%n%) do  ...

有几个问题：
1　这是个小问题，一直显示的是4行4列
2　数例没有完全对齐，原因在没有对小于10的数进行处理
3　代码书写不规范，切不可以为将代码挤在一堆就是简洁了，这样大大降低了代码的可读性
4　set /a 可以如此连写：set /a a+=1,b+=a,c+=b

[ 本帖最后由 batman 于 2008-8-28 17:05 编辑 ]

batman

楼上确实将代码进一步进行了简化，但变量个数还是一样的吧，少了个v多了个mod。

pusofalse

for 的/l产生的就是现有的数列，不必再在for里面set/a v+=1

@echo off&setlocal enabledelayedexpansion
set/p n=输入：
set/a m=n*n
for /l %%a in (1 1 %m%) do (
     set/a mod=%%a%%n
     if %%a lss 10 (set/p= %%a <nul) else set/p=%%a <nul
     if !mod! equ 0 echo.
)
pause>nul
复制代码

[ 本帖最后由 pusofalse 于 2008-8-28 14:13 编辑 ]

shqf

batman给我加分，受鼓励，前6步精简了二行代码，再贴出第7步我的解法（第8步实在无从下手了）：

@echo off&setlocal enabledelayedexpansion 
set ji=1
set /p n=请输入数字（1-9）

for /l %%i in (1,1,%n%) do (
set /a he+=%%i
set /a ji*=%%i
set /a pf=%%i*%%i&set /a pfh+=!pf!
set /a lf=!pf!*%%i&set /a lfh+=!lf!
)

echo %n%的平方：%pf%
echo %n%的平方：%lf%
echo 从1到%n%的和：%he%
echo 从1到%n%的积：%ji%
echo 从1到%n%的平方和：%pfh%
echo 从1到%n%的立方和：%lfh%
echo 4行4列的数列：
for /l %%i in (1,1,%n%) do (
        for /l %%j in (1,1,%n%) do (set /a ij=%%i*%n%-%n%+%%j&set /p=!ij! <nul)
        echo.
)

pause>nul
复制代码

[ 本帖最后由 shqf 于 2008-8-28 12:49 编辑 ]

batman

@echo off&setlocal enabledelayedexpansion
set /p n=请输入数字（1-9）
set /a nn=n*n
for /l %%i in (1,1,%nn%) do (
     set "a=%%i"&set /a v+=1
     if !a! lss 10 set "a= !a!"
     set /p=!a! <nul
     if !v! equ %n% set "v=0"&echo.
)
pause>nul
复制代码

还可减少一个变量：

@echo off&setlocal enabledelayedexpansion
set /p n=请输入数字（1-9）
set /a nn=n*n
for /l %%i in (1,1,%nn%) do (
     set /a v+=1
     if %%i lss 10 (
        set /p= %%i <nul
        ) else (
        set /p=%%i <nul
     )
     if !v! equ %n% set "v=0"&echo.
)
pause>nul
复制代码

[ 本帖最后由 batman 于 2008-8-28 10:31 编辑 ]

batman

建议楼上用for来简化代码。。。

mkl

第7题

@echo off
set /p n=请输入数字（1-9）
set s=%n% &set nn=0 &set v=1
:jj
set /a nn=%nn%+1
set "mn= %nn%"
set /p=%mn:~-2% <nul
if %nn% lss %s% goto jj
echo.
set /a s=%s%+%n%
set /a v=v+1
if %v% leq %n% goto jj
pause>nul
复制代码

shqf

前6题如下（后2题明日有空再想想）：

@echo off&setlocal enabledelayedexpansion 
set ji=1
set /p n=请输入数字（1-9）
set /a pf=%n%*%n%
set /a lf=%pf%*%n%
for /l %%i in (1,1,%n%) do (
set /a he+=%%i
set /a ji*=%%i
set /a pfh_pf=%%i*%%i&set /a pfh+=!pfh_pf!
set /a lfh_lf=!pfh_pf!*%%i&set /a lfh+=!lfh_lf!
)
echo %n%的平方：%pf%
echo %n%的平方：%lf%
echo 从1到%n%的和：%he%
echo 从1到%n%的积：%ji%
echo 从1到%n%的平方和：%pfh%
echo 从1到%n%的立方和：%lfh%

pause>nul
复制代码

[ 本帖最后由 shqf 于 2008-8-27 22:25 编辑 ]

mkl

前6题

@echo off
set /p n=请输入数字（1-9）
set /a p=%n%*%n%
set /a pp=%p%*%n%
set o=0 &set oo=1 &set m=0 &set mm=0
set a=1
:jj
set /a o=%o%+%a%
set /a oo=%oo%*%a%
set /a c=%a%*%a%
set /a cc=%a%*%a%*%a%
set /a m=%m%+%c%
set /a mm=%mm%+%cc%
if not %a%==%n% set /a a+=1 &goto jj
echo %n%的平方：%p%
echo %n%的平方：%pp%
echo 从1到%n%的和：%o%
echo 从1到%n%的积：%oo%
echo 从1到%n%的平方和：%m%
echo 从1到%n%的立方和：%mm%
pause>nul
复制代码