[文件操作] 批处理如何按照txt文本中列出的文件名顺序在文件名前添加序号？

knightkk

我需要按照指定的列表
list.txt中
Dog
Cat
Tiger
Monkey
Elephant
...
的顺序
从音频文件夹中的音频文件（乱序）
Cat.mp3
Panda.mp3
Dog.mp3
严格按照list列表的顺序改名成
1Dog.mp3
2Cat.mp3
3...
这个问题始终搞不定，希望各位批处理大神帮助刚入门的小白一把。

WHY

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('type list.txt') do (
    set /a n+=1
    if exist ".\linshi\%%a.mp3" (
        ren ".\linshi\%%a.mp3" "!n!%%a.mp3"
    ) else (
        echo !n!%%a.mp3
    )
)
复制代码

knightkk

回复 3# codegay

谢谢了，不过用python是不是要装解释器之类的环境呀？感觉会有很多的工作要做。

knightkk

回复 2# pcl_test


    谢谢，由于有些文件列表中有，而mp3库中没有，我就想知道哪些项没有。注（linshi是我的mp3文件库）

for /f "delims=" %%a in ('type "List.txt"') do (
set/a n+=1
call ren ".\linshi\%%a.mp3" "%%n%%%%a.mp3"
if not exist .\linshi\%%n%%%%a.mp3 (echo "%%n%%%%a.mp3">>yy.txt)
)
复制代码

修改调试了很久，但是总是会输出全部列表的内容
我觉得可能是not exist后面的%%n%%不能是序号的形式，echo里面的%%n%%也不能是序号，有什么办法可以解决这个问题呢？
新手小白，对于这里%%n%%,%n%有什么区别不清楚，还有""双引号加不加有什么区别吗？

codegay

import os;[os.rename(name+".mp3",str(num)+name+".mp3") for num,name in enumerate(open("list.txt"),1)]
复制代码

python版一行流

pcl_test

@for /f "tokens=1*delims=:" %%a in ('findstr /n . "list.txt"') do ren "%%b.mp3" "%%a%%b.mp3"
复制代码

@for /f "delims=" %%a in ('type "list.txt"') do set/a n+=1&call ren "%%a.mp3" "%%n%%%%a.mp3"
复制代码