[游戏娱乐] 批处理纯批处理版贪吃蛇

523066680

运行时直接打开open.bat
控制说明：wasd分别为方向，一开始是默认暂停(p)，按任意键开始游戏
    当按p暂停的时候 也是按任意键开始游戏的。
----------------open.bat--------------

@echo off
start direction.bat
title made by 523066680
:action
color 07
setlocal enabledelayedexpansion
mode con cols=65 lines=35
for /l %%a in (1,1,60) do (set space= !space!)
for /l %%a in (1,1,30) do (set L%%a=%space%)
set /a line=15,col=29,i=0,long=9
:loop
:::::::::::::::控制蛇长，判断是否建立食物部分
if %i% lss %long% (set /a i+=1) else (set i=1)
if defined cut%i% (
     if not defined dot (call :dot)
     !cut%i%:"=!
     set "L%a%=!L%a%:~0,%b%! !L%a%:~%c%!"
     set "%a%_%b%="
)
:pausego
    :::::::显示
    cls
    echo, %space: =_%__
    for /l %%a in (1,1,30) do echo,│!L%%a!│
    echo, %space: =-%--
    echo,- 分数:%fen%00  %echo%
    for /l %%a in (1,1,3) do (ping -n 1 127.0>nul)
::::::::::::::::读取数据，分析部分
:typex
set /p way=<x
if %way%==q (exit)
if %way%==r (endlocal &set echo=按wasd方向键激活。&goto :action) else (set echo=)
if %way%==p (ping -n 2 127.0>nul &set echo=按wasd方向键激活。&goto :pausego) else (set echo=)
if %way%==w (set /a line-=1)
if %way%==s (set /a line+=1)
if %way%==a (set /a col-=1)
if %way%==d (set /a col+=1)
    if defined %line%_%col% (goto :gameover)
    if %line% equ 31 (goto :gameover) 
    if %line% equ 0 (goto :gameover) 
    if %col% equ -1 (goto :gameover) 
    if %col% equ 60 (goto :gameover)
:::::::::::::::设置部分,描点,记录点坐标。
set /a C2=col+1
set "L%line%=!L%line%:~0,%col%!*!L%line%:~%C2%!"
set cut%i%="set /a a=%line%,b=%col%,c=%C2%"
set "%line%_%col%=exist"
if "%line%_%col%"=="%dotl%_%dotc%" (set /a long+=3,fen+=1 &set dot=)
goto :loop
  ::::::::::::建立食物O的调用部分
  :dot
  set /a dotl=%random%%%28+2,dotc=%random%%%58+1
  if defined %dotl%_%dotc% (goto :dot)
  set dot=%dotl%_%dotc%
  set /a dotc2=dotc+1
  set "L%dotl%=!L%dotl%:~0,%dotc%!O!L%dotl%:~%dotc2%!"
  goto :eof
:gameover
echo,p>x
color 0a
ping -n 2 127.0>nul
cls
echo,game over 在控制台按q结束游戏,r再玩一次,然后按任意方向键激活暂停状态
ping -n 3 127.0>nul
endlocal
goto :action
复制代码

--------------------------direction.bat------------------

@echo off &mode con cols=35 lines=8
setlocal enabledelayedexpansion
echo,p>x
for %%a in (w a s d p q) do (set de%%a=defined)
set _w=s
set _s=w
set _a=d
set _d=a
set notequ=have
:a
cls
set /p input="w a s d q(退出) r(重来) p(暂停):"
if "%input%"=="q" (
  echo,q>x
  exit
)
if "%input%"=="r" (
  echo,r>x
)
if "%input%"=="%notequ%" (goto :a)
if not defined de%input% (goto :a)
set notequ=!_%input%!
echo %input%>x
goto :a
复制代码

链接: https://pan.baidu.com/s/1rrTz8U4LULLOnpaoiu8Bsw?pwd=d7mb

cmd1152

回复 39# 008700


   

傻逼

    遇到这种情况请不要直接骂人，否则事大了就不好了。也希望这是我最后一次对你好言相劝。

cmd1152

回复 6# raozhao2008


   

不务正业
批处理是用来玩游戏

    批处理难道不能用来玩游戏吗？你难道没有尝试过写游戏吗？不务正业？那你说批处理不能用来玩游戏？
   

也对，我们的祖先就是这样
中国人只会用火药做鞭炮，那多好玩啊？

    呵呵，看到这真恼火，难道中国人真的只会用火药做鞭炮吗？你怕不是中国人吧？
  

的确，你真的很有能耐

    凭什么不让我们使用批处理写游戏，难道不实用就是不务正业吗？


    希望这是我最后一次对你好言相劝。

008700

回复 6# raozhao2008


    傻逼

q2512426

特别服。。。。。。。。

tl5519254

牛人啊！   必须赞！

卖女孩的小男孩

路过看看，顺便抱走学习

christy23456

好厉害！！！！！！！！强人

狱渊

很不错的游戏啊

狱渊

回复 1# 523066680


    貌似不错的啊

web

创意总是在不断发现

ljfnh403

太快了，半秒就到边了，都反应不过来

523066680

难道是GZUC的ASPER？ 额，又不像……

asp

精彩精彩~~~~~批处理  很强大~

精彩精彩~~~~~批处理  很强大~

精彩精彩~~~~~批处理  很强大~

asp

精彩精彩~~~~~批处理  很强大~

love~~