[日期时间] 批处理怎么在获取的时间上加上几秒？

gd6570

不是延迟执行，是在获取的时间上加上几秒，想用AT命令在指定时间（执行后的几秒钟）执行一个程序，at time

就是时间相加

飛雪

出現秒數也太細膩了吧?

gd6570

回复 5# apang


    如果不精确到秒，以分钟为单位相加怎么弄？代码会不会简单些？

凡凡之呗

下面的代码是越来越简便，他们既然说了，我就不用了吧，其实你为什么不在at命令后面直接修改时间呢

terse

@if(0)==(0) echo off
CScript -NoLogo -E:JScript %0
pause & exit
@end
var t = new Date(new Date().getTime()+5000);
var reg = /((\d{1,2}:){2}\d{1,2})/g;
t.toLocaleString().replace(reg, function(a,b){WSH.echo(b)});
复制代码

CrLf

推广一下，powershell 可以这样：

(Get-Date).AddSeconds(1000) | Get-Date -Format 'hh:mm:ss'
复制代码

apang

@echo off
set n=5
set t=%time: =0%
set /a s=n+(1%t:~,2%-100)*3600+(1%t:~3,2%-100)*60+1%t:~6,2%-100
set /a hh=s/3600%%24+100,mm=s%%3600/60+100,ss=s%%60+100
set "newTime=%hh:~1%:%mm:~1%:%ss:~1%"
echo,%newTime%
pause
复制代码

CrLf

来个当前时间加 100 秒的，话说写这么长和纯批比完全没优势了的...

<!-- : www.bathome.net
@echo off
for /f "delims=" %%a in ('echo %time:~,8% ^| mshta "file://%~0"') do echo %%a
pause&exit
-->


<script language=vbs>
Set fso = CreateObject("Scripting.FileSystemObject")
t = fso.GetStandardStream(0).ReadAll
t = DateAdd("s",100,CDate(t))
t = Hour(t) & ":" & Right("0" & Minute(t), 2) & ":" & Right("0" & Second(t), 2)
fso.GetStandardStream(1).Write t
close
</script>
复制代码

有更简便的办法，但现在还没完工

pcl_test

回复 1# gd6570

@echo off
set /p n=请输入要累加的秒数：
>gettime.vbs echo dim t,h,m,s
>>gettime.vbs echo t=Hour(Now)*3600+Minute(Now)*60+Second(Now)+%n%
>>gettime.vbs echo h=t\3600
>>gettime.vbs echo m=(t mod 3600)\60
>>gettime.vbs echo s=(t mod 3600) mod 60
>>gettime.vbs echo if (h^<10) then h="0"^&h
>>gettime.vbs echo if (m^<10) then m="0"^&m
>>gettime.vbs echo if (s^<10) then s="0"^&s
>>gettime.vbs echo wscript.echo h^&":"^&m^&":"^&s
for /f %%a in ('cscript /nologo gettime.vbs') do (set "gtime=%%a")
del gettime.vbs /f /q
echo 当前时间为%time:~0,8%
echo 累加%n%秒后的时间为%gtime%
pause
复制代码

DAIC

这里有函数库和实际例子，可以参考一下：
http://bbs.bathome.net/thread-3056-1-1.html