betterplayer

回复  betterplayer


    ghost命令即可，另外居然不用网刻
pcl_test 发表于 2015-12-27 02:48

这位兄弟不理解我的意思。
我是需要在教师机上远程让每台学生机执行一个批处理后，自动在启动菜单上增加默认启动到Ghost的选项，以实现重启后自动备份，且备份到本机上。ghost的命令行我已经知道了，但不知道的是如何添加启动选项，以及让它重启后自动能进入Ghost的工作环境里。

不用网克是因为这50台电脑配置有点差别，而且用网克速度不够快。
网克我也不会用。

ygqiang

楼上的各位兄台，我是新手，对于批处理只懂一点点。现在我有个问题想请教。
我管理一个机房，有50台电脑， ...
betterplayer 发表于 2015-12-27 01:25

    不懂，求高手解决。。

pcl_test

回复 12# betterplayer


    ghost命令即可，另外居然不用网刻

betterplayer

楼上的各位兄台，我是新手，对于批处理只懂一点点。现在我有个问题想请教。
我管理一个机房，有50台电脑，现在安装的都是Win7系统。
我在教师机上安装了控制软件（极域电子教室），可以对下面的学生机进行监控等任意操作，也可以让学生机直接运行某个程序。
我现在想作一个批处理放到每台学生机上，在教师机上命令每台学生机运行这个批处理后，每台学生机就能自动像人工点击onekey ghost那样按照我的要求设置好后，重启并转到Ghost进行系统的备份或恢复。

我对编程序不是太懂，所以请求各位的帮助。
现在的问题是：如果使用onekey ghost软件，教师机虽然能远程让学生机运行这个程序，但软件打开后，接下去还需要进行备份或恢复的相关设置，这一些却不能自动处理，需要手动来点了。那样就很麻烦。

有没有办法做一个批处理，运行后能让学生机的启动菜单加一条Ghost选项，且在重启后默认跳到这一条，并自动按设定好的Ghost参数对系统盘（C）进行备份呢？
万分感谢！

ygqiang

windows7的启动菜单项不像XP或2003那样编辑方便，windows7没有boot.ini.虽然可以通过bcdedit编辑和修改，但总感觉不那么方便迅速。为了方便，写了一个批处理用来编辑（包括添加和删除）win7的启动菜单项。

需要注意的是添加的启动菜单项的引导文件名一定不要填错，且文件一定要放到C盘根目录下!

另外，如果你的系统已经直接启用超级管理员（administrator）登录系统了，就不用右键-以管理员身份运行批处理了，直接双击运行即可。win7启用超级管理员（administrator）的方法：在“计算机”上点击鼠标右键选择“管理”，在“系统工具”－“本地用户和组”－“用户”里右键点击“Administrator”，选择属性，把“帐户已禁用”取消，然后退出管理并注销系统，选择Administrator帐户再登录



@echo off
@title 正在编辑bcdedit…By 百味人生http://baivi.com
MODE con COLS=60 LINES=10 &COLOR 0a
setlocal EnableDelayedExpansion
cd c:\windows\system32\
echo.
echo.
set /p name=输入你要添加的启动项名：
set /p path=输入你要添加的启动项的引导文件名：
bcdedit /create /d "%name%" /application bootsector>c:\1.txt
for /f "tokens=2 delims= " %%i in (c:\1.txt) do set dim=%%i

bcdedit /set %dim% device partition=c:
bcdedit /set %dim% path \%path%
bcdedit /displayorder %dim% /addlast

del c:\1.txt
cls
echo.
echo.
echo 正在编辑中，请稍候…
ping /n 4 127.0.0.1>nul 2>nul
cls
echo.
echo 创建了名为"%name%"的启动菜单项
echo.
echo 要删除此启动菜单项请按 1
echo.
echo 保留启动菜单项并退出请按任意键
echo.
echo.



set /p num=输入选项：
if "%num%"=="1" (
goto 1
)
goto 2



:1
bcdedit /delete %dim%>nul
echo 删除完毕！按任意键退出 & pause>nul

:2
set name=
set dim=
set path=
set num=
exit

DAIC

回复 9# ygqiang


    第19行>>左边那个空格是多余的

ygqiang

回复  ygqiang 这样可以避免重复写入
DAIC 发表于 2015-1-8 14:47

    多谢了。。。最终代码。。

@echo off
if "%1" == "h" goto begin
mshta vbscript:createobject("wscript.shell").run("%~fs0 h",0)(window.close)&&exit
:begin
rem 下边开始写批处代码了


set timeout=3
set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"

if exist c:\boot.ini goto ntldr
exit


:ntldr
bootcfg /timeout %timeout% >nul 2>nul
attrib -s -r -h c:\boot.ini

echo. >>c:\boot.ini

findstr /c:"WDOS工具箱" c:\boot.ini >nul || >>c:\boot.ini echo C:\wzldr="WDOS工具箱"
findstr /c:"通用 PE 工具箱" c:\boot.ini >nul || >>c:\boot.ini echo C:\WXPE\PELOAD=通用 PE 工具箱

if not exist c:\WZBOOT "%rar%" x -y "WDOS工具箱.rar" c:\
if not exist c:\PETools "%rar%" x -y "通用 PE 工具箱.rar" c:\

attrib +s +r +h c:\boot.ini

exit
复制代码

DAIC

回复 5# ygqiang

findstr /c:"WDOS工具箱" c:\boot.ini >nul || >>c:\boot.ini echo C:\wzldr="WDOS工具箱"
findstr /c:"通用 PE 工具箱" c:\boot.ini >nul || >>c:\boot.ini echo C:\WXPE\PELOAD=通用 PE 工具箱
复制代码

这样可以避免重复写入

amwfjhh

呵呵，楼上的很严谨啊。
任何一个项目，到具体实施时会发现问题比想象的多得多，为什么一个工作多年的高工会比刚毕业的大学生工资拿得高，就知识结构而言可能不相上下甚至可能现在出来的毕业生涉及的知识面还稍广一些，但论做事刚毕业的绝对跟高工比差上几条街，这就是经验差别，是一个项目一个项目累积起来的修炼成果，这是一个慢慢成长的过程，参与其中，解决问题不正是乐趣所在吗。

yu2n

回复 5# ygqiang
题目太大……还是说说你的BAT吧。
如果你自己忘了安装WinRAR……
如果你自己改了系统盘符，系统盘符不是 C: ，是 %SystemDrive% ……
如果你装了两个XP系统……
……
如果是给用户用呢？

感觉细节很多很烦是吧？感觉什么软件都不是尽善尽美了吧？
~自己喜欢就好。

安装脚本，供参考：

cls&@echo off
title %~n0

::@chcp 950
@echo off
title -- Install Grub4Dos Boot Menu --  [Win XP/2003/NT4]
color 0b
call :_main
:: setlocal enableDelayedExpansion

::  Get Input
goto :eof
:_main
	:: Set Path
	call :_set_path
	cls
	echo.
    echo, Please enter the installation path, the sample is as follows^:
    echo,     Local Drive^:  C^:
    echo,     UNC   Drive^:  \\PC002\C$
	echo.
    set /p "wkDir=Input Work Drive:> "
    if not exist "%wkDir%" 			call :_error_exit  "Work Drive Not Found!"
    if not exist "%wkDir%\windows"  call :_error_exit  "Work Drive Not Found!"
    if not exist "%wkDir%\boot.ini" call :_error_exit  "Work Drive Not Found!"
	
	call :_uninstall
	echo.
	echo,UnIntall Grub4Dos Done^!  ^$_^$
	echo.
	
	set /p "p=> Install Grub4Dos ... " <nul & pause
	call :_install
	echo.
	echo,Install Grub4Dos Done^!  ^^_^^
	echo.
	
	set /p "p=> Install 0pe ... " <nul & pause
	call :_install_0pe
	echo.
	echo,Install 0PE Done^!  ^^_^^
	echo.
	pause
	goto :eof

	
	
	
::  Install
goto :eof
:_install
	if not exist "%wkDir%\boot.ini.bak_g4d" (
		attrib -a -h -r -s  "%wkDir%\boot.ini"
		call :_xcopy  "%wkDir%\boot.ini"  "%wkDir%\boot.ini.bak_g4d"
	)
	call :_xcopy  "%meDir%\boot.ini"  "%wkDir%\boot.ini"
	call :_xcopy  "%meDir%\grldr"  "%wkDir%\grldr"
	call :_xcopy  "%meDir%\boot"  "%wkDir%\boot"
	goto :eof
	

goto :eof
:_install_0pe
	call :_xcopy  "%meDir%\0pe\0PE.ISO"  "%wkDir%\boot\pe\0PE.ISO"
	call :_xcopy  "%meDir%\0pe\0PE.ISO.txt"  "%wkDir%\boot\pe\0PE.ISO.txt"
	goto :eof
	
	
	goto :eof
:_uninstall
	if exist "%wkDir%\boot.ini.bak_g4d" (
		attrib -a -h -r -s  "%wkDir%\boot.ini"
		call :_xcopy  "%wkDir%\boot.ini.bak_g4d"  "%wkDir%\boot.ini"
		del /a /f /q "%wkDir%\boot.ini.bak_g4d"
		attrib +a +h +r +s  "%wkDir%\boot.ini"
	)
	if exist "%wkDir%\grldr"   del /a /f /q "%wkDir%\grldr"
	if exist "%wkDir%\boot"    rd /s /q  "%wkDir%\boot"
	goto :eof
    
    
goto :eof
:_xcopy
  if not exist "%~1" goto :eof
  echo.
  ((pushd "%~1" >nul 2>nul) && (
    echo,[Folder] %~1
    xcopy /d /e /v /c /i /h /r /y /z  "%~1"  "%~2"
    popd
  )) || (
	echo,[File] %~1
    copy /v /y /z  "%~1"  "%~2"
  )
  goto :eof
  
  
rem --set Path
goto :eof
:_set_path
  set "meName=%~n0"
  set "meDir=%~dp0"
  set "meDir=%MeDir:~0,-1%"
  set "meLog=%MeDir%\%MeName%.log"
  set "binPath=%MeDir%\bin"
  set "pathBak=%Path%"
  set "path=%pathBak%;%MeDir%;%binPath%"
  goto :eof
  
  
goto :eof
:_error_exit
	if "%~1" neq "" (
		echo,[Error] %~1
	) else (
		if %ERRORLEVEL% neq 0 (echo,[Error] %ERRORLEVEL%)
	)
	pause
	exit
复制代码

文件列表，供参考：

卷 VBOX_D_DRIVE 的文件夹 PATH 列表
卷序列号为 7C67-2B0F
E:\DATA\APP\SYSTEM\BOOT_GRUB\GRUB_BOOT
│  boot.ini
│  grldr
│  install_grub4dos.bat
│  
├─0pe
│      0PE.ISO
│      0PE.ISO.txt
│      
└─boot
    │  HDTune.winpe.7z.exe
    │  
    └─grub
        │  menu.lst
        │  unifont.hex.gz
        │  wallpaper.lzma
        │  
        ├─dos
        │      dir.txt
        │      Maxs.sys
        │      Memdisk.gz
        │      Memtest.iso
        │      ReadMe.txt
        │      
        ├─others.tools
        │      BOOTICEx86v1.321.exe.7z
        │      grldr
        │      grldr.mbr
        │      grldr~pwd_se
        │      WINNT5.X_NTLDR.7z
        │      
        └─pe
                0PE.iso.log
                dir.txt
                ReadMe.txt
                Ton8PE_V5.0_ISO.txt
                TonPE.iso
                V7PXE-g115.zip
                
复制代码

ygqiang

以上是Win7PE版本，支持VHD差分系统备份的恢复，支持Ghost备份的恢复。
另有纯DOS版本，仅仅支持Ghost备份 ...
yu2n 发表于 2015-1-8 09:40

    复杂问题简单化。

还是利用现成的启动软件吧。

不过是改造成运行1个bat 文件，就全自动安装到xp启动菜单上了。不需要频繁用鼠标手动点击好多次了。

@echo off
if "%1" == "h" goto begin
mshta vbscript:createobject("wscript.shell").run("%~fs0 h",0)(window.close)&&exit
:begin
rem 下边开始写批处代码了


set timeout=3
set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"

if exist c:\boot.ini goto ntldr
exit


:ntldr
bootcfg /timeout %timeout% >nul 2>nul
attrib -s -r -h c:\boot.ini

echo. >>c:\boot.ini

findstr /c:"WDOS工具箱" c:\boot.ini >nul || >>c:\boot.ini echo C:\wzldr="WDOS工具箱"
findstr /c:"通用 PE 工具箱" c:\boot.ini >nul || >>c:\boot.ini echo C:\WXPE\PELOAD=通用 PE 工具箱

if not exist c:\WZBOOT "%rar%" x -y "WDOS工具箱.rar" c:\
if not exist c:\PETools "%rar%" x -y "通用 PE 工具箱.rar" c:\

attrib +s +r +h c:\boot.ini

exit
复制代码

yu2n

以上是Win7PE版本，支持VHD差分系统备份的恢复，支持Ghost备份的恢复。
另有纯DOS版本，仅仅支持Ghost备份恢复。

……都没做到普通用户都能自行安装、安全使用的地步。
整个过程是按照配置文件全自动进行，给不会用的人就是灾难，毁灭数据只在分秒之中。

yu2n

一个文本文件创造一个世界？没那么简单。

放上未完工的项目，对照下，你做到哪一步了？

ygqiang

网上看到的资料。。。


@echo off
title 正在判定系统引导器类型……
color 1f
attrib -s -r -h >nul 2>nul
set disname=启动系统维护工具-20110210版
set timeout=3
if exist c:\boot.ini goto ntldr
if exist c:\boot\bcd goto bootmgr  
goto nosys

:ntldr
title 系统启动属于ntldr类型，正在安装工具，请稍等……
type c:\boot.ini| find "\ZHANGHD.LDR" >nul && echo. && title 本工具已经安装，请退出。&& pause && goto clear
echo=>>c:\boot.ini
echo=>>c:\boot.ini
echo C:\ZTPE\GRUB\ZHANGHD.LDR="%disname%">>c:\boot.ini
bootcfg /timeout %timeout% >nul 2>nul
goto clear

:bootmgr
title 系统启动属于bootmgr类型，正在安装工具，请稍等……
set vid=
bcdedit >bcdtemp.txt
type bcdtemp.txt | find "\ZHANGHD.LDR" >nul && echo. && title 本工具已经安装，请退出。&& pause && del ntldr && goto clear
bcdedit  /create /d "%disname%" /application bootsector >vid.ini
for,/f,"tokens=2 delims={",%%i,in (vid.ini) do (
                  set vida=%%i
)
for,/f,"tokens=1 delims=}",%%i,in ("%vida%") do (
                  set vid={%%i}
)
echo %vid%>vid.ini
bcdedit  /set %vid% device boot >nul
bcdedit  /set %vid% path \ZTPE\GRUB\ZHANGHD.LDR >nul
bcdedit  /displayorder %vid% /addlast >nul
bcdedit  /timeout  %timeout% >nul
del ntldr >nul 2>nul
goto clear

:nosys
title C盘没有发现系统引导器，正在安装工具到硬盘，请稍等……
echo 请手动删除C盘的NTLDR，然后重命名文件ZHANG到文件名NTLDR,然后按任意键继续
@pause >nul 2>nul
bootsect /nt52 C:
goto clear

:clear
del ntdetect.com >nul 2>nul
del bootfont.bin >nul 2>nul
del autoexec.bat >nul 2>nul
del config.sys >nul 2>nul
del autoexec.bat >nul 2>nul
del config.sys >nul 2>nul
del bcdtemp.txt >nul 2>nul
del vid.ini >nul 2>nul
del vid.txt >nul 2>nul
del bcd_backup.log >nul 2>nul
del bcd_backup.log1 >nul 2>nul
del bcd_backup.log2 >nul 2>nul
del bcd_backup.log1 >nul 2>nul
attrib +s +r +h   >nul 2>nul
attrib +s +r +h  ZTPE >nul
attrib +s +r +h  ZTPE\DESKTOP.INI >nul
attrib -s -r -h SETUP.CMD
title 安装已经完成,重新启动选择菜单进入系统维护工具。
@pause
del %0




加 echo. 很有必要相当于回车输出一空行，避免加到文件尾部，如果文件结束有空行则看不出来~~
保险起见批处理要以下最少三行内容
attrib -r c:\boot.ini
echo. >>c:\boot.ini
echo C:\wgldr.mbr="一键恢复系统" >>c:\boot.ini