[文本处理] [已解决]批处理怎么提取csv文件中的单元格汇总到一个新的表格里啊？

haichuan5121

一个文件夹下有一堆CSV文件，怎么才能提取每个csv文件中的一个单元格，合并汇总到一个新的表格里啊；
比如附件1.csv 里 我想提取当前文件夹下所有csv文件 D37 的内容 到新表里，怎么实现啊，求大神指教
        Lot Start Time        2011-5-4        4:48:22                               
Lot End Time                2011-5-4        5:12:12                               
Cassette ID                1AC-0999                                       
Lot ID                1AGX140551                                       
Port No.                3                                       
                                                       
Processed Substrate                20                                       
Total Processed Substrate                349000                                       
                                                       
Sub. No.                3001                                       
Cassette Slot No.                1                                       
Process Recipe                A-ITO400A                                       
Platen Used                Platen1                                       
Recipe Type                SMD-Product                                       
SetUp Recipe                A-ITO SETUP                                       
                                                       
                Step1                Step2                Step3       
Recipe1                A-ITO 400A        ( S3 )                               
                                                       
L1 Chamber In                                                       
L1 Waiting Time of Loading        [sec]        0                                77       
L1 Heat temp        [C]                24        23        26        24       
L1 Heating Program No..        [no.]                                        1       
L1 Keeping Program No..        [no.]                                        1       
                                                       
Chamber                S3(CA32)                                       
        Units        Set        Ave        Min        Max        Act       
Process Start                2011-5-4        4:50:57                               
Process End                2011-5-4        4:51:07                               
S3 CA32 Platen Pos.        [Pos.]                                        0       
S3 CA32 Process Time        [sec]        999                        12               
S3 CA32 Sputter Time        [sec]        11                        10               
S3 MFC1 Ar        [sccm]        280        281        281        281               
S3 MFC2 O2        [sccm]        0        0        0        0               
S3 MFC3 H2O        [sccm]        3        3        3        3               
S3 DG Pressure        [Pa]                0.65        0.63        0.66               
S3 CA32 DC Power1        [kW]        60        60        59.9        60               
S3 CA32 DC Current1        [A]                145        143        146               
S3 CA32 DC Voltage1        [V]                413        409        420               
S3 CA32 Arc count1        [Times]                                        6       
S3 CA32 Target Life(1)        [kWh]                                        8975

apang

回复 49# haichuan5121


    代码没有做容错处理，如果输入的行数或列数大于csv文件本身的行数或列数，就会报“下标越界”

解决办法：在vbs代码开头插入一行：

On Error Resume Next
复制代码

haichuan5121

Apang 大神 在不，帮忙看下 我的VB这个代码用的好好的，最近也没改啥咋用不了了啊！ 提示

haichuan5121

回复 45# apang


    Sorry  大哥对不住啊！ 我一直以为你写得代码是BAT格式的呢，原来是VBS的。。。可以了

haichuan5121

回复 45# apang


    你的40楼是正确的，问题解决了，一直以为是BAT代码呢 不知道是VBS的  改个后缀就能刷了 。。

yiwuyun

回复 44# haichuan5121
你用40楼的代码，很快的，几百个文件也不会超过10秒吧。
我是写着玩的，哪晓得你要那么多文件。根本就不考虑效率。
你把40楼的代码的文件名改成vbs结尾，不要用bat结尾。主要是你没把用途写清楚，一直都在变。别人当然就不考虑那么多了。

apang

除非单个文件几百兆上G级，否则不可能“刷一个要50分钟”。
如此，你应该在顶楼就交代清楚
顶楼不说清楚，一会想实现这样一会又想那样，什么心态？“我是小白”很了不起吗？
给你代码不会用，活该你慢。

haichuan5121

回复 39# apang


    你这个数据少能刷；我这个文件有200-500个文件 刷一个要50分钟。。。。。

haichuan5121

回复 40# apang


    运行没反应啊  我小白 也看不懂

haichuan5121

回复 38# yiwuyun


    大神NB啊 成了 ，就是小白用着有点蒙圈；能不能改成 输入 单元格刷数据的啊，比如 提示输入C2 .D8. F20 就可以刷这三位置的数据啊？
或者跟19楼似得刷取过程有个提示的。

yiwuyun

@echo off
setlocal EnableDelayedExpansion
set /a rowStart=37
set /a rowEnd=39
set /a colNumber=4
set "fileSeperator=,"
set "fileType=csv"

if "!fileType!"=="csv" (
  set "allFile=*.csv"
) else (
  set "allFile=*.txt"
)
if "!fileSeperator!"=="," (
  set outputFile=new.csv
) else (
  set outputFile=new.txt
)
set /a fileCount=!rowEnd!-!rowStart!+1
for /l %%a in (!rowStart!,1,!rowEnd!) do (
  set /a fileNumber=%%a-!rowStart!+1
  set /a skip=0
  for /f "delims=" %%b in ('dir /b !allFile!') do (
     for /f "tokens=%colNumber% delims=," %%c in ('type %%b') do (
       set /a skip+=1
       if "!skip!"=="%%a" (
         echo %%c>>file!fileNumber!.txt
       )
     )
     set /a skip=0
  )
)
set /a n=!fileCount!
set /a m=0
set str=
type nul>!outputFile!
for /l %%a in (1,1,!n!) do (
  set /a n1=0
  for /f %%b in ('type file%%a.txt') do (
    set /a n1+=1
    for /l %%c in (!n1!,1,!n1!) do (
       set file%%a.row%%c=%%b
    )
  )
  if !n1! gtr !m! (set /a m=!n1!)
)
for /l %%a in (1,1,!m!) do (
  for /l %%b in (1,1,!n!) do (
    if "!file%%b.row%%a!"=="" (set /a file%%b.row%%a=0)
    if "%%b"=="!n!" (
      set "str=!str!!file%%b.row%%a!"
    ) else (
       if "!fileSeperator!"=="," (
         set "str=!str!!file%%b.row%%a!,"
       ) else (
         set "str=!str!!file%%b.row%%a!    "
       )
    )
  )
  echo !str!>>!outputFile!
  set str=
)
for /l %%a in (1,1,!fileCount!) do (
  if exist ".\file%%a.txt" del ".\file%%a.txt"
)
复制代码

这个稍稍通用一点

apang

再来一下：

arrCell = Array("D37", "D38", "D39") ''需要提取的单元格
Set fso = CreateObject("Scripting.FileSystemObject")
For Each file in fso.GetFolder(".").Files
        If LCase(Right(file, 4)) = ".csv" Then
                Set f = fso.OpenTextFile(file, 1)
                txt = f.ReadAll : f.Close
                str = str & getCellsData(txt) & vbCrLf
        End If
Next

fso.OpenTextFile("new.csv", 2, true).Write str
MsgBox "OK"

Function getCellsData(ByVal txt)
        '' csv文本分割成数组
        arrTxt = Split(txt, vbCrLf)
        strChr = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
        ''建立正则表达式
        Set re = New RegExp
        ''正则表达式模式，最大支持到ZZ列
        re.Pattern = "^([a-z]{1,2})(\d+)$"
        re.IgnoreCase = true
        For i = 0 to UBound(arrCell)
                n = re.Execute(arrCell(i))(0).SubMatches(0)
                n = UCase(Right("0" & n, 2))
                n1 = InStr(strChr, Left(n, 1))
                n2 = InStr(strChr, Mid(n, 2))
                n = n1 * 26 + n2 - 1
                m = re.Execute(arrCell(i))(0).SubMatches(1) - 1
                s = s & "," & Split(arrTxt(m), ",")(n)
        Next
        getCellsData = Mid(s, 2)
End Function
复制代码

apang

也来一个：

@set @n=0;/* & echo off
set "cell=D37 D38 D39"
for %%a in (*.csv) do (
        cscript -nologo -e:jscript "%~0"<"%%a">>$ "%cell%"
)
move $ new.csv
pause & exit & */

arg = WScript.Arguments(0).split(" ");
txt = WScript.StdIn.ReadAll();
arTxt = txt.replace(/(\s*\n)+$/, "").split("\r\n");
chr = "0ABCDEFGHIJKLMNOPQRSTUVWXYZ";
arCell = [];
for (i=0; i<arg.length; i++) {
        m = arg[i].match(/\d+$/)[0] - 1;
        n = ("0" + arg[i]).match(/(..)\d+$/)[1].toUpperCase();
        n1 = chr.indexOf(n.substr(0, 1));
        n2 = chr.indexOf(n.substr(1));
        n = n1 * 26 + n2 - 1;
        arCell.push(arTxt[m].split(",")[n]);
}
WScript.Echo(arCell.join(","))
复制代码

yiwuyun

@echo off 
setlocal EnableDelayedExpansion
set /a start=36
for /l %%a in (37,1,39) do (
  set /a fileNumber=%%a-!start!
  set /a skip=0
  for /f "delims=" %%b in ('dir /b *.csv') do (
     for /f "tokens=4 delims=," %%c in ('type %%b') do (
       set /a skip+=1
       if "!skip!"=="%%a" (
         echo %%c>>file!fileNumber!.txt
       )
     )
     set /a skip=0
  )
)
set /a n=3
set /a m=0
set str=
type nul>new.csv
for /l %%a in (1,1,!n!) do (
  set /a n1=0
  for /f %%b in ('type file%%a.txt') do (
    set /a n1+=1
    for /l %%c in (!n1!,1,!n1!) do (
       set file%%a.row%%c=%%b
    )
  )
  if !n1! gtr !m! (set /a m=!n1!)
)
for /l %%a in (1,1,!m!) do (
  for /l %%b in (1,1,!n!) do (
    if "!file%%b.row%%a!"=="" (set /a file%%b.row%%a=0)
    if "%%b"=="!n!" (
      set "str=!str!!file%%b.row%%a!"
    ) else (
      set "str=!str!!file%%b.row%%a!,"
    )
  )
  echo !str!>>new.csv
  set str=
)
复制代码

逗号分隔

yiwuyun

@echo off 
setlocal EnableDelayedExpansion
set /a start=36
for /l %%a in (37,1,39) do (
  set /a fileNumber=%%a-!start!
  set /a skip=0
  for /f "delims=" %%b in ('dir /b *.csv') do (
     for /f "tokens=4 delims=," %%c in ('type %%b') do (
       set /a skip+=1
       if "!skip!"=="%%a" (
         echo %%c>>file!fileNumber!.txt
       )
     )
     set /a skip=0
  )
)
set /a n=3
set /a m=0
set str=
type nul>new.csv
for /l %%a in (1,1,!n!) do (
  set /a n1=0
  for /f %%b in ('type file%%a.txt') do (
    set /a n1+=1
    for /l %%c in (!n1!,1,!n1!) do (
       set file%%a.row%%c=%%b
    )
  )
  if !n1! gtr !m! (set /a m=!n1!)
)
for /l %%a in (1,1,!m!) do (
  for /l %%b in (1,1,!n!) do (
    if "!file%%b.row%%a!"=="" (set /a file%%b.row%%a=0)
    set "str=!str!!file%%b.row%%a!   "
  )
  echo !str!>>new.csv
  set str=
)
复制代码