[文件操作] 【已解决】BAT批处理如何查找文件并添加内容？

fsxhome

我近期在封装一个安装包，过程中需要在指定的xml文件中添加内容，特来请大侠们，帮写个批处理，好封装进去运行，先拜谢各位了！！

具体要求：
1、先查找“dll.xml文件”
64位系统中，文件位于“C:\Users\用户\AppData\Roaming\Microsoft\FSX”；
XP系统中，文件位于“C:\Documents and Settings\用户名\Application Data\Microsoft\FSX”

2、在"</SimBase.Document>"这一行之前，插入下列内容：
  <Launch.Addon>
    <Name>FSCopilot</Name>
    <Disabled>False</Disabled>
    <Path>Modules\FSCopilot.dll</Path>
  </Launch.Addon>
3、完成之后，在文件中，显示是这个样子的：

fsxhome

回复 26# DAIC


     好的呀，非常感谢！

    有空来我论坛玩玩哦： 模拟飞行之家 www.fsxhome.com.cn

DAIC

回复 25# fsxhome


    不聊qq，有问题就来论坛讨论吧。

fsxhome

回复 24# DAIC


    注册不足24小时，评分受限制，明天来评分哈！


   大神留个QQ给我把，发消息就好了。

DAIC

回复 23# fsxhome


    问题解决后，请编辑顶楼帖子在标题前面注明[已解决]，并给回答者加分。

fsxhome

回复 22# DAIC


    成功了呀，大神，太佩服您了，太感谢您了，非常感谢您的热诚帮助！！！！

DAIC

回复 21# fsxhome

@echo off
if exist "C:\Users\%username%\AppData\Roaming\Microsoft\FSX\dll.xml" (
    set "file=C:\Users\%username%\AppData\Roaming\Microsoft\FSX\dll.xml"
    set "folder=C:\Users\%username%\AppData\Roaming\Microsoft\FSX"
) else if exist "C:\Documents and Settings\%username%\Application Data\Microsoft\FSX\dll.xml" (
    set "file=C:\Documents and Settings\%username%\Application Data\Microsoft\FSX\dll.xml"
    set "folder=C:\Documents and Settings\%username%\Application Data\Microsoft\FSX"
) else (
    echo 找不到文件 dll.xml
    pause
    exit
)
(for /f "usebackq delims=" %%i in ("%file%") do (
    set "str=%%i"
    setlocal enabledelayedexpansion
    if "!str: =!" == "</SimBase.Document>" (
        echo  ^<Launch.Addon^>
        echo    ^<Name^>FSCopilot^</Name^>
        echo    ^<Disabled^>False^</Disabled^>
        echo    ^<Path^>Modules\FSCopilot.dll^</Path^>
        echo  ^</Launch.Addon^>
    )
    echo !str!
    endlocal
))>dll.xml.new
move /y dll.xml.new "%folder%\dll.xml"COPY

fsxhome

回复 20# DAIC


    大侠：

    抱歉，之前是我复制粘贴时，代码格式发生了变化。

   16楼的代码是可以成功执行的，但还是有个问题，他执行后，生成的文件，是在BAT文件所在的位置，不是在原位置。

DAIC

回复 19# fsxhome


把 @echo off 删掉，再执行一次，看看哪一行在报错。
另外，用记事本打开bat，文件，另存为，看看编码是不是ANSI

fsxhome

回复 16# DAIC

提示这错误

DAIC

回复 17# fsxhome


    16楼的代码试过没？

fsxhome

我觉得问题可能是这样的，代码中，可能没有跳过某个命令的字段，是在按顺序查找文件，当执行到下一个查找时，发现没文件，就退出运行了。

也不知道说的对不对，错了勿怪！！！

DAIC

@echo off
if exist "C:\Users\%username%\AppData\Roaming\Microsoft\FSX\dll.xml" (
    set "file=C:\Users\%username%\AppData\Roaming\Microsoft\FSX\dll.xml"
) else if exist "C:\Documents and Settings\%username%\Application Data\Microsoft\FSX\dll.xml" (
    set "file=C:\Documents and Settings\%username%\Application Data\Microsoft\FSX\dll.xml"
) else (
    echo 找不到文件 dll.xml
    pause
    exit
)
(for /f "usebackq delims=" %%i in ("%file%") do (
    set "str=%%i"
    setlocal enabledelayedexpansion
    if "!str: =!" == "</SimBase.Document>" (
        echo  ^<Launch.Addon^>
        echo    ^<Name^>FSCopilot^</Name^>
        echo    ^<Disabled^>False^</Disabled^>
        echo    ^<Path^>Modules\FSCopilot.dll^</Path^>
        echo  ^</Launch.Addon^>
    )
    echo !str!
    endlocal
))>dll.xml.new
move /y dll.xml.new dll.xmlCOPY

fsxhome

开始我还以为运行错了呢，我是WIN8.1的系统，提示这个。

DAIC

回复 13# fsxhome


开始
运行
cmd
C:\test.bat