[文本处理] [已解决]批处理如何在文本中非数字的行首加固定内容？

mrhxn

比如文本：
111
地地地地
2222
五五

我的意思是在非数字的行首加固定内容：
111
宋体地地地地
2222
宋体五五

请问，如何实现？

mrhxn

22# 23#

基本都可以，就是有一个问题，不能原样输出，比如有空行的话，就不行了。

CrLf

23# terse


好办法，不过筛选不够严格，而且建议用"%%i"

terse

直接 IF
@echo off
for /f "delims=" %%i in (a.txt) do (
    if %%i lss a (echo %%i)else echo 宋体%%i
)
pause
复制代码

batman

@echo off&setlocal enabledelayedexpansion
(for /f "delims=" %%a in (a.txt) do (
     set "str=%%a"&set "a=宋体"
     if "!str:~,1!" geq "0" if "!str:~,1!" leq "9" set "a="
     echo !a!%%a
))>$
move $ a.txt
start a.txt
复制代码

mrhxn

谢谢hanyeguxing，可以实现。

hanyeguxing

13# Hello123World


        for /l %%b in (0,1,9) do if defined a set "a=!a:%%b=!"
当行为纯数字时，!a!将被删空，这里的 if defined a 是防止对空删除的
        if defined a (echo;宋体%%a) else echo;%%a
当行为纯数字时，!a!已被删空，所以变量就不存在、未被定义

hanyeguxing

18# mrhxn


加上 if "%%b"=="" 判断空行了
如果不保留空行，使用17楼；如果要保留空行，则：

@echo off&set "n=a.txt"
for /f "tokens=1* delims=:" %%a in ('findstr /nb [0-9] "%n%"') do set #%%a==
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%n%"') do if "%%b"=="" (echo;) else (
    if defined #%%a (echo;%%b) else echo;宋体%%b
))>$
move $ "%n%"
复制代码

mrhxn

文本不大时：@echo off&set "n=a.txt"
for /f "tokens=1* delims=:" %%a in ('findstr /nb [0-9] "%n%"') do set #%%a==
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%n%"') do if defined #%%a (echo; ...
hanyeguxing 发表于 2011-4-27 13:44

基本可以实现，但是有空行的地方加了宋体，如何处理空行呢？

hanyeguxing

文本不太大时：

@echo off&set "n=a.txt"
for /f "tokens=1* delims=:" %%a in ('findstr /nb [0-9] "%n%"') do set #%%a==
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%n%"') do if not "%%b"=="" (
    if defined #%%a (echo;%%b) else echo;宋体%%b
))>$
move $ "%n%"
复制代码

CrLf

你自己不说，谁会知道“:”也算在内

@echo off&setlocal enabledelayedexpansion
(for /f "delims=" %%a in (1.txt) do (
        for /f "delims=0123456789:：" %%b in ("%%a@") do if "%%b"=="@" (echo;%%a) else echo 宋体%%a
))>2.txt
pause
复制代码

mrhxn

顶楼怎么不用更明了的例子讲清楚...到底这里说的非数字是匹配整行还是只匹配行首？
zm900612 发表于 2011-4-27 13:22

只匹配号首，问题是，行首是1：仍然给加上了。
1:
2
批处理之家

运行后变成这样：
宋体1：
2
宋体批处理之家
我的意思是：
1：
2
宋体批处理之家

CrLf

谢谢各位，但数字后有冒号的就不行了，比如：
1：
它也给加上了，只要行首是非数字的就加。
mrhxn 发表于 2011-4-27 13:14

顶楼怎么不用更明了的例子讲清楚...到底这里说的非数字是匹配整行还是只匹配行首？

Hello123World

3# hanyeguxing



if defined a (echo;宋体%%a) else echo;%%a

不明白，能解答一下吗？这里变量a无论如何都是定义的啊，为什么要加else

mrhxn

谢谢各位，但数字后有冒号的就不行了，比如：
1：
它也给加上了，只要行首是非数字的就加。