[问题求助] [已解决]VBS如何读取unicode编码的inf文件里等号后面的内容

yuanyannian

求助---VBS如何读取 inf 文件等号后面的内容 并赋给变量

问题描述：还是处理 unicode 格式的 inf 文件，比如：

  aaa.inf
   [Strings]
   BIOS = "abcd-abcd"
   TIDS  = ABCD

用 vbs （也要求是 unicode 格式）读取 BIOS 及 TIDS 等号后面的内容，并分别赋给变量 str1 和 str2

谢谢！

yuanyannian

回复 28# apang

可以了，非常感谢！

apang

回复 27# yuanyannian


    第25行下面插入一行：

regData = chr(34) & Replace(regData, chr(34), "") & chr(34)COPY

第23行改成：

re.Pattern = "^ *" & arField(i) & " *= *([^\r\n]+)"COPY

yuanyannian

回复 26# apang

是的，都是字符串 - REG_SZ 的。

apang

回复 25# yuanyannian


    不带双引号还是 REG_SZ 类型吗？你不说清楚那我只考虑一种类型，不考虑其它类型或其它特殊情况

yuanyannian

回复 23# apang

再麻烦 apang 老师，测试中发现一个问题：当源文件等号后面的数据没有 "" 情况下，无法读出及写入注册表文件。

yuanyannian

回复 23# apang

有道理，那我采用写入注册表文件。

apang

回复 22# yuanyannian


    代码是先找到 Strings 节，再在Strings节中找相应的字段。
比如 BIOS 字段，在Strings中有，在其它节也可能有。
如果去掉Strings节名，找到的可能就不正确，你希望这样吗？

yuanyannian

这样也好，19楼的代码不能写入 HKLM 应该是对该根键没有权限造成的，路径写入 HKLM 的子键中是则可以。
再次谢谢 apang 老师。

再请问，如果不需要搜索 [strings], 去掉那些代码？

apang

回复 19# yuanyannian


    还是保存到reg文件吧，少一点弯弯绕

Dim s1, s2, strSection, arField, arValue, arPath
s1 = "HKEY_CURRENT_USER\"
s2 = "HKEY_LOCAL_MACHINE\"
strSection = "Strings"
arField = Array("BIOS", "NDIS", "GULIM")
arValue = Array("yyn1", "yyn2", "yyn3")
arPath = Array(s1 & "yyn\Desktop", s1 & "yyn\Test", s2 & "Software\Test\yyn")
 
Dim fso, txt, re, i, regData
Set fso = CreateObject("Scripting.FileSystemObject")
txt = fso.OpenTextFile("HIVESFT.INF", 1, false, -1).ReadAll
txt = txt & vbCrLf & "["
 
Set re = New RegExp
re.Pattern = "^ *\[" & strSection & "] *$[\s\S]*?(?=^ *\[)"
re.IgnoreCase = true
re.Global = true
re.MultiLine = true
If Not re.Test(txt) Then WScript.Quit
txt = re.Execute(txt)(0)
 
For i = 0 to UBound(arField)
        re.Pattern = "^ *" & arField(i) & " *= *("".*"")"
        If re.Test(txt) Then
                regData = re.Execute(txt)(0).SubMatches(0)
                s = s & "[" & arPath(i) & "]" & vbCrLf
                s = s & """" & arValue(i) & """=" & regData & vbCrLf
                s = s & vbCrLf
        End If
Next
 
s = "Windows Registry Editor Version 5.00" & vbCrLf & vbCrLf & s
fso.OpenTextFile("Result.reg", 2, true, -1).Write sCOPY

yuanyannian

提示现象是我把 regWMI.CreateKey HKCU, regPath1 搞错了。

另外，我把 HKCU 改成 HKLM ，把  Const HKCU = &H80000001 改为     Const HKLM = &H80000002，失败。

yuanyannian

回复 18# apang

是这样吗？

Dim fso, txt, re, m, regPath, regValue, regData
Set fso = CreateObject("Scripting.FileSystemObject")
txt = fso.OpenTextFile("HIVESFT.INF", 1, false, -1).ReadAll
txt = txt & vbCrLf & "["
 
Set re = New RegExp
re.Pattern = "^ *\[Strings] *$[\s\S]*?(?=^ *\[)"
re.IgnoreCase = true
re.Global = true
re.MultiLine = true
If Not re.Test(txt) Then WScript.Quit
txt = re.Execute(txt)(0)
re.Pattern = "^ *(BIOS|NDIS|NETWORK_DDE|NETWORK_DDE_DESCRIPTION|NETWORK_DDE_DSDM) *= *(.+)"
For Each m in re.Execute(txt)
    regData = Replace(m.SubMatches(1), chr(34), "")
    If UCase(m.SubMatches(0)) = "BIOS" Then
        regPath = "yyn\Desktop"
        regValue = "yyn1"
    End If
    If UCase(m.SubMatches(0)) = "NDIS" Then
        regPath = "yyn\Desktop\yyn"
        regValue = "yyn2"
    End If
    If UCase(m.SubMatches(0)) = "NETWORK_DDE" Then
        regPath = "yyn\Test"
        regValue = "yyn3"
    End If
    If UCase(m.SubMatches(0)) = "NETWORK_DDE_DESCRIPTION" Then
        regPath = "yyn\Test\yyn"
        regValue = "yyn4"
    End If
    If UCase(m.SubMatches(0)) = "NETWORK_DDE_DSDM" Then
        regPath = "yyn\yyn\yyn"
        regValue = "yyn5"
    End If
    WriteToRegValue regPath, regValue, regData
Next
 
Sub WriteToRegValue(ByVal regPath, ByVal regValue, ByVal regData)
    Const HKCU = &H80000001
    Dim regWMI
    Set regWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\Default:StdRegProv")
    regWMI.CreateKey HKCU, regPath1
    regWMI.SetStringValue HKCU, regPath, regValue, regData
End SubCOPY

但提示：

另外，在 re.Pattern = "^ *(BIOS|NDIS|NETWORK_DDE|NETWORK_DDE_DESCRIPTION|NETWORK_DDE_DSDM) *= *(.+)" 中，如果需要几十个变量，该如何处理？

apang

回复 17# yuanyannian


    已修改，如果想自定义，更改相应变量的值即可

yuanyannian

回复 16# apang

谢谢 apang 老师出手，读、写均正常。
不过，我的需求是：只读出 =  后面的内容作为变量，写入注册表中的路径、键值是需要自定义的，比如 HKCU\yyn\Desktop, yyn(键值), BIOS 或 NDIS (还有很多其它的) = 后面的内容(数据), 或者如注册表文件：

[HKEY_CURRENT_USER\yyn\Desktop]
"yyn1"="대한민국 표준시"
"yyn2"="한국어"

或：
[HKEY_CURRENT_USER\yyn\System\Test]
"yyn3"="한국어 입력 시스템 (IME 2000)"
"yyn4"="한"

或者将读出的数据分别写成注册表文件，再自行导入注册表也可。比如写成注册表文件 (unicode 格式)：

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\yyn\Desktop]
"yyn1"="대한민국 표준시"
"yyn2"="한국어"

[HKEY_CURRENT_USER\yyn\System\Test]
"yyn3"="한국어 입력 시스템 (IME 2000)"
"yyn4"="한"

有劳 apang 老师了。

apang

我这里ws.regwrite写入是问号，wmi写入正常，试试看

Dim fso, txt, re, m, regPath, regValue, regData
Set fso = CreateObject("Scripting.FileSystemObject")
txt = fso.OpenTextFile("HIVESFT.INF", 1, false, -1).ReadAll
txt = txt & vbCrLf & "["
 
Set re = New RegExp
re.Pattern = "^ *\[Strings] *$[\s\S]*?(?=^ *\[)"
re.IgnoreCase = true
re.Global = true
re.MultiLine = true
If Not re.Test(txt) Then WScript.Quit
txt = re.Execute(txt)(0)
re.Pattern = "^ *(BIOS|NDIS) *= *(.+)"
For Each m in re.Execute(txt)
        regPath = "yyn\Desktop"
        regData = Replace(m.SubMatches(1), chr(34), "")
        If UCase(m.SubMatches(0)) = "BIOS" Then
                regValue = "yyn1"
        Else
                regValue = "yyn2"
        End If
        WriteToRegValue regPath, regValue, regData
Next
 
Sub WriteToRegValue(ByVal regPath, ByVal regValue, ByVal regData)
        Const HKCU = &H80000001
        Dim regWMI
        Set regWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\Default:StdRegProv")
        regWMI.CreateKey HKCU, regPath
        regWMI.SetStringValue HKCU, regPath, regValue, regData
End SubCOPY