[文本处理] [已解决]批处理如何把文件名横向排列并用分隔符隔开？

ahgogo

我想实现文件夹里的文件名横向排列并用字符分隔开，不知道怎样实现，求大神帮助！

只会用DIR命令列出文件名
dir *.* /b> 1.txt

1.jpg
2.jpg
3.jpg
4.jpg
...
//------------------------------

我想输出的1.txt里是这样的  1.jpg|2.jpg|3.jpg|4.jpg|...

gawk

回复 22# ahgogo


dir /b /a-d /od
dir /b /a-d /o-d
分别执行两个命令，观察一下差异。

ahgogo

回复 21# DAIC
谢谢你的解答，
我试了下按大小排序是有效果的，但是按时间排序没有反应，怎么回事！

DAIC

回复 20# ahgogo

@echo off
REM S  按大小(从小到大)
REM D  按日期/时间(从先到后)
(for /f "delims=" %%a in ('dir /b /a-d /oS') do (
    for /f "delims=| tokens=1,1" %%b in ("%%a\.") do (
        set /p "=%%~nxa|"<nul
    )
))>"list.txt"
复制代码

ahgogo

又遇到问题，请各位帮忙

@echo off

(for %%a in (*) do (
        for /f "delims=| tokens=1,1" %%b in ("%%a\.") do (
                set /p "=%%~nxa|"<nul
        )
)) >"list.txt"

我想在这个批处理中实现输出文件名按文件的大小进行排序，或者按时间排序，怎样操作！

freesoft00

回复 18# pcl_test

"bat$"结合findstr /v 就是排除批处理文件

哦，这个文件夹中有这个批处理文件，所以要排除一下这个扩展名的文件，对吧，我说呢，怎么处理图像文件排除中出现一个bat是干什么用的。
谢谢了！

pcl_test

回复 17# freesoft00

"bat$"结合findstr /v 就是排除批处理文件
<nul，实际是set /p=变量<nul的一部分，实现退格

freesoft00

回复 2# pcl_test

请教两个问题：
"bat$"是什么意思，没有太明白
导入到文件我知道的是>  或者>>
你代码最后面对<nul>"1.txt是否可以解释一下是怎么回事？
do @set /p=%%a^|改为do @set p=%%a^|不行吗？为什么要添加一个/呢？
希望能给解释一下。

CrLf

回复 10# pcl_test


    rem 可以省掉

ahgogo

我也不知道，运行后输出的是空的，但是我换了台电脑是可以的，估计是电脑的问题吧

CrLf

8 楼代码有什么问题吗？
findstr /s /m .* * 取得的就是相对路径

pcl_test

回复 12# ahgogo

因为你的目录结构不对，已修改，能适应不同层次的目录结构

ahgogo

感谢楼上各位的热心帮助，问题已解决，@pcl_test 命令执行后输出还是空的。@tmplinshi版主的方案可以，已采用，谢谢你们！

tmplinshi

@echo off

(for %%a in (*) do (
	for /f "delims=| tokens=1,2" %%b in ("%%~dpa\..|%%a\..") do (
		set /p "=%%~nxb\%%~nxc\%%~nxa|"<nul
	)
)) >"1.txt"
复制代码

pcl_test

@set @n=0; /* & echo off
for /f "delims=" %%a in ('echo;%~dp0^|cscript -nologo -e:jscript "%~0"') do set "fpath=%%a"
(for %%b in (*.jpg *.bmp *.gif *.png *.jpeg) do set /p=%fpath%%%b^|)<nul>"1.txt"
echo;完成
ping -n 2 0 >nul&exit & rem */
var str = "";
var Arr = new Array();
var Arr = WScript.StdIn.ReadLine().split("\\");
if (Arr.length<3) {
    str = Arr[1];
}else if (Arr.length==3){
    str = Arr[1]+"\\"+Arr.pop();
}else{
    str = Arr[Arr.length-3]+"\\"+Arr[Arr.length-2]+"\\"+Arr.pop();
}
WScript.Echo(str);
复制代码