[原创] 【征集】批处理库函数征集

defanive

征集批处理函数专用贴。。。

此贴用来征集批处理函数的。。。

所谓的函数呢，就是一个标签，里面有编写好的功能，通过call和参数来执行。。。

使用批处理函数可以减少重复的代码，让批处理更简洁。。。

下面给一些库函数做参考，格式可以不按照下面的。。。

这个是计算两点时间差，call :TimePoint Time1 Time2 Var
Var变量里就保存了Time1到Time2的时间差

1.0
CN-DOS Jvive
不需要其他库的支持
TimePoint、TimePoint_1标签
定义了TimePoint标签，用于计算两点时间差
用法 call :TimePoint Point1 Point2 Variable
Point1和Point2是标准时间格式（例如time变量），Point2需大于Point1。两点时间差将保存在Variable变量里。
使用本库的时候可以给参数外加上双引号（如"%time%"），本库会自动处理
使用本库需要保留TimePoint、TimePoint_1标签
使用本库需要开启变量延迟
//**//
:TimePoint
setlocal enableextensions
:TimePoint_1
set "P2=%~1"
set "P2=!P2::=!"
set /a "P2=%P2:.=%-4000*(%P2:~,4%+60*%P2:~,2%)"
if not "%~3"=="" (
        set "P1=!P2!"
        shift
        goto :TimePoint_1
)
if !P2! geq !P1! (
        set /a "df=!P2!-!P1!"
) else (
        set /a "df=!P2!-!P1!+8640000"
)
set /a "h=df/360000,m=df%%360000/6000,s=df%%6000/100,pt=df%%100"
if %pt% leq 9 set "pt=0%pt%"
endlocal&set "%~2=%h%:%m%:%s%.%pt%"
goto:eof
复制代码

下面这个是Ritchie Lawrence写的，也是他最先提出批处理函数这个概念的
这个函数可以将日期转化为星期

1.1
Ritchie Lawrence
不需要其他库的支持
DateToDOW标签
定义了DateToDOW标签，用于将日期转化为星期（1-7）
用法 call :DateToDOW "Year" "Month" "Date" "Variable"
Year为年，Month为月，Date为日。星期（1-7）将保存在Variable变量里。
使用本库的时候可以给参数外加上双引号（如"2009"），本库会自动处理
使用本库需要保留DateToDOW标签
//**//
:DateToDOW
setlocal ENABLEEXTENSIONS
set "yy=%~1"
set "mm=%~2"
set "dd=%~3"
if 1%yy% LSS 200 if 1%yy% LSS 170 (set "yy=20%yy%") else (set "yy=19%yy%")
set /a "dd=100%dd%%%100,mm=100%mm%%%100"
set /a "z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2"
set /a "dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1"
endlocal&set "%~4=%dow%"
goto :EOF
复制代码

大家多写点批处理函数发上来，谢谢了。。。。

Batcher

回复 19# yzlsc


    http://www.bathome.net/thread-3328-1-1.html

yzlsc

翻译的中文版里面哪个函数在中文系统中会出错？
Batcher 发表于 2009-2-3 12:02

比如GetDate函数，用于获取本地系统日期，我进行了如下修改，否则在我的windows XP sp3系统中测试出错：

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:GetDate yy mm dd
::
:: 作者：Ritchie Lawrence, 2002-06-15. 版本 1.0
::
:: 功能：把本地系统日期赋值给参数 1 到 3。
:: 适用于 NT4/2000/XP/2003.
:: 
:: 参数：%1 该变量用于接收年，四位（引用调用）
:: %2 该变量用于接收月，两位，01 到 12（引用调用）
:: %3 该变量用于接收日，两位，01 到 31（引用调用）
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
setlocal ENABLEEXTENSIONS
::set t=2&if "%date%z" LSS "A" set t=1
::for /f "skip=1 tokens=2-4 delims=(-)" %%a in ('echo/^|date') do (
:: for /f "tokens=%t%-4 delims=.-/ " %%d in ('date/t') do (
:: set %%a=%%d&set %%b=%%e&set %%c=%%f))
set "first=" 
for /f "tokens=1-3 delims=.-/ " %%a in ('date/t') do (
if not defined first set first=1&set yy=%%a&set mm=%%b&set dd=%%c)
endlocal&set %1=%yy%&set %2=%mm%&set %3=%dd%&goto :EOF
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
复制代码

wangtao6312

先顶在说啊

基拉freedom

用批处理加到外部库 的确很好很强大

wxcute

判断文件/目录/不存在

::判断指定路径代表的是文件、目录还是不存在。
::
::isF <文件/目录> [合格路径] [标志]
::　　<文件/目录>　　 要判断的路径。
::　　　　　　　　　　最后一个字符可以是“\”，方便用于处理“%~dp0”等后面跟有斜杠的路径。
::　　合格路径　　　　返回变量，默认为 Fn。处理后其值最后一个字符定不是“\”。
::　　标志　　　　　　返回变量，默认为 isFF。含义如下：
::　　　　　　　　　　文件/目录/不存在
::　　　　　　　　　　1　/　2 /0
::
::isF C:\boot.ini
::isF "C:\WINDOWS\" NEW_PATH
::isF "D:\SOFT" QUA_PATH FILE_OR_DIR_FLOG
::
setlocal
set "$FF_path=%~1"
if "%~2"=="" (set $Fn=Fn)else set $Fn=%~2
if "%~3"=="" (set $isFF=isFF)else set $isFF=%~3
if "%$FF_path:~-1%"=="\" set "$FF_path=%$FF_path:~,-1%"
if exist "%$FF_path%\" (set $isF=2)else (
　if exist "%$FF_path%" (set $isF=1)else set $isF=0
)
endlocal&set %$Fn%=%$FF_path%&set %$isFF%=%$isF%
goto :eof
复制代码

判断文件属性

::判断文件/目录的属性。
::
::Atn <文件/目录> [属性]
::　　<文件/目录>　 指定文件/目录
::　　属性　　　　　返回变量，默认为att。
::
::CALL Atn.BAT C:\BOOT.INI
::Atn "%WINDIR%\NOTEPAD.EXE" FILE_ATTRIBUTE
::
setlocal
if "%~2"=="" (set $att=att)else set $att=%~2
set $atbt=%~a1
endlocal&set %$att%=%$atbt%
goto :eof
复制代码

判断分区文件系统

::判断文件系统类型（CHKNTFS 法）
::
::FSt <分区> [类型]
::　　<分区>　　带冒号的分区盘符。
::　　类型　　　返回变量，默认为FStye。代表分区类型。
::
::FSt C:
::FSt H:\ FILE_SYSTEM_TYPE
::
setlocal
set "$Drv=%~1"
if "%~2"=="" (set $FStye=FStye)else set $FStye=%~2
if "%$Drv:~-1%"=="\" set "$Drv=%$Drv:~,-1%"
for /f "tokens=2 delims=。 " %%t in ('"chkntfs %$Drv%|find "类型""') do (
　set $type=%%t
)
::set $type=%$type:~,-1%
endlocal&set %$FStye%=%$type%
goto :eof
复制代码

::判断文件系统类型（FSUTIL 法）
::
::FSt2 <分区> [类型]
::　　<分区>　　带冒号的分区盘符。
::　　类型　　　返回变量，默认为FStye。代表分区类型。
::
::FSt2 C:
::FSt2 G:\ FILE_SYSTEM_TYPE
::
setlocal
set "$Drv=%~1"
if "%~2"=="" (set $FStye=FStye)else set $FStye=%~2
if "%$Drv:~-1%"==":" set "$Drv=%$Drv%\"
for /f "tokens=2 delims=: " %%t in ('"fsutil fsinfo volumeinfo %$Drv%|find "系统名""') do (
　set $type=%%t
)
endlocal&set %$FStye%=%$type%
goto :eof
复制代码

freeback

希望在以后能多增加一些库函数

xouou_53320

感谢楼主分享 顶上去

Batcher

对于网管来说，还是有点用的：）

BBCC

batcher要做双面人啊,囧.

defanive

不过网络类的实用价值不大。。。

Batcher

经测试，GetOS在中文版系统上确实有问题。
HAT已经更新了电子书。
我也重新上传了附件。
感谢分享。

另，网络类的函数没有问题。

defanive

GetOS有问题，网络类的函数没测试，不过估计都是有问题的了。。。

findstr查找的单词是英文的，在中文系统上都换成中文了。。。

Batcher

能否举例说明一下哪个不适用？也好让 HAT 去修改一下^_^

defanive

有些不适用，而且很多用处也不大。。。。