[文本处理] 批处理怎么删除for循环输出的最后一行的逗号？

hello163commail

代码如下：

@echo off
echo {
echo "data":[
for /f "skip=3 tokens=1" %%i in ('tasklist') do echo {"{#FSNAME}":"%%i"},
echo ]
echo }
pause
复制代码

输出如下：
{
"data":[
{"{#FSNAME}":"System"}, #保留这个逗号
{"{#FSNAME}":"System"}, #保留这个逗号
……
{"{#FSNAME}":"tasklist.exe"}, #删除这个逗号
]
}

apang

回复 12# DAIC


    最后两个进程名相同应该不受影响吧？消除重复是lz后来的要求

其实最不严谨的是，进程名有可能会包含空格，还有可能会包含特殊字符，处理起来比较罗嗦

@echo off
(for /f delims^=^" %%a in ('tasklist /nh /fo csv') do (
    if not defined %%a (
        set "%%a=1" & set /a n+=1
        echo,{"{#FSNAME}":"%%a"}
    )
))>$

echo {
echo "data":[
for /f "tokens=1*delims=:" %%a in ('findstr /n .* $') do (
    if "%%a" neq "%n%" (echo,%%b,) else echo,%%b
)
echo ]
echo }
del $
pause
复制代码

DAIC

回复 8# apang


    不是很严谨，因为最后两个进程名可能是相同的。

terse

回复 10# hello163commail
第5行 改为

    if not defined !a! if defined a echo {"{#FSNAME}":"!a!"},
    set "!a!=a
复制代码

hello163commail

回复 9# hello163commail


    如果我要将几个相同的进程变成一个，该怎么做？像这样输出
{
"data":[
{"{#FSNAME}":"System"},
{"{#FSNAME}":"System"}, #删除这行
……
{"{#FSNAME}":"tasklist.exe"}
]
}

hello163commail

回复 8# apang


    好厉害，测试成功，不过没看懂。

apang

@echo off & setlocal enabledelayedexpansion
echo {
echo "data":[
for /f "skip=3" %%i in ('tasklist') do (
    if defined a echo {"{#FSNAME}":"!a!"},
    set "a=%%i"
)
echo,{"{#FSNAME}":"!a!"}
echo ]
echo }
pause
复制代码

hello163commail

回复 6# hlzj88

输出如下
{
"data":[
{"{#FSNAME}":"System"},
{"{#FSNAME}":"System"},
……
{"{#FSNAME}":"tasklist.exe"}, #删除这个逗号
]
}

只是删除最后一个逗号，其他行的逗号保留。

hlzj88

你的代码for语句最后有一个点，去掉我测试没问题

hello163commail

回复 3# Batcher

不好意思，搞错了，源代码是这样的

@echo off
echo {
echo "data":[
for /f "skip=3 tokens=1" %%i in ('tasklist') do echo {"{#FSNAME}":"%%i"},
echo ]
echo }
pause
复制代码

hello163commail

回复 2# hfg1977
搞错了，源代码是这样的:

@echo off
echo {
echo "data":[
for /f "skip=3 tokens=1" %%i in ('tasklist') do echo {"{#FSNAME}":"%%i"},
echo ]
echo }
pause
复制代码

Batcher

逗号从哪里来的？
tasklist输出结果的第一列里面没有逗号吧

hfg1977

WIN7下正常，不存在所指逗号。