BS0小陈

@echo off
setlocal enabledelayedexpansion
set "nn=qQ wW eE rR tT yY uU iI oO pP aA sS dD fF gG hH jJ kK lL zZ xX cC vV bB nN mM"
set "a=123a,B"
                                                                                    
:a
set aa=!a:~0,1!
set aaa=!a:~1!
for %%a in (!nn!) do (
set n=%%a
set n1=!n:~0,1!
set n2=!n:~1,1!
if "!aa!"=="!n1!" (
set /p=!n2!<nul) else (
if "!aa!"=="!n2!" (
set /p=!n1!<nul) else (set /p=!aa!<nul)
)
set a=!aaa!
pause>nul
if "a"=="" goto :end
goto :a
)
:end
pause
复制代码

为什么出问题了！！！！

mxxcgzxxx

没事来个好玩的

@echo off
setlocal enabledelayedexpansion
set str=aAbBcCdDeEfFgGhHiIjJkKlLmMnNoOpPqQrRsStTuUvVwWxXyYzZ
:1
set/p p=
echo %p%|findstr "--[a-Z]--">nul&&echo 大哥没事写神马多减号嘛！重写！ && ghoto :1
set a=26
:2
set /a a-=1
set b=!str:~%a%,1!
set "p=!p:%b%=--%b%--!"
set /a a-=1
set c=!str:~%a%,1!
set "p=!p:%c%=%b%!"
set "p=!p:--%b%--=%c%!"
if %a%==0 goto :3
goto :2
:3
echo %p%
pause
复制代码

CrLf

另一种逐字替换，兼容各种可见的特殊字符，调用 ascmap 后可以支持汉字：

@echo off
set "字符串=WwW.baThOME.net"
set 字
setlocal enabledelayedexpansion
set<nul>tmp /p=@!字符串!
(for %%a in (tmp) do (
	for /l %%b in (1 2 %%~za) do echo;
))>k

set str=@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@!"#$%%&'()*+,-./0123456789:;<=>?@abcdefghijklmnopqrstuvwxyz[\]^_`ABCDEFGHIJKLMNOPQRSTUVWXYZ{|}~
for /f "skip=2 tokens=1,3" %%a in ('fc /b k tmp') do if "%%a" lss "1" set 结 果 =!结 果 !!str:~0x%%b,1!

set 结
del tmp k
pause
复制代码

batman

vbs:

Dim inpStr, Arr, Str
inpStr = InputBox("请输入要转换的字符串")
Arr = split("a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z", ",")
For Each Str In Arr
  inpStr = Replace(inpStr, Str,"@#$&")
  inpStr = Replace(inpStr, UCase(Str), Str)
  inpStr = Replace(inpStr, "@#$&", UCase(str))
Next
MsgBox inpStr
复制代码

CrLf

用 choice 的思路，不通用、不高效、不简洁、不考虑字符的兼容性：

aAcebFaJad
cls
@echo off&setlocal enabledelayedexpansion
set str=#ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz1234567890
set /p 字符串=<%0
set 字
call :strlen 字符串
(for /l %%a in (1 1 !len!) do (
choice /cs /c abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890 /n>nul
for %%b in (!errorlevel!) do set 结 果 =!结 果 !!str:~%%b,1!
))<%0
set 结
pause

:strlen
setlocal enabledelayedexpansion
set "$=!%1!#"
set len=&for %%a in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1)do if !$:~%%a^,1!. NEQ . set/a len+=%%a&set $=!$:~%%a!
endlocal&If %2. neq . (set/a%2=%len%)else set len=%len%
复制代码

Taurus

試一試...

@echo off&setlocal enabledelayedexpansion&set nub=0
set "s=a b c d e f g h i j k l m n o p q r s t u v w x y z"
set "b=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"
for %%i in (!s!) do set/a num+=1&set %%i1=%%i
for %%i in (!b!) do set/a num2+=1&set %%i2=%%i
set /p "str=string= *"
:lp
call set str=%%str:~!nub!%%
for %%i in (!b!) do if "!str:~0,1!"=="%%i" call set "OK=!OK!%%!str:~0,1!1%%"&goto ut
for %%i in (!s!) do if "!str:~0,1!"=="%%i" call set "OK=!OK!%%!str:~0,1!2%%"&goto :out
if not "!str!"=="" (set "ok=!ok!!str:~0,1!") else (goto :end)
:out
set nub=1
goto :lp
:end
echo string= *!OK!
pause>nul

netbenton

re zqz0012005
48楼又经修改，增加了以下特殊符号的处理：
^ ; !

效率可是很高的了
确实是只有exit强行退出，还没想到其它办法来做到一个预处理全部完成的，只好用它了。

zqz0012005

不要忘了 for /f 的 eol 隐患，呵呵。

for /l 无限循环由于运行机制，其实不太实用。必须用 exit 强制退出整个bat，exit /b 或 goto 都不行。

netbenton

支持各种特殊情况
包括：

^ < > " ; ^ & * = ：~ |
复制代码

等符号

 @echo off&setlocal enabledelayedexpansion
for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do set @D%%a=%%a
for %%a in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do set @x%%a=%%a
set /p in=输入一个大小写都的有字符串：
set n=0
set out=
for /l %%a in (0) do (
for %%n in (!n!) do (
  for /f "delims=" %%b in ("!in:~%%n,1!") do (
   if defined @d%%b (
    if %%b equ !@D%%b! (set out=!out!!@x%%b!) else (set out=!out!!@D%%b!)
   ) else (
    set out=!out!^^%%b
   )
  set /a n+=1
  )
  if "!in:~%%n,1!" equ ";" set out=!out!;&set/a n+=1
  if %%n equ !n! echo;大小写互换为：!out!&PAUSE&exit
)
)
复制代码

[ 本帖最后由 netbenton 于 2009-11-14 19:32 编辑 ]

zqz0012005

嗯，没必要将大小写字母定义在两个变量中。

@echo off
set "letters= abcdefghijklmnopqrstuvwxyzZYXWVUTSRQPONMLKJIHGFEDCBA"
for /l %%a in (1,1,26) do call set /a "_%%letters:~%%a,1%%=%%a"
:input
setlocal EnableDelayedExpansion
echo 请输入:&set /p var=&if not defined var endlocal&goto:input
:loop
set char=!var:~%pi%,1!
set /a sn=_!char! 2>nul||set sn=0
if defined char (
    if %sn% gtr 0 (
        if "!char!"=="!letters:~%sn%,1!" (set str=!str!!letters:~-%sn%,1!) else (set str=!str!!letters:~%sn%,1!)
    ) else (
        set str=!str!!char!
    )
    set /a pi+=1
    goto loop
)
echo=!str!
pause&endlocal&goto input
复制代码

batman

首先设置变量提高点效率：

@echo off&setlocal enabledelayedexpansion
for %%a in (aA bB cC dD eE fF gG hH iI jJ kK lL mM nN oO pP qQ rR sS tT uU vV wW xX yY zZ) do (
    set "code=%%a"&set "#!code:~,1!=!code:~1,1!"&set "_!code:~1,1!=!code:~,1!"
)
set /p str=请输入字符：&echo.&set /p=经转换后：<nul
:lp
if defined _%str:~,1% (
   if "%str:~,1%" equ "!#%str:~,1%!" (
      set /p=!_%str:~,1%!<nul
      ) else (
      set /p=!#%str:~,1%!<nul
   )
   ) else (
   set /p=%str:~,1%<nul
)
set "str=%str:~1%"
if defined str goto lp
pause>nul
复制代码

hhl1987

看一看先……………………

lxzzr

水平有限，想不到更好的办法，呵呵

lxzzr

rem 思路:先定义两个集合：大写和小写，然后逐字符分析。
rem 调换两个变量即可实现小大写互换

@echo off
setlocal enabledelayedexpansion

set temp_a=ABCDEFGHIJKLMNOPQRSTUVWXYZ
set temp_b=abcdefghijklmnopqrstuvwxyz

set /p temp_c=请输入:
echo 转换前:%temp_c%
for /l %%a in (0 1 10000000) do (
set temp_n=!temp_c:~%%a,1!
for /l %%b in (0 1 26) do (
set temp_m=!temp_a:~%%b,1!
if !temp_n! == !temp_m! (
if defined temp_n (
set temp_s=!temp_b:~%%b,1!
call :sub !temp_n! !temp_s!
) else (
echo 转换后:!temp_c!
pause>nul
exit
)
)
)
)
复制代码

随风

此类代码始终摆脱不了逐字判断，效率问题，goto次数等于 字符串个数。
兄的代码不觉得for循环次数比36楼要多些吗？
32、33楼虽用goto跳出for，但其实for循环是不会跳出的，只是停止运行里面的命令罢了。也就是说for循环次数等于字符串个数乘26