批处理列出1000以内回文数

wxcute

[新手练功区的新手跟帖不多，可能是因为题目太难了。各位等等新手两天再回答好了。]
我国古代有一种回文诗，倒念顺念都有意思，例如“人过大佛寺”，倒读起来便是“寺佛大过人”。还有经典的对联“客上天然居，居然天上客”。此种例子举不胜举。

从左向右读与从右向左读完全一样的数字就是回文数，如11、121、767等等。

shelluserwlb

参照9楼的代码，按从小到大的顺序完全列出10000以内的回文数
（效率应该不会差到哪里去的。）

@echo off
set /a total=9
for /l %%i in (1,1,9) do echo %%i%%i
for /l %%i in (1,1,9) do (
    for /l %%j in (0,1,9) do ( 
	echo %%i%%j%%i 
        set /a total+=1
    )
)
for /l %%i in (1,1,9) do (
    for /l %%j in (0,1,9) do ( 
        echo %%i%%j%%j%%i 
        set /a total+=1
    )
)
echo 一万以内共有%total%个回文数！
pause>nul
复制代码

shelluserwlb

参照18楼的代码，改了一下，按从小到大的顺序显示1000以内的回文数（1个数字不能算回文数）。

@echo off
for /l %%i in (1,1,9) do echo %%i%%i
for /l %%i in (1,1,9) do (
    for /l %%j in (0,1,9) do ( 
	echo %%i%%j%%i 
    )
)
pause
复制代码

shelluserwlb

@echo off 
goto :START
我国古代有一种回文诗，倒念顺念都有意思，例如“人过大佛寺”，倒读起来便是“寺佛大过人”。还
有经典的对联“客上天然居，居然天上客”。此种例子举不胜举。
从左向右读与从右向左读完全一样的数字就是回文数，如11、121、767等等。
:START
MODE CON LINES=200
setlocal enabledelayedexpansion
set /a total=0
for /l %%i in (11,1,10000) do (
    set num=%%i
    :: 判断小于1000的数字
    if !num! lss 1000  (
	if "!num:~0,1!"=="!num:~-1,1!" (
	    echo !num! & set /a total+=1  
	)	
    )
   ::判断大于等于1000且小于10000的数字
   if !num! geq 1000  ( if !num! lss 10000 ( 
	if "!num:~0,1!"=="!num:~-1,1!" ( if "!num:~1,1!"=="!num:~2,1!" (
	    echo !num! & set /a total+=1
        ))
    ))
)
echo 一万以内总共有%total%个回文件数。
endlocal & pause>NUL
复制代码

上述是找出10000以内的回文数的批处理代码。

zqy220422

你们是怎么样炼成的啊

悬崖之树

回复 29# 悬崖之树
这个代码有问题，并不是只要测试到六位数就提示“你输入的数太大了”，而是要到类似 “124521” 之类的六位数才会提示。下面是改进后的

@echo off
setlocal enabledelayedexpansion
if exist 1.txt del 1.txt
:ks
set /p num=请输入一个最多5位的正整数：
if %num% gtr 999999 echo 你的数太大了，请重新输入！& goto ks 
for /l %%i in (0,1,%num%) do (
     set a=%%i
     if "!a:~0,1!"=="!a:~-1!"  (
       if "!a:~3,1!"=="" (
         echo !a!>>1.txt
       ) else (
                if "!a:~1,1!"=="!a:~-2,1!" (
                  if "!a:~5,1!"=="" (
                    echo !a!>>1.txt
                  )
                )
         )
     )
)
echo 结果已经保存在当前目录下的1.txt文件中
pause
复制代码

悬崖之树

@echo off
setlocal enabledelayedexpansion

for /l %%i in (0,1,1200) do (
     set a=%%i
     if "!a:~0,1!"=="!a:~-1!"  (
       if "!a:~1,1!"=="" (
         echo !a!>>1.txt
       ) else (
                if "!a:~1,1!"=="!a:~-2,1!" (
                  if "!a:~3,1!"=="" (
                    echo !a!>>1.txt
                  ) else echo 你的数太大啦！&goto  out
                )
         )
     )
)
:out
pause
复制代码

mxxcgzxxx

给个新思路,100000以内回文数
怎么就没人想出这个方案呢？？很容易啊

@echo off
setlocal enabledelayedexpansion
for /l %%i in  (1 1 99) do (
         set /a a=%%i/10+%%i%%10*10+100
         if !a:~-1!==0 (set a=!a:~-2,1!) else (set a=!a:~-2!)
         echo %%i!a!
         for /l %%j in (0 1 9) do echo %%i%%j!a!
         pause>nul
         )
set /a b=99*11
echo 100000以内有%b%个回文数
pause>nul
复制代码

PCL505512957

@if not defined debug @echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 1000) do (
    set /a a=%%i/100
    set /a b=%%i/10-!a!*10
    set /a c=%%i-!a!*100-!b!*10
    if !c! equ !a! (if not !a! equ 0 echo %%i)
)
pause >nul
复制代码

scarcr

回复 1# wxcute

@echo off
setlocal enabledelayedexpansion
for /l %%i in (10 1 999) do (
	set "a=%%i"
	if "!a:~,1!" equ "!a:~-1!" (echo !a!)
	)
pause
复制代码

lxzzr

100以内的就不去“数”了。

@echo off&setlocal enabledelayedexpansion
for /l %%a in (100,1,10000000) do (
set a=%%a
if "!a:~0,1!" == "!a:~-1,1!" (
if "!a:~1,1!" == "!a:~-2,1!" (
if "!a:~2,1!" == "!a:~-3,1!" (
echo !a!
))))
pause
复制代码

sjzong

这个问题如果是每一个数去判断的话，那效率是低点，但是这样求出的数是有顺序的！

@echo off
setlocal enabledelayedexpansion
for %%a in (1 2 3 4 5 6 7 8 9) do (
rem 以下两句是求两位的回文数
 echo %%a%%a
 set/a num+=1
 for %%b in (0 1 2 3 4 5 6 7 8 9) do (
rem 以下两句是求三位的回文数
  echo %%a%%b%%a
  set/a num+=1
rem 以下两句是求四位的回文数
  echo %%a%%b%%b%%a
  set/a num+=1
 )
)
echo 10000以内回文数共有!num!
pause
复制代码

cainiao736

@echo off&setlocal enabledelayedexpansion
for /l %%i in ( 10,1,999 ) do (
set str=%%i
set a=!str:~0,1!
set b=!str:~-1,1!
if "!a!"=="!b!" echo %%i)
pause
复制代码

10000以内的

@echo off&setlocal enabledelayedexpansion
for /l %%i in (10,1,10000) do (
set str=%%i
set a=!str:~0,1!
set b=!str:~-1,1!
set c=!str:~1,1!
set d=!str:~-2,1!
if "!a!"=="!b!" ( if "!c!"=="!d!" echo !str!))
pause
复制代码

[ 本帖最后由 cainiao736 于 2009-4-4 16:45 编辑 ]

keen

简洁10000以内的回文数：

@echo off&setlocal enabledelayedexpansion
for /l %%i in (0 1 10000) do (
    set a=%%i
    if "!a:~0,1!"=="!a:~-1,1!" if !a! lss 1000 (echo !a!) else (if "!a:~1,1!"=="!a:~-2,1!" echo !a!) 
)
pause
复制代码

keen

来个10000以内的回文数：

@echo off&setlocal enabledelayedexpansion
for /l %%i in (0 1 1000) do (
    set a=%%i
    if "!a:~0,1!"=="!a:~-1,1!" echo !a!
)
for /l %%i in (1001 1 10000) do (
    set a=%%i
    if "!a:~0,1!"=="!a:~-1,1!" if "!a:~1,1!"=="!a:~-2,1!" echo !a!
)
pause
复制代码

其实是在1000以内的多加几行。