[网络连接] 怎么用批处理判断有没有连上网络？

sexfio

怎么用批处理判断有没有连上网络？

htnet11

我也来帖一个。感觉清楚些
用到得DNS202.101.98.55是我们福建的，你可以根据你自己属地的dns改下

@echo off 
::这里改为你的网关地址
ping 192.168.0.1
if %errorlevel%==0 (goto case2) else (goto case1) 
:case1 
        cls
        @echo 你和路由器的连接有问题，请检查连接属性
        pause
        ncpa.cpl
        goto end
:case2 
        cls        
        @echo 和路由器连接没有问题
        pause
        ping 202.101.98.55 
        if not %errorlevel%==0 (goto case3) else (goto case4)
:case3 
        cls
        @echo 你的路由器有问题。
        pause
        ncpa.cpl
        goto end
:case4
        cls        
        @echo 可以连接到Inter网
        pause
        ping www.baidu.com
        if not %errorlevel%==0 (goto case5) else (goto case6)
:case5
        cls
        @echo 设置你的dns吧 推荐：202.101.98.55。记下了么？
        pause
        ncpa.cpl
        goto end
:case6
        cls
        @echo 你耍我吧~~明明可以上网啊。真不能上就是你浏览器问题了~~！
        pause
        goto end
:end
exit
复制代码

[ 本帖最后由 htnet11 于 2009-4-20 11:36 编辑 ]

leaparde

代码没有考虑多网卡和拨号的情况，我的环境为单网卡LAN接入方式上网，一般的公司上网模式。

@echo off
ipconfig|findstr /c:"IP Address">nul&&(echo 本地网络连接正常！)||(echo 本地网络连接已断开或禁用！&pause>nul&exit)
echo.&echo Your ip address info：&echo.
ipconfig /all |findstr "adapter Physical Address Mask Gateway Servers"
for /f "tokens=2 delims=:" %%i in ('ipconfig^|findstr Gateway') do  set gw=%%i
echo.&echo.&echo.
ping %gw% -n 2 |findstr TTL>nul&&(echo 本机到网关的链路正常！)||(echo 本机到网关的链路不正常！&pause>nul&exit)
ping 202.108.23.59 -n 2 |findstr TTL>nul&&(echo 本机到Internet线路正常！)||(echo 本机到Internet不通！&pause>nul&exit)
ping baidu.com -n 2 |findstr TTL>nul&&(echo DNS解析正常！)||(echo DNS解析错误，请检查DNS设置或更换DNS！&pause>nul&exit)
pause>nul
复制代码

Batcher

ping一个指定的站点，能通就说明连上了。