[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
1234
返回列表 发帖
bluewing009

Rank: 6Rank: 6

帖子
515 
积分
1788 
技术
15  
捐助
0  
注册时间
2009-11-27 
1楼 跳转到 » 正序看帖
打印
tT
发表于 2011-7-10 13:44 | 只看该作者

[安全相关] 批处理危险等级

鉴于大家对批处理的想法.....额
特别写了这么一个对目标批处理进行 危险等级划分 和 可疑程度评估 的一个小工具
通过这个工具，你可以大致判定一个陌生的批处理是危险还是安全~

希望大家支持~！
大家多提意见才是对我的最大帮助~
PS：可以M我或者回帖时带上你用来判定的批处理

说明：

1.可以对拖入的批处理进行分析，显示危险等级和可疑程度，并在目标文件夹下生成 详细分析.txt 里面有当前文件的详细敏感命令的分析：敏感命令所在行、敏感命令作用以及当前命令内容
2.自带一个解密组件，可以对当前常见的批处理加密进行解析，从而能够正确的判断
3.危险等级划分为5个等级，用★表示：★越多表示危险等级越高
4.可疑程度是用来辅助判定，有些批处理虽然危险等级很高，但是可疑程度很低，我们就可以大致认为：这是一个虽然涉及敏感命令的正常批处理（在详细分析.txt中有列举出各敏感命令，大家可以判定是误报还是确有其事）


附件下载链接: https://pan.baidu.com/s/1a-b2rzmlsiHeaaeu3RdanA?pwd=gg4y

关于附件：
考虑到其作为一个判别工具，当前的附件进行轻微加密

说是加密过的，了解的人轻松就能看到~


-------------------------更新说明-------------------------

0.0 测试版，希望那个大家提建议
0.1 添加敏感命令数量
0.2 重新编写判别方式，减少文件体积
0.3 修正因为@导致该语句无法判断的问题
0.4 优化@字符检测，减少运行时间
0.5 修正因为路径为题导致可疑程度超过100%
0.6 修正for if 单独一行时敏感命令无法判别的问题
0.7 修正对加密的批处理敏感性判定
0.8 添加在线更新组件，方便大家测试更新
0.9 添加对输出文件的处理 针对 echo > 命令
1.0 修正输出路径，修正对 标签 注释 的忽略
1.1 添加敏感命令，修改进度计数方式
1.2 添加敏感命令，修正可能无法更新的问题
1.3 修正set /p 导致的一场中断 添加空变量解密 修正特殊符号导致的错误退出

---------------------------------------------------------------
1

评分人数

收藏 分享

ANSL

帖子
123 
积分
195 
技术
10  
捐助
0  
注册时间
2022-3-30 
47楼
发表于 2022-12-19 15:40 | 只看该作者
回复 46# FenoX
你不知道?这只是这个批处理的一个标签
与
@ echo off
:test
echo 1111
goto test
同理只是把test换成了Main
本人已死,不用联系,要联系下来联系~

TOP

FenoX

Rank: 1

帖子
26 
积分
44 
技术
2  
捐助
0  
注册时间
2022-11-24 
46楼
发表于 2022-12-19 11:28 | 只看该作者
FenoX`代理：写的很好！让我惊讶的是源码中居然有“main”!!楼主是用什么语言的么！？
:Main
Setlocal enabledelayedexpansion
Mode con cols=46 lines=12
Title 危险等级分析工具
.....
echo.
echo                     请下载更新
ping /n 3 127.1>nul
goto Main

不过为什么要加密？？

TOP

gmj0xdq

Rank: 1

帖子
5 
积分
16 
技术
0  
捐助
0  
注册时间
2022-8-26 
45楼
发表于 2022-8-26 22:39 | 只看该作者
rem ӔЂΪַԃةݾ

:Bat_Decrypt
rem كةݾ& ...
gmj0xdq 发表于 2022-8-26 22:38

有的字符识别成表情了（啊这）

TOP

gmj0xdq

Rank: 1

帖子
5 
积分
16 
技术
0  
捐助
0  
注册时间
2022-8-26 
44楼
发表于 2022-8-26 22:38 | 只看该作者
:Analyze
cls
set /a NO.=Risk_level_=Key_NO.=0
echo ƺԦmࠉӉԌ&#14 ...
gmj0xdq 发表于 2022-8-26 22:37


rem ӔЂΪַԃةݾ

:Bat_Decrypt
rem كةݾΪƺԦmޢĜةݾì߼ÇսƺԦmݓĜһѣΪѣۤطƷìȫʷטעҼޢĜ۳քτݾìذטط֟Ҳˇذטؔܺc
rem ɫࠚӎ˽ %1 ΪѨҪޢĜքτݾ·޶ By Bluewing009
cls
del /f /s /q %temp%\decrypt.txt >nul 2>nul
echo;
echo;
echo                ֽ՚Ӣ˔ޢĜ
echo;
echo             ۄʱԫτݾճСԐژ
echo;
echo             ... ȫōфֈս ...
ping /n 2 127.1>nul
setlocal enabledelayedexpansion
rem ЂĦ}ѐࠕѐҘѨѣզìԃԚݫ&ͦۻΪۻѐ
set Change_Line=^


set /a NO._Now=0
for /f "usebackq tokens=1* delims=:" %%i in (`findstr/n .* "%~1"`) do set NO._all=%%i
for /f "usebackq delims=" %%a in ("%~1") do (
        set var_change=%%a
        set /a NO._Now+=1
        cls
        echo;
        echo;
        echo    ֽ՚ޢ϶    !NO._Now!/!NO._all!
        set var_change=!var_change:^|=#_1_#!
        set var_change=!var_change:^<=#_2_#!
        set var_change=!var_change:^>=#_3_#!
        set var_change=!var_change:^(=#_4_#!
        set var_change=!var_change:^)=#_5_#!
        set var_change=!var_change:^"=#_6_#!
        set var_change=!var_change:^^=^^^^!
        for %%l in ("!Change_Line!") do set var_change=!var_change:^&=%%~l!
        call :Bat_Decrypt_Key "!var_change!"
)
goto :eof

:Bat_Decrypt_Key
set str_get=%~1
if "!str_get:set =!" neq "!str_get!" (echo;|call %~1&set var_change_back=%~1) else (set var_change_back=%~1)
set var_change_back=!var_change_back:#_1_#=^|!
set var_change_back=!var_change_back:#_2_#=^<!
set var_change_back=!var_change_back:#_3_#=^>!
set var_change_back=!var_change_back:#_4_#=^(!
set var_change_back=!var_change_back:#_5_#=^)!
set var_change_back=!var_change_back:#_6_#=^"!
echo !var_change_back!>>%temp%\decrypt.txt
goto :eof



:Check_Updates
Setlocal enabledelayedexpansion
Mode con cols=50 lines=10
Title ՚Пټт
set version_New=δ֪
cls
echo.
echo.
echo.
echo                    ֽ՚ݬөټт
echo.
echo                    ...ȫʔ۳...
echo on error resume next >%temp%\Updates_.vbs.vbs
echo set arg=wscript.arguments >>%temp%\Updates_.vbs.vbs
echo if arg.count=0 then wscript.quit >>%temp%\Updates_.vbs.vbs
echo Set Message = CreateObject("CDO.Message") >>%temp%\Updates_.vbs.vbs
echo Message.CreateMHTMLBody arg(0),31 >>%temp%\Updates_.vbs.vbs
echo DownLoad= Message.HTMLBody >>%temp%\Updates_.vbs.vbs
echo Set Message = Nothing >>%temp%\Updates_.vbs.vbs
echo Set DownRecord=CreateObject("ADODB.Recordset") >>%temp%\Updates_.vbs.vbs
echo Length=Len(DownLoad)/2 >>%temp%\Updates_.vbs.vbs
echo DownRecord.Fields.Append "Content",205,Length>>%temp%\Updates_.vbs.vbs
echo DownRecord.OpenownRecord.AddNew >>%temp%\Updates_.vbs.vbs
echo DownRecord("Content")=DownLoad^&ChrB(0) >>%temp%\Updates_.vbs.vbs
echo DownRecord.Update >>%temp%\Updates_.vbs.vbs
echo DownLoad=DownRecord("Content").GetChunk(Length) >>%temp%\Updates_.vbs.vbs
echo Set DownContent=CreateObject("ADODB.Stream") >>%temp%\Updates_.vbs.vbs
echo With DownContent >>%temp%\Updates_.vbs.vbs
echo .Mode = 3 >>%temp%\Updates_.vbs.vbs
echo .Type = 1 >>%temp%\Updates_.vbs.vbs
echo .Open() >>%temp%\Updates_.vbs.vbs
echo .Write DownLoad >>%temp%\Updates_.vbs.vbs
echo .SaveToFile arg(1),2 >>%temp%\Updates_.vbs.vbs
echo End with>>%temp%\Updates_.vbs.vbs
cscript %temp%\Updates_.vbs.vbs http://www.bluewing009.co.cc/ƺԦmΣЕֈܶ_ѦѾҪ݇.htm %temp%/ƺԦmΣЕֈܶ_ѦѾҪ݇.txt >nul
ping /n 1 127.1>nul
for /f %%i in (%temp%\ƺԦmΣЕֈܶ_ѦѾҪ݇.txt) do set version_New=%%i
if "%version_New%"=="δ֪" goto Check_Updates_Error
for /f "tokens=1* delims=:" %%i in ('findstr /n .* %0') do if %%i==18 for /f "tokens=3" %%m in ('%%j') do set version_Now=%%m
if %version_Now%==%version_New% goto Main else  Check_Updates_Do

:Check_Updates_Do
cls
echo.
echo.
echo.
echo                    ֽ՚Ђ՘ټт
echo.
echo                    ...ȫʔ۳...
cscript %temp%\Updates_.vbs.vbs http://www.bluewing009.co.cc/ƺԦmΣЕֈܶ_պë.htm %temp%\ƺԦmΣЕֈܶ.bat >nul
ping /n 3 127.1>nul
echo @echo off>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo Mode con cols=50 lines=10>>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo Color 3F>>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo Title ՚Пټт>>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo echo.>>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo echo.>>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo echo.>>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo echo.>>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo echo                   ...טтǴ֯...>>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo ping /n 3 127.1^>nul>>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo copy /y "%temp%\ƺԦmΣЕֈܶ.bat" "%~dp0\%~n0.bat"^>nul >>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo start "" "%~dp0\%~n0.bat">>%temp%\ƺԦmΣЕֈܶ_ټт.bat
echo Exit>>%temp%\ƺԦmΣЕֈܶ_ټт.bat
start %temp%\ƺԦmΣЕֈܶ_ټт.bat
exit

:Check_Updates_Error
cls
echo.
echo.
echo                 ϞרlޓټтؾϱǷ
echo.
echo                     ȫЂ՘ټт
ping /n 3 127.1>nul
goto Main

TOP

gmj0xdq

Rank: 1

帖子
5 
积分
16 
技术
0  
捐助
0  
注册时间
2022-8-26 
43楼
发表于 2022-8-26 22:37 | 只看该作者
那啥哈，源码给破译出来了（汉字还没转换呢，实在不行自己把关键字写到文件里让bat检测一下就知道原文是什么 ...
gmj0xdq 发表于 2022-8-26 22:35



:Analyze
cls
set /a NO.=Risk_level_=Key_NO.=0
echo ƺԦmࠉӉԌ׈ؖ϶Ѩ٦>%temp%\Ъϸؖ϶_1.txt
echo By bluewing009   QQ 961881006 >>%temp%\Ъϸؖ϶_1.txt
echo;>>%temp%\Ъϸؖ϶_1.txt
echo ؖ϶τݾú%Target_File% >>%temp%\Ъϸؖ϶_1.txt
findstr /i /b /v "echo set pause : rem" "%temp%\decrypt.txt">%temp%\key_code.txt
findstr /i /b "echo" "%Target_File%" |find  ">" >%temp%\key_code_output.txt
findstr /i /b "for if" "%temp%\key_code.txt">%temp%\key_code_special.txt
for /f "usebackq tokens=1* delims=:" %%i in (`findstr /n .* "%temp%\key_code.txt"`) do set /a Key_NO.=%%i
for %%m in (
    "5 : format : ٱʽۯՅƌ"
    "5 : debug : Śզўل"
    "5 : ftp : ԫˤδ֪τݾ"
    "4 : assoc : ўلτݾژj"
    "4 : start : ַԃδ֪τݾ"
    "4 : cscript : ַԃδ֪ޅѾ"
    "4 : mshta : ַԃδ֪ޅѾ"
    "4 : reg : әطעӡҭݼֵ"
    "4 : cacls : ўلτݾ؃ϊ࠘׆"
    "4 : icacls : ўلτݾ؃ϊ࠘׆"
    "4 : Bootcfg : ўلϵͳݓ՘ЮĿ"
    "4 : ntsd : ޸Ԍַ˔"
    "4 : regsvr32 : עӡdllτݾ"
    "4 : route : ·ԉәط"
    "4 : sc : ؾϱәط"
    "4 : arp : ўلַ֘ޢ϶ЭөèARPé"
    "3 : del : ɾԽτݾ"
    "3 : erase : ɾԽτݾ"
    "3 : rd : ɾԽĿ¼"
    "3 : rmdir : ɾԽĿ¼"
    "3 : cprofile : ȥԽƤ׃τݾ"
    "3 : ftype : ўلτݾژj)չ"
    "3 : replace : ͦۻτݾ"
    "2 : attrib : ўلτݾ˴є"
    "2 : convert : ўل߭`э"
    "2 : device : ݓ՘ʨѸȽ֯"
    "2 : schtasks : ўل݆ۮɎϱ"
    "2 : shutdown : ژҕ݆̣ܺ"
    "2 : subst : ѩŢȽ֯Ƿ"
    "2 : taskkill : ޡ˸Ɏϱܲ޸Ԍ"
    "2 : tskill : ޡ˸Ɏϱܲ޸Ԍ"
    "1 : copy : ش׆τݾ"
    "1 : xcopy : ش׆τݾݐ"
    "1 : mkdir : ԴݨĿ¼ܲؓĿ¼"
    "1 : md : ԴݨĿ¼ܲؓĿ¼"
    "1 : move : ӆ֯τݾ"
    "1 : ren : ўلτݾĻ"
    "1 : rename : ўلτݾĻ"
) do (
        set /a NO._Doing+=26
        set /a NO._Doing_Check1=!NO._Doing:~0,2!
        set /a NO._Doing_Check2=!NO._Doing:~-2!
        if !NO._Doing_Check1!==!NO._Doing_Check2! (
            set /a NO._Doing_Number=!NO._Doing:~0,1!
            set /a NO._Doing_Point=!NO._Doing:~-1!
        ) else (
            set /a NO._Doing_Number=!NO._Doing:~0,2!
            set /a NO._Doing_Point=!NO._Doing:~-1!
        )
        cls
        echo;
        echo;
        echo  ֽ՚ޢ϶ìȫʔ۳
        echo;
        echo;
        echo                       !NO._Doing_Number!.!NO._Doing_Point! %%%
    for /f "tokens=1,2,* delims=:" %%i in ("%%m") do (
        set Risk_level_temp=%%i
        set Risk_level_temp=!Risk_level_temp:~1,-1!
        set Code_temp=%%j
        set Code=!Code_temp:~1,-1!
        set Exegesis_temp=%%k
        set Exegesis=!Exegesis_temp:~1,-1!
        
        for /f "usebackq tokens=1* delims=:" %%u in (`findstr /n /i /b "!code! @!code!" "%temp%\decrypt.txt"`) do (
            echo ֚%%uѐ   !Exegesis!   %%v >>%temp%\Ъϸؖ϶_2.txt
            set /a NO.+=1
            if !Risk_level_! leq !Risk_level_temp! set /a Risk_level_=!Risk_level_temp!
        )
        
        for /f "usebackq tokens=1* delims=:" %%u in (`findstr /n /i /C:"!code! " "%temp%\key_code_special.txt"`) do (
            echo ֚%%uѐ   !Exegesis!   %%v >>%temp%\Ъϸؖ϶_2.txt
            set /a NO.+=1
            if !Risk_level_! leq !Risk_level_temp! set /a Risk_level_=!Risk_level_temp!
        )

        for /f "usebackq tokens=1* delims=:" %%u in (`findstr /n /i /C:"!code! " "%temp%\key_code_output.txt"`) do (
            echo ֚%%uѐ   !Exegesis!   %%v >>%temp%\Ъϸؖ϶_2.txt
            set /a NO.+=1
            if !Risk_level_! leq !Risk_level_temp! set /a Risk_level_=!Risk_level_temp!
        )
        
    )
)
if !Risk_level_!==5 set Risk_level=ˉˉˉˉˉ & set Risk_=ܫ׈ΣЕ
if !Risk_level_!==4 set Risk_level=ˉˉˉˉ® & set Risk_=א׈ΣЕ
if !Risk_level_!==3 set Risk_level=ˉˉˉ®® & set Risk_=ȡ׈ΣЕ
if !Risk_level_!==2 set Risk_level=ˉˉ®®® & set Risk_=ѨҪژע
if !Risk_level_!==1 set Risk_level=ˉ®®®® & set Risk_=ѨҪעӢ
if !Risk_level_!==0 set Risk_level=®®®®® & set Risk_=ûԐΣЕ
set /a Suspicious_level=!NO.!*100/!Key_NO.!
del  "%temp%\result.txt"  "%temp%\decrypt.txt" "%temp%\key_code.txt" "%temp%\key_code_special.txt" "%temp%\key_code_output.txt" >nul
echo ============================================== >>%temp%\Ъϸؖ϶_1.txt
echo    ΣЕֈܶú !Risk_level!   !Risk_! >>%temp%\Ъϸؖ϶_1.txt
echo    ࠉӉԌ׈ú !Suspicious_level!%%>>%temp%\Ъϸؖ϶_1.txt
echo ============================================== >>%temp%\Ъϸؖ϶_1.txt
copy /b %temp%\Ъϸؖ϶_1.txt+%temp%\Ъϸؖ϶_2.txt "%Target_File_Path%%Target_File_Name%_Ъϸؖ϶.txt"
del %temp%\Ъϸؖ϶_1.txt %temp%\Ъϸؖ϶_2.txt >nul
cls
echo;
echo                  ؖ ϶ ޡ ڻ
echo ==============================================
echo;
echo ࠉӉԌ׈Խٟղ˵ķĿҪΪױӢƺԦmքࠉŜԽճ
echo    ࠉӉԌ׈ú !Suspicious_level!%%
echo;
echo ΣЕֈܶԽٟղ˵ķࠉŜլԉքΣڦԌ׈Խճ
echo    ΣЕֈܶú !Risk_level!
echo;
ping /n 3 127.1>nul
start "" "%Target_File_Path%%Target_File_Name%_Ъϸؖ϶.txt"
pause>nul  
exit

TOP

gmj0xdq

Rank: 1

帖子
5 
积分
16 
技术
0  
捐助
0  
注册时间
2022-8-26 
42楼
发表于 2022-8-26 22:35 | 只看该作者
那啥哈，源码给破译出来了（汉字还没转换呢，实在不行自己把关键字写到文件里让bat检测一下就知道原文是什么了）
关键句子如下
��cls
@echo off
Color 3F
goto Check_Updates


:Main
Setlocal enabledelayedexpansion
Mode con cols=46 lines=12
Title ΣЕֈܶؖ϶٤ߟ
cls
echo;
echo   ˉ®ˉ®ˉ®ˉ®ˉ®ˉ®ˉ®ˉ®ˉ®ˉ®ˉ
echo   ®                                      ®
echo   ˉ       ƺԦmΣЕֈܶؖ϶׺٤ߟ       ˉ
echo   ®                                      ®
echo   ˉ                             V 1.3    ˉ
echo   ®                                      ®
echo   ˉ                        bluewing009   ˉ
echo   ®                       QQ ú961881006 ®
echo   ˉ®ˉ®ˉ®ˉ®ˉ®ˉ®ˉ®ˉ®ˉ®ˉ®ˉ
ping /n 3 127.1>nul



:Target_Get
cls
echo;
echo  ȫѡձҪؖ϶քƺԦm(Q=΋Զ):
echo;
echo   Ώ֯ܲˤɫ߹ࠉ
echo;
set /p Target_File=
set "Target_File=%Target_File:"=%"
if /i "%Target_File%"=="q" exit
if /i "%Target_File:~-4%"==".bat" if exist "%Target_File%" goto Prepare
if /i "%Target_File:~-4%"==".cmd" if exist "%Target_File%" goto Prepare
echo ĿҪτݾһˇƺԦmτݾè*.bat  *.cmdé
ping /n 3 127.1>nul
goto Target_Get



repare
for /f "delims=" %%i in ("%Target_File%") do (
    set Target_File_Name=%%~ni
    set Target_File_Path=%%~dpi
)
call :Bat_Decrypt "%Target_File%"


（写不下，分批发）

TOP

LJY4.0

Rank: 3Rank: 3

帖子
185 
积分
260 
技术
14  
捐助
0  
注册时间
2022-4-23 
41楼
发表于 2022-7-16 11:39 | 只看该作者
回复 2# plp626
幸好搞了个文件夹,桌面大把东西

TOP

ZJHJ

Rank: 4

帖子
125 
积分
463 
技术
2  
捐助
0  
注册时间
2008-7-30 
40楼
发表于 2012-2-27 20:39 | 只看该作者
如果你相信分析，每个批处理都很危险。看下面的；
@echo off
set /p jm=  请输入要批量解密文件的扩展名:
md yjm
cd.>jie.tx
setlocal enabledelayedexpansion
for  %%i in (*.%jm%) do (
set xg=%%~ni
copy jie.tx + "%%i" yjm\!xg!.txt
)

del jie.tx
start yjm
。。。。。。
这个代码有危险吗？
但
批处理可疑程度分析报告
By bluewing009   QQ 961881006

分析文件：C:\Documents and Settings\Administrator\桌面\新建文件夹\批量乱码解密.bat
==============================================
   危险等级： ★★★★☆    中度危险
   可疑程度： 50%
==============================================
第11行   调用未知文件    start yjm
第10行   删除文件    del jie.tx
第8行   复制文件    copy jie.tx + "%i" yjm\.txt
第3行   创建目录或子目录    md yjm

TOP

ZJHJ

Rank: 4

帖子
125 
积分
463 
技术
2  
捐助
0  
注册时间
2008-7-30 
39楼
发表于 2012-2-27 20:28 | 只看该作者
cls
@echo off
Color 3F
goto Check_Updates


:Main
Setlocal enabledelayedexpansion
Mode con cols=46 lines=12
Title 危险等级分析工具
cls
echo;
echo   ★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★
echo   ☆                                      ☆
echo   ★       批处理危险等级分析助工具       ★
echo   ☆                                      ☆
echo   ★                             V 1.3    ★
echo   ☆                                      ☆
echo   ★                        bluewing009   ★
echo   ☆                       QQ ：961881006 ☆
echo   ★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★
ping /n 3 127.1>nul



:Target_Get
cls
echo;
echo  请选择要分析的批处理(Q=退出):
echo;
echo   拖动或输入均可
echo;
set /p Target_File=
set "Target_File=%Target_File:"=%"
if /i "%Target_File%"=="q" exit
if /i "%Target_File:~-4%"==".bat" if exist "%Target_File%" goto Prepare
if /i "%Target_File:~-4%"==".cmd" if exist "%Target_File%" goto Prepare
echo 目标文件不是批处理文件（*.bat  *.cmd）
ping /n 3 127.1>nul
goto Target_Get



repare
for /f "delims=" %%i in ("%Target_File%") do (
    set Target_File_Name=%%~ni
    set Target_File_Path=%%~dpi
)
call :Bat_Decrypt "%Target_File%"



:Analyze
cls
set /a NO.=Risk_level_=Key_NO.=0
echo 批处理可疑程度分析报告>%temp%\详细分析_1.txt
echo By bluewing009   QQ 961881006 >>%temp%\详细分析_1.txt
echo;>>%temp%\详细分析_1.txt
echo 分析文件：%Target_File% >>%temp%\详细分析_1.txt
findstr /i /b /v "echo set pause : rem" "%temp%\decrypt.txt">%temp%\key_code.txt
findstr /i /b "echo" "%Target_File%" |find  ">" >%temp%\key_code_output.txt
findstr /i /b "for if" "%temp%\key_code.txt">%temp%\key_code_special.txt
for /f "usebackq tokens=1* delims=:" %%i in (`findstr /n .* "%temp%\key_code.txt"`) do set /a Key_NO.=%%i
for %%m in (
    "5 : format : 格式化磁盘"
    "5 : debug : 内存修改"
    "5 : ftp : 传输未知文件"
    "4 : assoc : 修改文件关联"
    "4 : start : 调用未知文件"
    "4 : cscript : 调用未知脚本"
    "4 : mshta : 调用未知脚本"
    "4 : reg : 操作注册表键值"
    "4 : cacls : 修改文件访问控制"
    "4 : icacls : 修改文件访问控制"
    "4 : Bootcfg : 修改系统加载项目"
    "4 : ntsd : 进程调试"
    "4 : regsvr32 : 注册dll文件"
    "4 : route : 路由操作"
    "4 : sc : 服务操作"
    "4 : arp : 修改地址解析协议（ARP）"
    "3 : del : 删除文件"
    "3 : erase : 删除文件"
    "3 : rd : 删除目录"
    "3 : rmdir : 删除目录"
    "3 : cprofile : 清除配置文件"
    "3 : ftype : 修改文件关联扩展"
    "3 : replace : 替换文件"
    "2 : attrib : 修改文件属性"
    "2 : convert : 修改卷类型"
    "2 : device : 加载设备驱动"
    "2 : schtasks : 修改计划任务"
    "2 : shutdown : 关闭计算机"
    "2 : subst : 虚拟驱动器"
    "2 : taskkill : 结束任务或进程"
    "2 : tskill : 结束任务或进程"
    "1 : copy : 复制文件"
    "1 : xcopy : 复制文件夹"
    "1 : mkdir : 创建目录或子目录"
    "1 : md : 创建目录或子目录"
    "1 : move : 移动文件"
    "1 : ren : 修改文件名"
    "1 : rename : 修改文件名"
) do (
        set /a NO._Doing+=26
        set /a NO._Doing_Check1=!NO._Doing:~0,2!
        set /a NO._Doing_Check2=!NO._Doing:~-2!
        if !NO._Doing_Check1!==!NO._Doing_Check2! (
            set /a NO._Doing_Number=!NO._Doing:~0,1!
            set /a NO._Doing_Point=!NO._Doing:~-1!
        ) else (
            set /a NO._Doing_Number=!NO._Doing:~0,2!
            set /a NO._Doing_Point=!NO._Doing:~-1!
        )
        cls
        echo;
        echo;
        echo  正在解析，请稍后
        echo;
        echo;
        echo                       !NO._Doing_Number!.!NO._Doing_Point! %%%
    for /f "tokens=1,2,* delims=:" %%i in ("%%m") do (
        set Risk_level_temp=%%i
        set Risk_level_temp=!Risk_level_temp:~1,-1!
        set Code_temp=%%j
        set Code=!Code_temp:~1,-1!
        set Exegesis_temp=%%k
        set Exegesis=!Exegesis_temp:~1,-1!
        
        for /f "usebackq tokens=1* delims=:" %%u in (`findstr /n /i /b "!code! @!code!" "%temp%\decrypt.txt"`) do (
            echo 第%%u行   !Exegesis!   %%v >>%temp%\详细分析_2.txt
            set /a NO.+=1
            if !Risk_level_! leq !Risk_level_temp! set /a Risk_level_=!Risk_level_temp!
        )
        
        for /f "usebackq tokens=1* delims=:" %%u in (`findstr /n /i /C:"!code! " "%temp%\key_code_special.txt"`) do (
            echo 第%%u行   !Exegesis!   %%v >>%temp%\详细分析_2.txt
            set /a NO.+=1
            if !Risk_level_! leq !Risk_level_temp! set /a Risk_level_=!Risk_level_temp!
        )

        for /f "usebackq tokens=1* delims=:" %%u in (`findstr /n /i /C:"!code! " "%temp%\key_code_output.txt"`) do (
            echo 第%%u行   !Exegesis!   %%v >>%temp%\详细分析_2.txt
            set /a NO.+=1
            if !Risk_level_! leq !Risk_level_temp! set /a Risk_level_=!Risk_level_temp!
        )
        
    )
)
if !Risk_level_!==5 set Risk_level=★★★★★ & set Risk_=极度危险
if !Risk_level_!==4 set Risk_level=★★★★☆ & set Risk_=中度危险
if !Risk_level_!==3 set Risk_level=★★★☆☆ & set Risk_=轻度危险
if !Risk_level_!==2 set Risk_level=★★☆☆☆ & set Risk_=需要关注
if !Risk_level_!==1 set Risk_level=★☆☆☆☆ & set Risk_=需要注意
if !Risk_level_!==0 set Risk_level=☆☆☆☆☆ & set Risk_=没有危险
set /a Suspicious_level=!NO.!*100/!Key_NO.!
del  "%temp%\result.txt"  "%temp%\decrypt.txt" "%temp%\key_code.txt" "%temp%\key_code_special.txt" "%temp%\key_code_output.txt" >nul
echo ============================================== >>%temp%\详细分析_1.txt
echo    危险等级： !Risk_level!   !Risk_! >>%temp%\详细分析_1.txt
echo    可疑程度： !Suspicious_level!%%>>%temp%\详细分析_1.txt
echo ============================================== >>%temp%\详细分析_1.txt
copy /b %temp%\详细分析_1.txt+%temp%\详细分析_2.txt "%Target_File_Path%%Target_File_Name%_详细分析.txt"
del %temp%\详细分析_1.txt %temp%\详细分析_2.txt >nul
cls
echo;
echo                  分 析 结 果
echo ==============================================
echo;
echo 可疑程度越高则说明目标为恶意批处理的可能越大
echo    可疑程度： !Suspicious_level!%%
echo;
echo 危险等级越高则说明可能造成的危害程度越大
echo    危险等级： !Risk_level!
echo;
ping /n 3 127.1>nul
start "" "%Target_File_Path%%Target_File_Name%_详细分析.txt"
pause>nul  
exit


rem 以下为调用组件

:Bat_Decrypt
rem 该组件为批处理解密组件，考虑到批处理加密一般为保护作品，请慎重发布解密后的文件，尊重作者也是尊重自己。
rem 入口参数 %1 为需要解密的文件路径 By Bluewing009
cls
del /f /s /q %temp%\decrypt.txt >nul 2>nul
echo;
echo;
echo                正在尝试解密
echo;
echo             耗时与文件大小有关
echo;
echo             ... 请耐心等待 ...
ping /n 2 127.1>nul
setlocal enabledelayedexpansion
rem 下面两行空行必需保存，用于将&替换为换行
set Change_Line=^


set /a NO._Now=0
for /f "usebackq tokens=1* delims=:" %%i in (`findstr/n .* "%~1"`) do set NO._all=%%i
for /f "usebackq delims=" %%a in ("%~1") do (
        set var_change=%%a
        set /a NO._Now+=1
        cls
        echo;
        echo;
        echo    正在解析    !NO._Now!/!NO._all!
        set var_change=!var_change:^|=#_1_#!
        set var_change=!var_change:^<=#_2_#!
        set var_change=!var_change:^>=#_3_#!
        set var_change=!var_change:^(=#_4_#!
        set var_change=!var_change:^)=#_5_#!
        set var_change=!var_change:^"=#_6_#!
        set var_change=!var_change:^^=^^^^!
        for %%l in ("!Change_Line!") do set var_change=!var_change:^&=%%~l!
        call :Bat_Decrypt_Key "!var_change!"
)
goto :eof

:Bat_Decrypt_Key
set str_get=%~1
if "!str_get:set =!" neq "!str_get!" (echo;|call %~1&set var_change_back=%~1) else (set var_change_back=%~1)
set var_change_back=!var_change_back:#_1_#=^|!
set var_change_back=!var_change_back:#_2_#=^<!
set var_change_back=!var_change_back:#_3_#=^>!
set var_change_back=!var_change_back:#_4_#=^(!
set var_change_back=!var_change_back:#_5_#=^)!
set var_change_back=!var_change_back:#_6_#=^"!
echo !var_change_back!>>%temp%\decrypt.txt
goto :eof



:Check_Updates
Setlocal enabledelayedexpansion
Mode con cols=50 lines=10
Title 在线更新
set version_New=未知
cls
echo.
echo.
echo.
echo                    正在检查更新
echo.
echo                    ...请稍后...
echo on error resume next >%temp%\Updates_.vbs.vbs
echo set arg=wscript.arguments >>%temp%\Updates_.vbs.vbs
echo if arg.count=0 then wscript.quit >>%temp%\Updates_.vbs.vbs
echo Set Message = CreateObject("CDO.Message") >>%temp%\Updates_.vbs.vbs
echo Message.CreateMHTMLBody arg(0),31 >>%temp%\Updates_.vbs.vbs
echo DownLoad= Message.HTMLBody >>%temp%\Updates_.vbs.vbs
echo Set Message = Nothing >>%temp%\Updates_.vbs.vbs
echo Set DownRecord=CreateObject("ADODB.Recordset") >>%temp%\Updates_.vbs.vbs
echo Length=Len(DownLoad)/2 >>%temp%\Updates_.vbs.vbs
echo DownRecord.Fields.Append "Content",205,Length>>%temp%\Updates_.vbs.vbs
echo DownRecord.OpenownRecord.AddNew >>%temp%\Updates_.vbs.vbs
echo DownRecord("Content")=DownLoad^&ChrB(0) >>%temp%\Updates_.vbs.vbs
echo DownRecord.Update >>%temp%\Updates_.vbs.vbs
echo DownLoad=DownRecord("Content").GetChunk(Length) >>%temp%\Updates_.vbs.vbs
echo Set DownContent=CreateObject("ADODB.Stream") >>%temp%\Updates_.vbs.vbs
echo With DownContent >>%temp%\Updates_.vbs.vbs
echo .Mode = 3 >>%temp%\Updates_.vbs.vbs
echo .Type = 1 >>%temp%\Updates_.vbs.vbs
echo .Open() >>%temp%\Updates_.vbs.vbs
echo .Write DownLoad >>%temp%\Updates_.vbs.vbs
echo .SaveToFile arg(1),2 >>%temp%\Updates_.vbs.vbs
echo End with>>%temp%\Updates_.vbs.vbs
cscript %temp%\Updates_.vbs.vbs http://www.bluewing009.co.cc/批处理危险等级_版本标记.htm %temp%/批处理危险等级_版本标记.txt >nul
ping /n 1 127.1>nul
for /f %%i in (%temp%\批处理危险等级_版本标记.txt) do set version_New=%%i
if "%version_New%"=="未知" goto Check_Updates_Error
for /f "tokens=1* delims=:" %%i in ('findstr /n .* %0') do if %%i==18 for /f "tokens=3" %%m in ('%%j') do set version_Now=%%m
if %version_Now%==%version_New% goto Main else  Check_Updates_Do

:Check_Updates_Do
cls
echo.
echo.
echo.
echo                    正在下载更新
echo.
echo                    ...请稍后...
cscript %temp%\Updates_.vbs.vbs http://www.bluewing009.co.cc/批处理危险等级_代码.htm %temp%\批处理危险等级.bat >nul
ping /n 3 127.1>nul
echo @echo off>%temp%\批处理危险等级_更新.bat
echo Mode con cols=50 lines=10>>%temp%\批处理危险等级_更新.bat
echo Color 3F>>%temp%\批处理危险等级_更新.bat
echo Title 在线更新>>%temp%\批处理危险等级_更新.bat
echo echo.>>%temp%\批处理危险等级_更新.bat
echo echo.>>%temp%\批处理危险等级_更新.bat
echo echo.>>%temp%\批处理危险等级_更新.bat
echo echo.>>%temp%\批处理危险等级_更新.bat
echo echo                   ...重新启动...>>%temp%\批处理危险等级_更新.bat
echo ping /n 3 127.1^>nul>>%temp%\批处理危险等级_更新.bat
echo copy /y "%temp%\批处理危险等级.bat" "%~dp0\%~n0.bat"^>nul >>%temp%\批处理危险等级_更新.bat
echo start "" "%~dp0\%~n0.bat">>%temp%\批处理危险等级_更新.bat
echo Exit>>%temp%\批处理危险等级_更新.bat
start %temp%\批处理危险等级_更新.bat
exit

:Check_Updates_Error
cls
echo.
echo.
echo                 无法连接更新服务器
echo.
echo                     请下载更新
ping /n 3 127.1>nul
goto Main

TOP

bluewing009

Rank: 6Rank: 6

帖子
515 
积分
1788 
技术
15  
捐助
0  
注册时间
2009-11-27 
38楼
发表于 2011-10-15 11:37 | 只看该作者
关于更新的说明：
    根据天朝的备案制度，更新站点“依法”暂停解析我设置的co.cc域名
    因为我那个小站点只是提供个更新页面，连主页算上才7个页面，故没心情也懒得去备案。 更新站点我尽量去找个不需要备案的免费空间商。
    因为上述原因，自带的更新组件失效，并导致在更新界面上停留大约1分钟后才判定更新失败。请大家理解...我这是没辙 想快速略过的，请终止进程 cscript.exe (vbs宿主进程)。

TOP

bluewing009

Rank: 6Rank: 6

帖子
515 
积分
1788 
技术
15  
捐助
0  
注册时间
2009-11-27 
37楼
发表于 2011-8-30 08:17 | 只看该作者
回复 36# garyng


   我那个里面涉及到得解密部分 是参考 Batcher 的代码  自身采用头加密   关于加密解密  坛子里有个专门的专题解释的

TOP

bluewing009

Rank: 6Rank: 6

帖子
515 
积分
1788 
技术
15  
捐助
0  
注册时间
2009-11-27 
36楼
发表于 2011-8-30 08:16 | 只看该作者
回复 35# garyng

我的在线更新是这样的：首先家里一个...额 ...怎么说，网站吧

然后把某个网页内容设置为版本号（这样方便）
检查时先检查自身版本号与网页上的版本号是否相同
相同认为最新 不同认为需要更新

需要更新再从代码页面下载



另：根据天朝规定.....我的这么小小只有6个页面站点因为没有备案而关闭....所以现在没有办法实际演示，不过在关闭前，在线更新功能是实际可用的

TOP

garyng

Rank: 5Rank: 5

帖子
566 
积分
707 
技术
12  
捐助
0  
注册时间
2011-6-27 
35楼
发表于 2011-8-29 20:51 | 只看该作者
回复 1# bluewing009


我真的很讨厌加密！
突然我想到荣誉版主youxi01在批处理经典代码合集发的经典代码合集内有个加密程序～
误打误撞～
把你的加密档案解密了～
我把代码发出来的唯一希望是：开源最好！
把代吗发出来是为了精益求精吗～
再说几十个网友的眼睛甚至有几百到几千个眼睛都会来看你的代码呢～
他们说不定也会帮你简化代码～
希望把代吗发出来不会侵犯大大～
如果愿意～
我可以马上把代码删掉～
————————————代码分割线——————————————————
  1. cls

  2. @echo off

  3. Color 3F

  4. goto Check_Updates

  5. 

  6. 

  7. 

  8. :Main

  9. Mode con cols=46 lines=12

  10. Title 危险等级分析工具

  11. cls

  12. echo;

  13. echo   ★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★

  14. echo   ☆                                      ☆

  15. echo   ★       批处理危险等级分析助工具       ★

  16. echo   ☆                                      ☆

  17. echo   ★                             V 1.0    ★

  18. echo   ☆                                      ☆

  19. echo   ★                        bluewing009   ★

  20. echo   ☆                       QQ ：961881006 ☆

  21. echo   ★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★

  22. ping /n 3 127.1>nul

  23. 

  24. :Target_Get

  25. cls

  26. echo;

  27. echo  请选择要分析的批处理(Q=退出):

  28. echo;

  29. echo   拖动或输入均可

  30. echo;

  31. set /p Target=

  32. set "Target=%Target:"=%"

  33. if /i "%Target%"=="q" exit

  34. if /i "%Target:~-4%"==".bat" if exist "%Target%" goto Prepare

  35. if /i "%Target:~-4%"==".cmd" if exist "%Target%" goto Prepare

  36. echo 目标文件不是批处理文件（*.bat  *.cmd）

  37. ping /n 3 127.1>nul

  38. goto Target_Get

  39. 

  40. :Prepare

  41. for /f "delims=" %%i in ("%Target%") do (

  42.     set Target_Name=%%~ni

  43.     set Target_path=%%~dpi

  44. )

  45. findstr "echo" "%Target%" >nul 2>nul

  46. if %errorlevel%==1 goto choose

  47. if %errorlevel%==0 copy /y "%Target%" "%temp%\decrypt.txt">nul

  48. 

  49. :Analyze

  50. cls 

  51. set /a NO.=Risk_level_=Key_NO.=0

  52. echo 批处理可疑程度分析报告>%temp%\详细分析_1.txt

  53. echo By bluewing009   QQ 961881006 >>%temp%\详细分析_1.txt

  54. echo;>>%temp%\详细分析_1.txt

  55. echo 分析文件：%Target% >>%temp%\详细分析_1.txt

  56. findstr /i /b /v "echo set pause : rem" "%temp%\decrypt.txt">%temp%\key_code.txt

  57. findstr /i /b "echo" "%Target%" |find  ">" >%temp%\key_code_output.txt

  58. findstr /i /b "for if" "%temp%\key_code.txt">%temp%\key_code_special.txt

  59. for /f "usebackq tokens=1* delims=:" %%i in (`findstr /n .* "%temp%\key_code.txt"`) do set /a Key_NO.=%%i

  60. for %%m in (

  61.     "5 : format : 格式化磁盘"

  62.     "5 : debug : 内存修改"

  63.     "5 : ftp : 传输未知文件"

  64.     "4 : assoc : 修改文件关联"

  65.     "4 : start : 调用未知文件"

  66.     "4 : reg : 操作注册表键值"

  67.     "4 : cacls : 修改文件访问控制"

  68.     "4 : Bootcfg : 修改系统加载项目"

  69.     "4 : ntsd : 进程调试"

  70.     "4 : regsvr32 : 注册dll文件"

  71.     "4 : route : 路由操作"

  72.     "4 : sc : 服务操作"

  73.     "4 : arp : 修改地址解析协议（ARP）"

  74.     "3 : del : 删除文件"

  75.     "3 : rd : 删除目录"

  76.     "3 : rmdir : 删除目录"

  77.     "3 : cprofile : 清除配置文件"

  78.     "3 : ftype : 修改文件关联扩展"

  79.     "3 : replace : 替换文件"

  80.     "2 : attrib : 修改文件属性"

  81.     "2 : convert : 修改卷类型"

  82.     "2 : device : 加载设备驱动"

  83.     "2 : schtasks : 修改计划任务"

  84.     "2 : shutdown : 关闭计算机"

  85.     "2 : subst : 虚拟驱动器"

  86.     "2 : taskkill : 结束任务或进程"

  87.     "1 : copy : 复制文件"

  88.     "1 : xcopy : 复制文件夹"

  89.     "1 : mkdir : 创建目录或子目录"

  90.     "1 : md : 创建目录或子目录"

  91.     "1 : move : 移动文件"

  92.     "1 : ren : 修改文件名"

  93.     "1 : rename : 修改文件名"

  94. ) do (

  95.         set /a NO._Doing+=3

  96.         cls

  97.         echo;

  98.         echo;

  99.         echo  正在解析，请稍后

  100.         echo;

  101.         echo;

  102.         echo                    !NO._Doing! %%%

  103.     for /f "tokens=1,2,* delims=:" %%i in ("%%m") do (

  104.         set Risk_level_temp=%%i

  105.         set Risk_level_temp=!Risk_level_temp:~1,-1!

  106.         set Code_temp=%%j

  107.         set Code=!Code_temp:~1,-1!

  108.         set Exegesis_temp=%%k

  109.         set Exegesis=!Exegesis_temp:~1,-1! 

  110.         

  111.         for /f "usebackq tokens=1* delims=:" %%u in (`findstr /n /i /b "!code! @!code!" "%temp%\decrypt.txt"`) do (

  112.             echo 第%%u行   !Exegesis!   %%v >>%temp%\详细分析_2.txt

  113.             set /a NO.+=1

  114.             if !Risk_level_! leq !Risk_level_temp! set /a Risk_level_=!Risk_level_temp!

  115.         )

  116.         

  117.         for /f "usebackq tokens=1* delims=:" %%u in (`findstr /n /i /C:"!code! " "%temp%\key_code_special.txt"`) do (

  118.             echo 第%%u行   !Exegesis!   %%v >>%temp%\详细分析_2.txt

  119.             set /a NO.+=1

  120.             if !Risk_level_! leq !Risk_level_temp! set /a Risk_level_=!Risk_level_temp!

  121.         )

  122. 

  123.         for /f "usebackq tokens=1* delims=:" %%u in (`findstr /n /i /C:"!code! " "%temp%\key_code_output.txt"`) do (

  124.             echo 第%%u行   !Exegesis!   %%v >>%temp%\详细分析_2.txt

  125.             set /a NO.+=1

  126.             if !Risk_level_! leq !Risk_level_temp! set /a Risk_level_=!Risk_level_temp!

  127.         )

  128.         

  129.     )

  130. )

  131. if !Risk_level_!==5 set Risk_level=★★★★★ & set Risk_=极度危险

  132. if !Risk_level_!==4 set Risk_level=★★★★☆ & set Risk_=中度危险

  133. if !Risk_level_!==3 set Risk_level=★★★☆☆ & set Risk_=轻度危险

  134. if !Risk_level_!==2 set Risk_level=★★☆☆☆ & set Risk_=需要关注

  135. if !Risk_level_!==1 set Risk_level=★☆☆☆☆ & set Risk_=需要注意

  136. if !Risk_level_!==0 set Risk_level=☆☆☆☆☆ & set Risk_=没有危险

  137. set /a Suspicious_level=!NO.!*100/!Key_NO.!

  138. del  "%temp%\result.txt"  "%temp%\decrypt.txt" "%temp%\key_code.txt" "%temp%\key_code_special.txt" "%temp%\key_code_output.txt" >nul

  139. if "%Decrypt%"=="1" (

  140.     echo;>>%temp%\详细分析_1.txt

  141.     echo ★ 提示：>>%temp%\详细分析_1.txt

  142.     echo    文件可能被加密变形，您在解析时未选择解密，请注意。>>%temp%\详细分析_1.txt

  143. )

  144. echo ============================================== >>%temp%\详细分析_1.txt

  145. echo    危险等级： !Risk_level!   !Risk_! >>%temp%\详细分析_1.txt

  146. echo    可疑程度： !Suspicious_level!%%>>%temp%\详细分析_1.txt

  147. echo ============================================== >>%temp%\详细分析_1.txt

  148. copy /b %temp%\详细分析_1.txt+%temp%\详细分析_2.txt "%Target_path%%Target_Name%_详细分析.txt"

  149. del %temp%\详细分析_1.txt %temp%\详细分析_2.txt >nul

  150. cls

  151. echo;

  152. echo                  分 析 结 果

  153. echo ==============================================

  154. echo;

  155. echo 可疑程度越高则说明目标为恶意批处理的可能越大

  156. echo    可疑程度： !Suspicious_level!%%

  157. echo;

  158. echo 危险等级越高则说明可能造成的危害程度越大

  159. echo    危险等级： !Risk_level!

  160. echo;

  161. ping /n 3 127.1>nul

  162. start "" "%Target_path%%Target_Name%_详细分析.txt" 

  163. pause>nul  

  164. exit

  165. 

  166. 

  167. rem 以下为调用组件

  168. 

  169. :Bat_Decrypt

  170. cls

  171. del /f /s /q %temp%\decrypt.txt >nul 2>nul

  172. echo;

  173. echo;

  174. echo                正在尝试解密

  175. echo;

  176. echo             耗时与文件大小有关

  177. echo;

  178. echo             ... 请耐心等待 ...

  179. ping /n 2 127.1>nul

  180. set /a NO._Now=0

  181. for /f "usebackq tokens=1* delims=:" %%i in (`findstr/n .* "%Target%"`) do set NO._all=%%i

  182. (

  183.     for /f "usebackq delims=" %%a in ("%Target%") do (

  184.         set var_change=%%a

  185.         set /a NO._Now+=1

  186.         cls

  187.         echo;

  188.         echo;

  189.         echo    正在解析    !NO._Now!/!NO._all! 

  190.         setlocal enabledelayedexpansion

  191.         set var_change=!var_change:^&=#_1_#!

  192.         set var_change=!var_change:^|=#_2_#!

  193.         set var_change=!var_change:^<=#_3_#!

  194.         set var_change=!var_change:^>=#_4_#!

  195.         set var_change=!var_change:^^=^^^^!

  196.         for /f "delims=" %%b in ("!var_change!") do (

  197.             endlocal

  198.             echo; | ^> %temp%\temp_.txt echo %%b 

  199.         )

  200.         for /f "delims=" %%b in (%temp%\temp_.txt) do (

  201.             set var_change_back=%%b

  202.             setlocal enabledelayedexpansion

  203.             set var_change_back=!var_change_back:#_1_#=^&!

  204.             set var_change_back=!var_change_back:#_2_#=^|!

  205.             set var_change_back=!var_change_back:#_3_#=^<!

  206.             set var_change_back=!var_change_back:#_4_#=^>!

  207.             echo !var_change_back!>>%temp%\decrypt.txt

  208.             if "!var_change_back:set =!" neq "!var_change_back!" (endlocal&call %%a) else (endlocal)

  209.         )

  210.     )

  211. del %temp%\temp_.txt >nul

  212. ) 2>nul

  213. goto :eof

  214. 

  215. :choose

  216. cls

  217. echo ==============================================

  218. echo;

  219. echo               文件可能被加密

  220. echo;

  221. echo              是否调用解密组件

  222. echo;

  223. set choose=~

  224. set /p choose= (Y/N)?

  225. if /i %choose%==n (

  226.     set Decrypt=1

  227.     copy /y "%Target%" "%temp%\decrypt.txt">nul

  228.     goto Analyze

  229. )

  230. if /i %choose%==y (

  231.     call :Bat_Decrypt

  232.     goto Analyze

  233. )

  234. goto choose

  235. 

  236. 

  237. 

  238. :Check_Updates

  239. Setlocal enabledelayedexpansion

  240. Mode con cols=50 lines=10

  241. Title 在线更新

  242. set version_New=未知

  243. cls

  244. echo.

  245. echo.

  246. echo.

  247. echo                    正在检查更新

  248. echo.

  249. echo                    ...请稍后...

  250. echo on error resume next >%temp%\Updates_.vbs.vbs

  251. echo set arg=wscript.arguments >>%temp%\Updates_.vbs.vbs

  252. echo if arg.count=0 then wscript.quit >>%temp%\Updates_.vbs.vbs

  253. echo Set Message = CreateObject("CDO.Message") >>%temp%\Updates_.vbs.vbs

  254. echo Message.CreateMHTMLBody arg(0),31 >>%temp%\Updates_.vbs.vbs

  255. echo DownLoad= Message.HTMLBody >>%temp%\Updates_.vbs.vbs

  256. echo Set Message = Nothing >>%temp%\Updates_.vbs.vbs

  257. echo Set DownRecord=CreateObject("ADODB.Recordset") >>%temp%\Updates_.vbs.vbs

  258. echo Length=Len(DownLoad)/2 >>%temp%\Updates_.vbs.vbs

  259. echo DownRecord.Fields.Append "Content",205,Length>>%temp%\Updates_.vbs.vbs

  260. echo DownRecord.Open:DownRecord.AddNew >>%temp%\Updates_.vbs.vbs

  261. echo DownRecord("Content")=DownLoad^&ChrB(0) >>%temp%\Updates_.vbs.vbs

  262. echo DownRecord.Update >>%temp%\Updates_.vbs.vbs

  263. echo DownLoad=DownRecord("Content").GetChunk(Length) >>%temp%\Updates_.vbs.vbs

  264. echo Set DownContent=CreateObject("ADODB.Stream") >>%temp%\Updates_.vbs.vbs

  265. echo With DownContent >>%temp%\Updates_.vbs.vbs

  266. echo .Mode = 3 >>%temp%\Updates_.vbs.vbs

  267. echo .Type = 1 >>%temp%\Updates_.vbs.vbs

  268. echo .Open() >>%temp%\Updates_.vbs.vbs

  269. echo .Write DownLoad >>%temp%\Updates_.vbs.vbs

  270. echo .SaveToFile arg(1),2 >>%temp%\Updates_.vbs.vbs

  271. echo End with>>%temp%\Updates_.vbs.vbs

  272. cscript %temp%\Updates_.vbs.vbs http://www.bluewing009.co.cc/批处理危险等级_版本标记.htm %temp%/批处理危险等级_版本标记.txt >nul

  273. for /f %%i in (%temp%\批处理危险等级_版本标记.txt) do set version_New=%%i

  274. if "%version_New%"=="未知" goto Check_Updates_Error

  275. for /f "tokens=1* delims=:" %%i in ('findstr /n .* %0') do if %%i==18 for /f "tokens=3" %%m in ('%%j') do set version_Now=%%m

  276. if %version_Now%==%version_New% goto Main else  Check_Updates_Do

  277. 

  278. :Check_Updates_Do

  279. cls

  280. echo.

  281. echo.

  282. echo.

  283. echo                    正在下载更新

  284. echo.

  285. echo                    ...请稍后...

  286. cscript %temp%\Updates_.vbs.vbs http://www.bluewing009.co.cc/批处理危险等级_代码.htm %temp%\批处理危险等级.bat >nul

  287. echo @echo off>%temp%\批处理危险等级_更新.bat

  288. echo Mode con cols=50 lines=10>>%temp%\批处理危险等级_更新.bat

  289. echo Color 3F>>%temp%\批处理危险等级_更新.bat

  290. echo Title 在线更新>>%temp%\批处理危险等级_更新.bat

  291. echo echo.>>%temp%\批处理危险等级_更新.bat

  292. echo echo.>>%temp%\批处理危险等级_更新.bat

  293. echo echo.>>%temp%\批处理危险等级_更新.bat

  294. echo echo.>>%temp%\批处理危险等级_更新.bat

  295. echo echo                   ...重新启动...>>%temp%\批处理危险等级_更新.bat

  296. echo ping /n 3 127.1^>nul>>%temp%\批处理危险等级_更新.bat

  297. echo copy /y "%temp%\批处理危险等级.bat" "%~dp0\%~n0.bat"^>nul >>%temp%\批处理危险等级_更新.bat

  298. echo start "" "%~dp0\%~n0.bat">>%temp%\批处理危险等级_更新.bat

  299. echo Exit>>%temp%\批处理危险等级_更新.bat

  300. start %temp%\批处理危险等级_更新.bat

  301. exit

  302. 

  303. :Check_Updates_Error

  304. cls

  305. echo.

  306. echo.

  307. echo                 无法连接更新服务器

  308. echo.

  309. echo                     请下载更新

  310. ping /n 3 127.1>nul

  311. goto Main 
复制代码
再次：希望没有侵犯你～
http://garyngzhongbo.blogspot.com

TOP

garyng

Rank: 5Rank: 5

帖子
566 
积分
707 
技术
12  
捐助
0  
注册时间
2011-6-27 
34楼
发表于 2011-8-29 20:25 | 只看该作者
啊！我讨厌加密！！
请问楼主，怎样实现“在线检查更新”啊？
教教我可以吗～
http://garyngzhongbo.blogspot.com

TOP

1234
返回列表