[注册表类] 在批处理FOR中如何取得注册表路径中有空格的项值？

sixes

简单示例代码：

set RegPath=path1,path2,path3
for %%a in (%RegPath%) do(
echo %%a
)
复制代码

当RegPath中的路径都没有空格时，此代码能正确输出各个路径，
但是当路径中有空格时，FOR遇到空格就会以为是分隔符，从而截断。
比如，path1为HKEY_CURRENT_USER\Control Panel\Desktop\HungAppTimeout
Control Panel这里有个空格。

如果在FOR中加上delims=,的话，就得这样写：

for /f "delims=," %%a in ("%RegPath") do ....
复制代码

RegPath加上引号。
但这样又有一个问题，就是只输出path1

我是想RegPath可手动添加，而不用改动其他代码。
在线等高手解决。

Batcher

楼主的意思是，当需要添加新的地址时，只修改set，不修改for。

tmplinshi

set RegPath=path1,path2,path3
set RegPath="%RegPath:,=","%"
for %%a in (%RegPath%) do echo %%~a
复制代码

broly

set RegPath=path1,path2,path3
复制代码

如果这里固定只有几个地址，可以：

for /f "tokens=1-3 delims=," %%a in ("%RegPath%") do (echo %%a&echo %%b&echo %%c)
复制代码

hanyeguxing

方法1：

@echo off
for /f "delims=" %%a in ('more +4^<"%~f0"') do echo;%%a
pause&exit
:列表
1 2
2 3
3 4
复制代码

方法2：

@echo off
for /f "usebackq delims=" %%a in ("%~f0") do (
if defined a echo;%%a
if "%%a"==":列表" set a==
)
pause&exit
:列表
1 2
2 3
3 4
复制代码

方法3：

@echo off&setlocal enabledelayedexpansion
set RegPath=1:2,2:3,3:4
for %%a in (%RegPath%) do set "a=%%a"&echo;!a::= !
pause
复制代码

[ 本帖最后由 hanyeguxing 于 2011-1-25 16:26 编辑 ]