[文件操作] 修改批处理BAT代码：给子目录文件夹重命名

lzyecho

大家好，又来学习了，请教帮忙修改代码：
我要给当前目录里的文件夹及其子目录（文件夹）重命名，而不影响里面的文件。但是下面的两个代码只能给当前批处理所在的文件夹命名了，而对下层子目录（文件夹）无效，请帮忙给看看。
第一种：

@echo off
setlocal enabledelayedexpansion 
for /f "delims="  %%i in ('dir /ad/b') do (
set /a num+=1       
ren "%%i" "!num!%%i"               
)
echo 处理完毕！按任意键结束。
pause>NUL
复制代码

问题是：代码中 dir /ad/b又不能加参数 /s ,提示说是语法错误？？
第二种：

@echo off
setlocal enabledelayedexpansion
for /r  %%i in (.) do (
ren "%%i" "!num!%%~ni"
set /a num+=1 
) 2>NUL 
echo 处理完毕！按任意键结束。
pause>NUL
复制代码

DAIC

回复 17# lzyecho


http://www.bathome.net/viewthread.php?tid=28866#pid144656

lzyecho

回复 16# terse


      terse ,您好 ，你的代码完美解决了我的问题，第二个代码更简洁！只是对我来说太深了，看不大懂，特别是 这一句  %1(for /f "tokens=*" %%i in ('%~s0 :^|sort /r') do ren %%i)  ，用了参数%1。若有时间麻烦给我逐行解释一下你的设计思路及代码含义，先谢了。

terse

这样省略临时文件

@echo off&setlocal enabledelayedexpansion
%1(for /f "tokens=*" %%i in ('%~s0 :^|sort /r') do ren %%i)&pause&exit
for /f "tokens=*" %%i in ('dir /ad /b /s') do (
    set "file=%%i"
    set "str1=%%~dpi"
    if "!str1!" neq "!str2!" (
       set "n=1"
    ) else set /a n+=1
      echo "!file!" "!n!_%%~nxi"
      set "str2=%%~dpi"
)
复制代码

terse

用临时文件过度下

@echo off&setlocal enabledelayedexpansion
(for /f "skip=2 tokens=*" %%i in ('dir /s /ad') do (
    set "str=%%i"
    if exist "!str:~,-4!\" (
       set "files=!str:~,-4!"&set n=0
    ) else for /f "tokens=*" %%a in ("!str:*>=!") do (
               if exist "!files!\%%~nxa\" if "%%~nxa" neq "" (
                     set /an+=1
                     echo ren "!files!\%%a" "!n!%%a"   
                  )
               )
))>$
sort /r $>Ren_files.cmd
call Ren_files.cmd
del $ Ren_files.cmd
pause
复制代码

lzyecho

回复 12# DAIC


    感谢DAIC给的学习教程及修改后的代码，很实用！！本论坛是我们这些新手学习的好地方，我会经常来报道的。

lzyecho

回复 10# apang


    因为本人对批处理还在初级阶段，只是在表面上编一些简单的代码，希望apang 不要介意，依然感谢你的热心帮助。

DAIC

回复 9# lzyecho

@echo off
setlocal enabledelayedexpansion
set "PathLast="
set "NumCounter="
for /f "delims=" %%a in ('dir /ad /b /s ^| sort /r') do (
    set "file=%%a"
    set "name=%%~nxa"
    set "PathThis=%%~dpa"
    if !PathThis! neq !PathLast! (
        set "NumCounter=0"
    )
    set /a NumCounter+=1
    set "f=!file:%~dp0=!"
    ren "!file!" "!NumCounter!!name!"
    set "PathLast=%%~dpa"
)
复制代码

DAIC

编写代码时 何时要用到变量增加扩展的格式，有没有相应的文章或教程

http://bbs.bathome.net/thread-2899-1-1.html

apang

回复 9# lzyecho


    不明白你说的“每一级目录”是个什么概念
你已经从“修改代码”变成“求代码”了，自己慢慢求去吧

lzyecho

回复 8# apang


    您好，这个代码还是由最内层到最外按数字序列命名的。我的意思是要每一级的目录里的多个文件夹都 是按1、2、3、、、命名的，不同目录里的文件夹没有联系的。再次感谢您。
另外 ，编写代码时 何时要用到变量增加扩展的格式，有没有相应的文章或教程，烦请您介绍一下。

apang

回复 6# lzyecho


    是不是想要这样？

@echo off
for /f "delims=" %%a in ('dir /ad/b/s^|sort /r') do (
    set "file=%%a" & set "name=%%~nxa"
    setlocal enabledelayedexpansion
    set "f=!file:%~dp0=!"
    for %%b in ("!f:\=" "!") do set /a n+=1
    echo,ren "!file!" "!n!!name!"
    endlocal
)
pause
复制代码

煎饼

学习了，这个很实用

lzyecho

回复 5# apang


    感谢回复 ！！，我试了您的代码，发现是把当前目录的文件夹与子目录里的文件夹混合起来按数字序列命名的。这不是理想结果，我想要的是每一级目录中的文件夹都是按数字序列从1开始命名。不知能不能做到？

apang

回复 4# lzyecho


    2楼DAIC已经给你答案了，你仔细琢磨就会明白
顶楼代码可以这样改：

@echo off
for /f "delims="  %%i in ('dir /ad/b/s^|sort /r') do (
    set /a num+=1
    set "file=%%i" & set "name=%%~nxi"
    setlocal enabledelayedexpansion 
    ren "!file!" "!num!!name!"
    endlocal               
)
echo 处理完毕！按任意键结束。
pause>NUL
复制代码