Batcher

回复 16# aries215

@echo off
SetLocal EnableDelayedExpansion
set n=1
for /f "tokens=1,3" %%i in ('fsutil volume diskfree c:') do (
    if !n! equ 1 (
        set "free=%%j"
    ) else if !n! equ 2 (
        set "total=%%j"
    )
    set /a n+=1
)
echo !free!
echo !total!
pause
复制代码

aries215

回复 15# Batcher
结果正确！
如果不带汉字，以便适应不同语言，可以吗？
谢谢！

Batcher

回复 14# aries215

@echo off
SetLocal EnableDelayedExpansion
for /f "tokens=1,3" %%i in ('fsutil volume diskfree c:') do (
    if "%%i" equ "可用字节总数" (
        set "free=%%j"
    ) else if "%%i" equ "字节总数" (
        set "total=%%j"
    )
)
echo !free!
echo !total!
pause
复制代码

aries215

回复 13# 523066680
我要的是总空间和剩余空间，分别赋值，要相减得出系统占用大小。
谢谢

523066680

回复 1# aries215


    你想要第一列和最后一列是吗？

@echo off
SetLocal EnableDelayedExpansion
for /f "tokens=1,3" %%i in ('fsutil volume diskfree c:') do (
    set "a=%%i"
    set "b=%%j"
    echo !a! - !b!
)
复制代码

蛋疼一点：

@echo off
SetLocal EnableDelayedExpansion
:: 常量初始化
set sharp=####################

:get_total_size
for /f "tokens=3" %%i in ('fsutil volume diskfree c:') do (set total=%%i&goto :get_free_size)
:get_free_size
for /f "tokens=3" %%i in ('fsutil volume diskfree c: ^|more +1') do (set free=%%i&goto :count)

:count
call :bignum_minus %total% %free% delta
echo %total% %free% 已用空间 %delta%
exit /b

::大数减法
:bignum_minus
    setlocal
    set num_a=%1
    set num_b=%2
    call :length %num_a% len_a
    call :length %num_b% len_b
    set /a max = len_a
    if %len_b% gtr %len_a% (set /a max=len_b, len_b=len_a&set num_a=%num_b%&set num_b=%num_a%)

    set /a minus = 0
    for /l %%n in ( 1, 1, %max% ) do (
        if %%n leq %len_b% (
            set /a dt = !num_a:~-%%n,1! - !num_b:~-%%n,1! - minus
        ) else (
            set /a dt = !num_a:~-%%n,1! - minus
        )
        if !dt! lss 0 (
            set /a buff[%%n] = dt + 10, minus=1
        ) else (
            set /a buff[%%n] = dt, minus=0
        )
    )

    set delta=#
    for /l %%a in (%max%, -1, 1) do set delta=!delta:#0=#!!buff[%%a]!
    endlocal &set %3=%delta:#=%
    goto :eof

::字符串长度计算
:length %str% %vname%
    setlocal
    set test=%~1_%sharp%
    set test=!test:~0,20!
    set test=%test:*_=%
    set /a len=20-(%test:#=1+%1)
    endlocal &set %2=%len%
    goto :eof
复制代码

如果你要我转换成 KB MB GB ，对不起，我不会批处理，我是论坛消遣区负责灌水的。

aries215

回复 4# tigerpower
拜托！
1楼有新问题！

aries215

顶起，有新问题！

tigerpower

发现一个更简单的

powershell -c (gdr C).Used/1mb
复制代码

aries215

回复 8# codegay
谢谢，虽然看不懂

codegay

用nim写了一个，表示很开心：

type 
    WINBOOL* = uint32

    s64* = uint64

proc  getDiskFreeSpaceEx*(name: cstring, freeBytes,
    lpTotalNumberOfBytes,lpTotalNumberOfFreeBytes: var s64): WINBOOL
    {.stdcall, dynlib: "kernel32", importc: "GetDiskFreeSpaceExA", discardable.}

proc getusedspace*(name: cstring):auto {.discardable.} =
    var freeBytes, totalBytes, totalFreeBytes: s64
    getDiskFreeSpaceEx(name, freeBytes, totalBytes,totalFreeBytes)
    result = ((totalBytes - freeBytes) div 1024 div 1024)

echo "已经使用：", getusedspace("c:\\EFI"), "MB"
复制代码

aries215

回复 6# tigerpower
结果正确！
再次感谢！

tigerpower

回复 5# aries215

纯批的代码已改，误差在2MB以内，如果在意这点误差，可以搜一下论坛里“大数”和“浮点数”的帖子。
Powershell第一次运行是比较慢，之后和纯批的速度差距不超过1秒。

aries215

回复 4# tigerpower
谢谢！但闪退。
Powershell 不是每台电脑都有。结果正确，速度太慢。

tigerpower

纯批，误差在2MB以内：

@echo off
for /f "tokens=2,3" %%i in ('wmic logicaldisk C: get size^,freespace^,caption^|findstr C:') do @set a=%%i&set b=%%j
set /a s=(%b:~0,-3%-%a:~0,-3%)/1024*1000/1024
echo %s%MB
复制代码

要精确值使用powershell：

powershell -c "$c=Get-WmiObject Win32_LogicalDisk -Filter \"DeviceID='C:'\";\"{0:F2}MB\" -f (($c.Size-$c.FreeSpace)/1mb)"
复制代码

aries215

回复 2# 1410029385
我要纯批处理哦，否则有些环境执行不了。
谢谢！为啥要转Base64？