pusofalse

sorry，刚刚脑子短路了。。。
因为我的代码是先获取一个yyyymmdd格式的标准格式的日期（所谓标准，即是别的机子上也是如此），所以没有考虑太过关于日/年/月格式该如何区分日、月的问题就说了出来。
依次看来，随风兄的代码算得上完美代码了，期待更多好代码的出现。

terse

用个临时文件取日期

@echo off
set n=-1&set m=+1
echo wscript.echo date>tmp.vbs
for /f "tokens=1,2,3* delims=-" %%i in ('cscript /nologo tmp.vbs^&del tmp.vbs') do set "ymda=10%%k 10%%i 10%%j"
:lp
echo wscript.echo dateadd("d",%n%,date)>tmp.vbs
for /f "tokens=1,2,3* delims=-" %%i in ('cscript /nologo tmp.vbs^&del tmp.vbs') do set "ymdb=10%%k 10%%i 10%%j"
for  %%i in (%ymda%) do set %%i=%%i
for  %%i in (%ymdb%) do if %%i gtr 1031 (set yyyy=%%i)else (
if not defined %%i (set/a dd=%%i%m%,t+=2)else set mm=%%i)
)
if %t% gtr 3 set n=+1&set t=&set m=-1&goto lp
   set yyyy=%yyyy:~-4%
   set mm=%mm:~-2%
   set dd=%dd:~-2%
   set .y=%yyyy%
   set .m=%mm%
   set .d=%dd%
   set/p str=请输入:
   setlocal enabledelayedexpansion
:lp1
   set v=!str:~,1!
     if not defined .%v% (
       if not defined var (set var=!v!)else set var=!var!!v!
        ) else (
          call set var=!var!%%.%v%:~!_%v%!,1%%
          set/a _!v!+=1
)
set str=!str:~1!
if defined str goto lp1
echo !var!
pause
复制代码

随风

10/2008/10
这样的话，哪个是月哪个是日呢？
这个是必须知道的前提啊？

pusofalse

是的。%date%的值是日/年/月这样格式的日期我也没见过，只是个人意见而已。不管格式怎样，即使千变万化也能正确输出才能谓之完美。

随风

那样就无法判断 月和日 了啊？

pusofalse

回复楼上的兄弟。八个字母的排列方式太多了。
我有可能输入 ym-ym-dydy，抑或m/-yydy/myd。。。

shqf

@echo off
reg export "HKEY_CURRENT_USER\Control Panel\International" 1.reg >nul
reg add "HKEY_CURRENT_USER\Control Panel\International" /f /v sShortDate /d "yyyy-MM-dd" >nul

:shuchu
set /p rqgs=请输入日期格式(按q退出):
if "%rqgs%"=="mm dd yyyy" echo %date:~5,2% %date:~8,2% %date:~0,4%
if "%rqgs%"=="yyyy/mm/dd" echo %date:~0,4%/%date:~5,2%/%date:~8,2%
if "%rqgs%"=="mm-dd/yyyy" echo %date:~5,2%-%date:~8,2%/%date:~0,4%
if "%rqgs%"=="md-md-yyyy" echo %date:~5,1%%date:~8,1%-%date:~6,1%%date:~9,1%-%date:~0,4%
if "%rqgs%"=="ymydymyd" echo %date:~0,1%%date:~5,1%%date:~1,1%%date:~8,1%%date:~2,1%%date:~6,1%%date:~3,1%%date:~9,1%
if "%rqgs%"=="ydmydm-yy" echo %date:~0,1%%date:~8,1%%date:~5,1%%date:~1,1%%date:~9,1%%date:~6,1%-%date:~2,1%%date:~3,1%
if "%rqgs%"=="dd---/m/m/ y y y y" echo %date:~8,2%---/%date:~5,1%/%date:~6,1%/ %date:~0,1% %date:~1,1% %date:~2,1% %date:~3,1%
echo.
if /i not "%rqgs%"=="q" goto shuchu
reg import 1.reg>nul
echo OK&pause>nul
exit
复制代码

pusofalse

是的 现在可以了！
不过如果%date%的格式是这样的呢：
月/年/日。 日/年/月。 年/日/月。
。。。而不只是年/月/日 或 月/日/年。
或许也没有这样的日期格式。。。

随风

以发现，你再试试？

pusofalse

如果%date%是这样的格式就会出错：
10/21/2008 Tue
输入yyyy mm dd，输出10~0,1~ 21 20，本该是2008 10 21。

随风

看似一个简单的问题，居然也要这么长的代码。。。
:

@echo off&setlocal enabledelayedexpansion
set /p var=请输入: 
set .y=a&set .m=a&set .d=a&set h=ymd
for /l %%a in (0 1 9) do set .%%a=a
for %%i in (%date%) do (
   set str=%%i&set "str=!str:~0,1!"
   if defined .!str! (
      for /f "tokens=1-3 delims=/\,.-: " %%a in ("%%i") do (
      set str=%%a&set str=!str:~2,1!
      if not defined .!str! set h=mdy
      set !h:~0,1!=%%a&set !h:~1,1!=%%b&set "!h:~2,1!=%%c"
)))
:loop
set n=%var:~0,1%
if defined .%n% (
   set num=!num!!%n%:~0,1!
   set "%n%=!%n%:~1!"
) else set "num=%num%%n%"
set "var=%var:~1%"
if defined var goto loop
echo\&echo %num%
pause>nul
复制代码

[ 本帖最后由 随风 于 2008-10-21 21:43 编辑 ]

pusofalse

回复terse前辈，可以这样理解。
但不必非要从%date%中读取日期，也可以用其他的方法，比如读取注册表提取当前日期。。。方法不限，只是不能借助第三方工具。

[ 本帖最后由 pusofalse 于 2008-10-21 21:14 编辑 ]

terse

原帖由 pusofalse 于 2008-10-21 20:24 发表
未知%date%的格式。

第一个01当然是mm，第二个当然是dd。
如果是2008-01-01、2000-12-12这样的日期，输入mmddyyyy虽然同ddmmyyyy是一样的结果，都是01012008、12122000，但第一个01确实是月份。ddmmyyyy格式的01 ...

还是有疑惑的
我的意思的 如果 %date%的值是 2008-01-01 那么两个01要自己判断哪个是DD 哪个是MM  是这样吗？
也可以这样说 2008-01-01 第一个01 可以是 dd 也可以是mm 因为各电脑的日期格式不一，所以要代码自己判断了
这样理解对吗

pusofalse

这样的格式：
星期二 2008-10-21
2008-10-21 星期二
10/21/2008 Tue
Tue 10/21/2008
只考虑用4位数表示年份，暂时不必考虑用两位数表示的年份。

随风

未知%date%的格式。
有可能是 10-21-2008 或 10-21-08 这样的格式吗？