tireless

@echo off
:lop
cls
set "n="
set /p n=输入你想计算的数字n（范围:1~65535）=：

if not defined n goto lop
for /f "tokens=* delims=0123456789" %%a in ("%n%") do if "%%a" neq "" goto lop
if %n% gtr 65535 goto lop

set 位数=%n%54321
title %n% 的位数是 %位数:~5,1%

set sum=0
for /l %%i in (1 1 %n%) do (set /a sum+=%%i)
echo 1+2+....+n=%sum%
pause>nul
goto lop
复制代码

[ 本帖最后由 tireless 于 2009-6-2 21:19 编辑 ]

inittab

能准确判断纯数字

@echo off
:loop
set /p n=请输入:
set m=%n%
for %%a in (0 1 2 3 4 5 6 7 8 9) do (
call set n=%%n:%%a=%%
if not defined n goto start)
goto loop
:start
set "sum="
for /l %%i in (1 1 %m%) do ( set /a sum=sum+%%i)
echo 1+2+....+n=%sum%
pause>nul
goto loop
复制代码

第二种方法：不能区分124asd 和124

@echo off
:lop
cls
set /p n=输入你想计算的数字n=：
2>nuo set /a 1/n || goto lop
set "sum="
for /l %%i in (1 1 %n%) do ( set /a sum=sum+%%i)
echo 1+2+....+n=%sum%
pause>nul
goto lop
复制代码

[ 本帖最后由 inittab 于 2009-6-2 19:49 编辑 ]

netbenton

@echo off
:lop
cls
set /p n=输入你想计算的数字n=：
if %n% lss 0 goto :lop
if %n% gtr 999999999 goto :lop
for /l %%i in (1 1 %n%) do ( set /a sum=sum+%%i)
echo 1+2+....+n=%sum%
pause>nul
goto lop
复制代码

 
@echo off
:lop
cls
set /p n=输入你想计算的数字n=：
set /a v=n
if %v% neq %n% goto :lop
for /l %%i in (1 1 %n%) do ( set /a sum=sum+%%i)
echo 1+2+....+n=%sum%
pause>nul
goto lop
复制代码

[ 本帖最后由 netbenton 于 2009-6-2 20:15 编辑 ]

lo_er

@echo off
cls
set sum=
set /p n=输入你想计算的数字n=
IF %n% lss 0 %0
for /l %%i in (1 1 %n%) do ( set /a sum+=%%i)
echo 1+2+...+n=%sum%
pause>nul
%0
复制代码