【练习-014】出给新手的数值排序加分题

pusofalse

出题目的：
        掌握任意数列之间的排序技巧
解题要求：
        代码通用、高效
        尽量简洁
        尽量不生成临时文件
加分规则：
        1 思路独特基准分5分
        2 代码高效、通用基准分4分
        3 技巧高超基准分3分
        4 代码简洁基准分2分
        5 完美代码加分15分
题目如下：
        给出任意一组数列，正序输出，如：
        3 2008 11 19 777 23 2014 453 789 51
        输出为：3 11 19 23 51 453 777 789 2008 2014
说明：
        不必考虑特大数，所给的数列中都是整数值。

sunraojian

回复 7# terse


    那个set .是什么意思？

愚无尽

居然才是新手的题目，哎，看来。。。

CZT

哈哈
看到这篇贴子
我知道了有一个叫冒泡排序的东西
另外Batcher兄在另外一个贴子里面给了一个学习冒泡排序的连接
让我好好的学习了一把
我现在把它帮到这里来
希望不懂什么叫冒泡排序的朋友也去学习下
http://www.google.cn/search?hl=z ... %E5%BA%8F&meta=

itrui

有些地方正好对我工作有点用处。

[ 本帖最后由 itrui 于 2008-8-23 21:03 编辑 ]

基拉freedom

原帖由 523066680 于 2008-8-22 14:40 发表
以上部分代码考虑了相同的数 有的没有考虑 。有相同的数 只显示了一次。
（嘿！！！！凭什么我写那个跟你想的￥！@#%@##~！#        就只加我2分啊）

这倒是的~~呵呵~~~

523066680

居然没人理我也……17楼的思路是可以完善到 存在重复的数的，
（呜呜 我读书的时候想过这个思路的 估计false也不会考虑给我加分了）
以下是17楼思路的更新版本  允许存在相同的数

@echo off
setlocal enabledelayedexpansion
set hang=3 2008 11 19 777 23 2014 453 789 51 3 3 4 2014
set n=0
for %%a in (%hang%) do (
  set /a num=1,n+=1
  for %%b in (%hang%) do (
    if %%a gtr %%b set /a num+=1
  )
call :next !num!
set !num!=%%a
)
for /l %%a in (1,1,%n%) do echo !%%a!
pause
goto :eof
:next
if defined %num% (set /a num+=1 &goto :next)
复制代码

[ 本帖最后由 523066680 于 2008-8-23 11:37 编辑 ]

pusofalse

只需把9楼的代码稍作调整即可。

@echo off
setlocal EnableDelayedExpansion
for /l %%a in (1 1 10) do set "var=!var!!random! "
echo %var%%
for %%i in (%var%) do (
set "str=   %%i"
set "echo=!echo!echo !str:~-5!&"
)
(%echo:~,-1%)|sort
pause>nul
复制代码

[ 本帖最后由 pusofalse 于 2008-8-22 15:03 编辑 ]

523066680

以上部分代码考虑了相同的数 有的没有考虑 。有相同的数 只显示了一次。
（嘿！！！！凭什么我写那个跟你想的￥！@#%@##~！#        就只加我2分啊）

[ 本帖最后由 523066680 于 2008-8-23 11:41 编辑 ]

batman

原帖由 mkl 于 2008-8-22 09:04 发表
不知是否符合题意@echo off&setlocal enabledelayedexpansion
set "p=3 2008 11 19 777 23 2014 453 789 51"
for %%i in (%p%) do (
   set t=1
   for %%r in (%p%) do (
       if %%i gtr %%r set /a t=!t!+ ...

修改成如下可使代码通用些：

@echo off&setlocal enabledelayedexpansion
set "p=3 2008 11 19 777 23 2014 453 789 51"
for %%i in (%p%) do (
   set /a n+=1,t=1
   for %%r in (%p%) do (
       if %%i gtr %%r set /a t+=1
   ) 
   set !t!=%%i
)
for /l %%i in (1,1,%n%) do set /p=!%%i! <nul
pause>nul
复制代码

[ 本帖最后由 batman 于 2008-8-22 10:51 编辑 ]

基拉freedom

好了
根据版主所说改进了一下
还是用了临时文件 不改了 ~~ ~  通用性增强 最大到10位~~

@echo off
setlocal EnableDelayedExpansion
echo 数组排列
echo.
echo 最大可支持10位 输入时以空格键隔开
echo.
set /p str=输入数组:
echo.
echo 原数组为%str%.
set n=0
for %%i in (%str%) do (
set/a n+=1
set str[!n!]=         %%i
)
for /l %%i in (1,1,%n%) do echo !str[%%i]:~-10!>>1.txt
echo.
echo.
echo 现数组为：
sort 1.txt
set /p a=按回车键结束
del 1.txt
复制代码

batman

一、冒泡法：

@echo off&setlocal enabledelayedexpansion
for %%i in (3 2008 11 19 777 23 2014 453 789 51) do set "str=!str! #%%i#"
set "var=%str%"
for %%a in (%str%) do (
    for %%i in (!var!) do (
        set "a=%%a"&set "b=%%i"
        set "a=!a:#=!"&set "b=!b:#=!"
        if !a! gtr !b! (
        set "var=!var:%%a =!"
        set "var=!var:%%i=%%i %%a!"
        )
    )
)
echo %var:#=%&pause>nul
复制代码

二、补位法：

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1,1,80) do set "bw=!bw!0"
for %%i in (3 2008 11 19 777 23 2014 453 789 51) do (
     set "str=%bw%%%i"
     set "_!str:~-80!=%%i"
)
for /f "tokens=2 delims==" %%i in ('set _') do set /p=%%i <nul
pause>nul
复制代码

[ 本帖最后由 batman 于 2008-8-22 14:18 编辑 ]

mkl

不知是否符合题意

@echo off&setlocal enabledelayedexpansion
set "p=3 2008 11 19 777 23 2014 453 789 51"
for %%i in (%p%) do (
   set t=1
   for %%r in (%p%) do (
       if %%i gtr %%r set /a t=!t!+1
   ) 
set !t!=%%i
)
echo !1! !2! !3! !4! !5! !6! !7! !8! !9! !10!
pause 
复制代码

523066680

问题出来了，
虽然偏方的代码不长，但是如果排序的数字 有几个是相同滴咋办

523066680

原帖由 terse 于 2008-8-21 14:01 发表
还是用补位效率高
…… set .!str:~-10! !random!=%%i……

这里random是否起着一定作用。