77七

回复 16# kimycai


   对

kimycai

回复  kimycai


        
这样估计好理解了..“=”前后是被替换和替换后的内容
77七 发表于 2022-12-5 17:10

    就是把 !out1:'=‘! 再赋值给out2的意思吗

kimycai

回复 12# tmplinshi


    这段暂时还不理解，得好好学习，感谢版主大大

77七

回复 12# tmplinshi

set "inputStr=%inputStr:^^=^%"
if "!c!" == "" (goto :ReplaceSingleQuotes_Finish)
复制代码

请教版主一个问题，这个第一行的代码是什么意思？
我以为和第二行这个有关，但是我把第一行删了，结果也是正确的

77七

回复 11# kimycai


      

    @echo off
    setlocal enabledelayedexpansion
    for %%a in (*.flac) do (
        set "out1=%%~na"
        set "out2=!out1:'=‘!"
        ffmpeg -y -i "%%a" -acodec pcm_s24le  -ar 48000  "!out2!.wav"
    )
复制代码

这样估计好理解了..“=”前后是被替换和替换后的内容

tmplinshi

@echo off

for %%a in (*.flac) do (
    call :ReplaceSingleQuotes "%%~na" newNameNoExt
    set "oldName=%%a"
    setLocal enableDelayedExpansion

    ffmpeg -y -i "!oldName!" -acodec pcm_s24le  -ar 48000  "!newNameNoExt!.wav"

    endLocal
)

pause
exit /b


:ReplaceSingleQuotes <inputStr> <outputVar>

    setLocal disableDelayedExpansion

    set "inputStr=%~1"
    set "inputStr=%inputStr:^^=^%"
    set "outputVar=%~2"
    set "outputStr="

    if "%inputStr:'=%" == "%inputStr%" (
        endLocal & set "%outputVar%=%inputStr%" & exit /b
    )

    set isLeftQuote=true
    set leftQuote=‘
    set rightQuote=’

    setLocal enableDelayedExpansion

    for /l %%i in (0 1 1000) do (
        set c=!inputStr:~%%i,1!

        if "!c!" == "" (goto :ReplaceSingleQuotes_Finish)

        if "!c!" == "'" (
            if !isLeftQuote! == true (
                set c=%leftQuote%
                set isLeftQuote=false
            ) else (
                set c=%rightQuote%
                set isLeftQuote=true
            )
        )

        set "outputStr=!outputStr!!c!"
    )

    :ReplaceSingleQuotes_Finish
    endLocal & endLocal & set "%outputVar%=%outputStr%"
    exit /b
复制代码

kimycai

回复 5# 77七


    set "out=!out:'=‘!"
请问这句是什么意思，包括第一个out和第二个out？

kimycai

回复 7# qixiaobin0715


    英文的引号在传递参数时会引起命令行出错，所以必须要替换掉

kimycai

回复 6# Batcher


    单引号在歌曲名里，比如英文歌曲名是需要的，所以还是要稍微保留一下，只要显示在右上方就可以了

kimycai

中文的引号不是分左右的吗？
77七 发表于 2022-12-5 11:35

    需要加上CHCP 65001，可以用了，谢谢

qixiaobin0715

如果不影响大局的话，不要纠结了，英文中文又何妨？

Batcher

回复 1# kimycai


中文的单引号、双引号是区分左右的。
建议考虑把英文引号直接删掉，而不是替换。

77七

@echo off
setlocal enabledelayedexpansion
for %%a in (*.flac) do (
    set "out=%%~na"
    set "out=!out:'=‘!"
    ffmpeg -y -i "%%a" -acodec pcm_s24le  -ar 48000  "!out!.wav"
)
复制代码

中文的引号不是分左右的吗？

kimycai

英文双引号在文件名中是非法的吧！你可以试着手工把双引号添加到文件名中测试一下。
qixiaobin0715 发表于 2022-12-5 11:00

    对对，应该只是单引号要替换，我修改下内容

kimycai

回复 2# qixiaobin0715


    是吗，那我检查下文件名是不是英文字符