Batcher

38楼用到的外部命令只有一个sort.exe
如果你机器上没有可以到别人机器上拷贝一个过来

keen

自己想的，没有实现排序：

@echo off&setlocal enabledelayedexpansion
for /l %%i in (0 1 9) do (
    for /f "delims=" %%j in (a.txt) do (
        for %%k in (%%j) do (
            set num=%%k
            if "!num:~-1,1!"=="%%i" set _%%i=!_%%i! !num!
)
)
if "!_%%i!" neq "" echo %%i !_%%i!
)
pause
复制代码

随风

for 比 call 快多了，但是用 for /l 似乎没必要，白浪费了9次循环，直接用 for 不是更好吗？
for %%i in (%%a) do set .%%a=!.%%a! 。。。。

tyc

随风的贴子测了一下，不能运行，可能和我的win2000系统有关

[ 本帖最后由 tyc 于 2009-4-15 09:33 编辑 ]

tyc

@echo off
setlocal enabledelayedexpansion
::先排序，再按尾数取
::第一步构建一维数组，并给每个元数武值
for /f "delims=*" %%i in (a.txt) do (
  for %%j in (%%i) do (
      set /a n+=1&set _!n!=%%j
)
)
::用选择法排序
rem echo %n%
for /l %%i in (1,1,%n%) do (
  set /a m=%%i+1
  for /l %%j in (!m!,1,%n%) do (
       if !_%%i! gtr !_%%j! (
            set /a t=_%%i
            set /a _%%i=!_%%j!
            set /a _%%j=t  
)
)
)
::按尾数取
for /l %%i in (1,1,%n%) do (
     for /l %%j in (0,1,9) do (
       if !_%%i:~-1! ==%%j set a_%%j=!a_%%j! !_%%i!
)
)
::输出
for /l %%k in (0,1,9) do (
if !a_%%k! neq 0 echo %%k  !a_%%k!
)

rem set a_
rem set _
pause>nul
复制代码

缺点是建一维数组时变量过多，优点是易读易写

随风

@echo off
if "%~1"=="b" (
   setlocal enabledelayedexpansion
   for /f "delims=" %%a in (a.txt) do (
      for %%i in (%%a) do (
         set "var=     %%i"
         echo !var:~-1! !var:~-5!
))
exit /b 
)
setlocal enabledelayedexpansion
for /f "tokens=1* delims= " %%a in ('%~s0 b^|sort') do set .%%a=!.%%a! %%b
for /l %%a in (0 1 9) do if defined .%%a echo %%a !.%%a!
pause
复制代码

tireless

不会显示重复数字啊。

batman

回楼上，事实胜于雄辩，兄弟还是先测试下吧。。。

tireless

for %%i in (#!var:~-1!) do (
    set "var=!%%i! "
    if "!var: %%a =!"=="!var!" set %%i=!%%i! %%a
  )

这个 for 处理了重复数字。我没有把每个数字设为变量，只用了这些变量：var、#0 至 #9

[ 本帖最后由 tireless 于 2009-4-14 21:04 编辑 ]

batman

你楼上的代码没有处理，如果处理就要在下面这句中用if来处理：
for %%i in (%%a) do set "var=00%%i" & echo !var:~-3!
你这样就是将相同值多次赋值，只保留下最后的一次赋值，也就
是说无论数字中有多少个值相同，结果也只会有一个数字被输出
，如下面这一段代码：

@echo off
for %%a in (1 1 2 3 3 4 4) do set "_%%a=%%a"
set _
pause>nul 
复制代码

tireless

处理了                                                                                                                   .

batman

楼上是否有点考虑欠妥了，好像没有处理数值相同的情况！

[ 本帖最后由 batman 于 2009-4-14 19:56 编辑 ]

tireless

@echo off&setlocal enabledelayedexpansion
(for /f "tokens=*" %%a in (a.txt) do (
  for %%i in (%%a) do set "var=00%%i" & echo !var:~-3!
))>a_tmp.txt

for /f "tokens=* delims=0" %%a in ('sort a_tmp.txt') do (
  set var=%%a
  for %%i in (#!var:~-1!) do (
    set "var=!%%i! "
    if "!var: %%a =!"=="!var!" set %%i=!%%i! %%a
  )
)

for /l %%a in (0 1 9) do if defined #%%a echo %%a!#%%a!
del a_tmp.txt & pause
复制代码

rat

写错了，效率挺好的，学习

batman

17、18楼的代码都有问题，请nanhui兄弟仔细对照题目要求测试和检查，你24楼的写得太罗索，我就没仔细看了。

[ 本帖最后由 batman 于 2009-4-14 11:57 编辑 ]