novaa

N长，哈哈
不过人性化，
功能足
很不错的啊
向版主学习！

随风

::知道这个原理就好办了。
::    但又要人性化，又要简洁，只怕有点难度。。。。
::         哈哈…… 代码 N 长…………

@echo off&color 0f&title 网址 屏蔽/解除屏蔽
:: by 小楼一夜听春雨 2007-11-25
set wjm=C:\WINDOWS\system32\drivers\etc
set "str=127.0.0.1       "&set "kg=                   "
set "tisi=echo\&echo %kg%注： 此操作需要经过杀毒软件的同意。"
set "tisi2=echo %kg%=================================="
set "yip=以下是已经被屏蔽的网址&echo ======================&echo\"
set "npb=目前没有被屏蔽的网址。&echo ======================&echo\&echo\&echo\"
set "tisi=%tisi%&%tisi2%&echo\&echo\"
:loop
setlocal EnableDelayedExpansion
call :xiansi
echo\&echo 请选择 ｛ 1 屏蔽网址 ｝ ｛ 2 解除屏蔽 ｝ ｛ 3 全部解除屏蔽 ｝&echo\
set /p xuan=请选择 [ 1，2，3 ] 
if "%xuan%"=="" (set xuan=a) else set xuan=%xuan:"=%
if "%xuan%"=="1" goto jia
if "%xuan%"=="2" goto _jiecu
if "%xuan%"=="3" set pinbi3=y&goto _jiecu
call :cuowu
endlocal
goto loop
:_jiecu
cls&call :xiansi
if defined pinbi3 (
   for /l %%a in (1 1 %num%) do set wz=!wz! %%a
   goto jiecu
)
echo\&echo 输入已经屏蔽的网址前面的序号，解除屏蔽相应的网址。
echo\&echo 解除屏蔽,可一次输入多个序号，用空格分开。
echo\&echo 如：1 2 5 10 （即：解除1、2、5、10）
echo\&echo 按“回车键”或“点关闭按钮”退出。。。&echo\
set /p wz=请输入序号：
if "!wz!"=="" exit
set pand=!wz: =!
echo !pand!|findstr "^[0-9].*$"&&goto jiecu
call :cuowu
endlocal
goto loop
:jiecu
attrib -r %wjm%\hosts
color 1f
for /f "delims=" %%a in (%wjm%\hosts) do (
   set pin=
   for %%i in (%wz%) do if "%%a"=="!str!!%%i!" set pin=a
   if not defined pin echo %%a>>%wjm%\hosts1
)
set wz=&set "pinbi3="
del/q %wjm%\hosts
ren %wjm%\hosts1 hosts
del/q %wjm%\hosts1
attrib +r %wjm%\hosts
cls&echo\&echo 解除屏蔽成功。。。
endlocal
goto loop
:jia
cls&%tisi%
echo\&echo 请输入需要“屏蔽”的“单个”网址。
echo\&echo 或 先在“某文档”里输入所有要屏蔽的网址，一行一个。
echo\&echo 再在这里输入 “文档名” （含全路径和后缀名）
echo\&echo 或将此文档拖放到此，可批量添加。
echo\&echo 按“回车键”或“点关闭按钮”退出。。。&echo\
set /p wdm=请输入文档名或网址：
set wdm=%wdm:"=%
if "%wdm%"=="" exit
set wdm="%wdm%"
if exist %wdm% (set "wdm=type %wdm%") else (set "wdm=echo %wdm%")
attrib -r %wjm%\hosts
for /f "delims=" %%a in ('%wdm%') do (
   color cf&echo !str!%%a>>%wjm%\hosts
)
attrib +r %wjm%\hosts
cls&echo\&echo 屏蔽成功。。。
endlocal
goto loop
:xiansi
set you=&set xs=&set num=
for /f "tokens=1* delims= " %%a in (%wjm%\hosts) do (
   if "%%a"=="127.0.0.1" set /a xs+=1
   if !xs! geq 2 (
     if !xs! equ 2  %tisi%&echo %yip%&set you=a
     set /a num+=1
     set !num!=%%b&echo ^(!num!^) %%b
))
echo\
if not defined you %tisi%&echo %npb%
goto :eof
:cuowu
cls&echo\&echo  你的输入错误，请重新输入。。。&echo\
goto :eof
复制代码

[ 本帖最后由 随风 于 2007-11-29 07:19 编辑 ]

novaa

哈哈
发现我写的好马虎
格式排版的也不好
本来想用CHOICE选择的，但是别人告诉，XP没有命令，。。。

novaa

可能部分人不知道原理，
我先简单的说下
大家可以打开hosts文件看看（在C:\WINDOWS\system32\drivers\etc里面），如下

# Copyright (c) 1993-1999 Microsoft Corp.
#
# This is a sample HOSTS file used by Microsoft TCP/IP for Windows.
#
# This file contains the mappings of IP addresses to host names. Each
# entry should be kept on an individual line. The IP address should
# be placed in the first column followed by the corresponding host name.
# The IP address and the host name should be separated by at least one
# space.
#
# Additionally, comments (such as these) may be inserted on individual
# lines or following the machine name denoted by a '#' symbol.
#
# For example:
#
# 102.54.94.97 rhino.acme.com # source server
# 38.25.63.10 x.acme.com # x client host

127.0.0.1 localhost
复制代码

只要在最后一行后面加上
127.0.0.1       你想屏蔽的网址    （注意:有7个空格）      
就打不开了（对原理感兴趣的自己BAIDU下）
下面是我写的

@echo off&setlocal enabledelayedexpansion
:kaishi
echo.
echo.
echo.
echo.
echo 添加网址过滤请输入1;解除网址屏蔽请输入2;退出请按0;
set /p scanf=
if !scanf!==1 goto :pb else ( 
if !scanf!==2 goto:jc else 
goto :end)
:pb 
set /p str=请输入你想屏蔽的网址:
echo 127.0.0.1 !str!>>C:\WINDOWS\system32\drivers\etc\hosts
echo 网址!str!已经成功屏蔽!
pause & cls & goto :kaishi

:jc
set /p str=请输入你想解除屏蔽的网址:
for /f "delims=" %%a in (C:\WINDOWS\system32\drivers\etc\hosts) do echo %%a | findstr /v "!str!">>C:\WINDOWS\system32\drivers\etc\hosts1
del C:\WINDOWS\system32\drivers\etc\hosts /q
ren C:\WINDOWS\system32\drivers\etc\hosts1 hosts
pause & cls & goto :kaishi

:end
exit
复制代码

[ 本帖最后由 novaa 于 2007-11-25 18:58 编辑 ]