wxcute

@echo off
set var=av sdkjf   dfj  sdjf df     abc    efg
set var=%var: =.%
call :xx %var%
call :x %var%
pause>nul
:xx
set var=%~n1
goto :eof
:x
echo%~x1
复制代码

我的代码用for有点勉强，参考[ 梦想种子]

@echo off
set var=av sdkjf   dfj  sdjf df     abc    efg
set var=%var: =.%
for %%i in (%var%) do set "var=%%~ni"
call :x %var%
pause>nul
goto :eof
:x
echo%~x1
复制代码

bater

[code]@echo off
set a=sd sdfs sdf sdfsdfa sdfasd abc sdf1
call :lis %a%
pause
:lis
if "%3"=="" echo %1&goto :eof
shift /1
goto lis
这个题目各位高手都能给出正确结果，就菜鸟的接受能力，和解题思路来讲，应该是随风版主，上面的这段代码，是本题目的最佳答案！ 
虽然其他版主的也很简洁，但就解决问题，除了技术和思路来说。越浅显易懂，越是对我等菜鸟有帮助！

[ 本帖最后由 bater 于 2008-9-13 22:11 编辑 ]

fu417674

截取倒数第三段
@echo off
set var=af df aa dfdg adfd  df dgg
for %%i in (%var%) do (call call set d=%%b%%
call set b=%%e%%
set e=%%i)
echo %d%
pause
请帮忙看看

[ 本帖最后由 fu417674 于 2008-5-6 18:29 编辑 ]

fu417674

那如果是要倒数第三四段呢？
因为我照各位的方法能达到要求，但我自己对倒数第三～以后的没有办法，
请各位好心回答我一下，我是刚学的就想到论坛来请各位带进门！

BatHome

以上的代码类 随风的

call在这里的用途类似 延迟

xiaoxx

@echo off
set var=av sdkjf stdf asby  dfj  sdjf   abc efg
set str="test"
setlocal EnableDelayedExpansion
for %%i in (%var%) do (
   set last=!str!
   set str=%%i
)
echo !last!嘿嘿
pause

想法是用2个变量，str始终存储当前%%i,last存储%%i的前一个.
学习中，那个call没看懂，有高手给解释下吗？

梦想种子

@echo off
set var=av sdkjf   dfj  sdjf df abc efg
for %%i in (%var%) do call :rev %%i
set /a c-=1
call echo %%#%c%%%
pause
exit
:rev
set /a c+=1
set #%c%=%1
复制代码

这样对么？

梦想种子

%%~ni 得到文件名
%%~xi 得到后缀名

1、av sdkjf   dfj  sdjf df abc efg （初始值）
2、av.sdkjf...dfj..sdjf.df.abc.efg （把空格换成点）
3、av.sdkjf...dfj..sdjf.df.abc （获得文件名）
4、.abc （获得后缀名）
5、abc （去掉前面的点）

easyguy

@echo off
set var=av sdkjf   dfj  sdjf df abc efg
set var=%var: =.%
for %%i in (%var%) do set "var=%%~ni"
for %%i in (%var%) do set "var=%%~xi"
echo %var:.=%
pause

能不能给我解释下%%~ni和%%~xi什么意思？

梦想种子

@echo off
set var=av sdkjf   dfj  sdjf df abc efg
set var=%var: =.%
for %%i in (%var%) do set "var=%%~ni"
for %%i in (%var%) do set "var=%%~xi"
echo %var:.=%
pause
复制代码

或者

@echo off
set var=av sdkjf   dfj  sdjf df abc efg
set var=%var: =.%
call :get %var% 0
call :get %var% 1
echo %var:.=%
pause
exit
:get
if %2 == 0 (set var=%~n1) else set var=%~x1
复制代码

[ 本帖最后由 梦想种子 于 2008-3-29 23:27 编辑 ]

foxJL

楼上兄弟的代码跟二楼是一样的.

553850000

@echo off
set a="av sdkjf dfj sdjf abc efg"
for /f "tokens=5 delims= " %%i in (%a%) do @echo %%i
pause

随风

代码内容，设置的颜色为white(即：白色)防止答案轻易泄露
显示方法 1：按住鼠标左键，框住代码即可。
显示方法 2：点击代码右上角的“复制内容到剪贴板”也可。

不错，不错，真是一山还有一山高，借鉴foxjl的思路，再来两个，不用for用shift

@echo off
set a=sd sdfs sdf sdfsdfa sdfasd abc sdf1
call :lis %a%
pause
:lis
if "%3"=="" echo %1&goto :eof
shift /1
goto lis
复制代码

不用set也可以。

@echo off
set a=sd sdfs sdf sdfsdfa sdfasd abc sdf1
call :lis "%a%"
pause
:lis
for /f "tokens=1,2*" %%a in ("%~1") do (
  if "%%c"=="" (echo %%a) else call :lis "%%b %%c"
)
goto :eof
复制代码

高亮(反选)显示代码

[ 本帖最后由 随风 于 2008-1-7 22:20 编辑 ]

foxJL

@echo off
set a=sd sdfs sdf sdfsdfa sdfasd 123 sdf1
for %%i in (%a%) do (call set a=%%i %%a%%)
call :a %a%
:a
echo.%2
pause
复制代码

[ 本帖最后由 foxJL 于 2008-1-7 21:56 编辑 ]

随风

代码内容，设置的颜色为white，防止答案轻易泄露
显示方法 1：按住鼠标左键，框住代码即可。
显示方法 2：点击代码右上角的“复制内容到剪贴板”也可。

@echo off
set var=av sdkjf   dfj  sdjf   abc efg
for %%i in (%var%) do (
   call set num=%%str%%
   set str=%%i
)
echo %num%
pause
复制代码

高亮(反选)显示代码

[ 本帖最后由 随风 于 2008-1-7 21:13 编辑 ]