自动生成虚拟u盘2.文件就会保存到这个虚拟u盘，虚拟u盘数据悬赏 2000，网盘里面，

edisonma

1.现在想保存到网络共享盘符里面，现在想的方案是1.电脑是XP系统，欺骗系统已经插入u盘，自动生成虚拟u盘2.文件就会保存到这个虚拟u盘，虚拟u盘数据再自动复制到网盘里面，网盘里面复制的每天自动建一个日期命名的文件夹保存，价格可以谈， 我 qq：1344746759

edisonma

回复 9# zaqmlp


    好，我加你qq，详聊

zaqmlp

回复 8# edisonma
代码会将C:\xxx\test虚拟成U盘

edisonma

回复 7# zaqmlp


   不好意思，我没有表达清楚，我说的U盘，不是盘符，移动硬盘的u盘

zaqmlp

@echo off
set "sourcepath=C:\xxx\test"
set "oldfolder=U:"
set "newfolder=Z:"
if not exist "%sourcepath%" md "%sourcepath%"
if not exist %oldfolder% (subst %oldfolder% "%sourcepath%")
>"%tmp%\v.v" echo;d=date:WSH.echo right(Year(d),4) ^& right("0" ^& Month(d),2) ^& right("0" ^& Day(d),2)
:loop
for /f %%a in ('cscript -nologo -e:vbscript "%tmp%\v.v"') do set "today=%%a"
if not exist "%newfolder%\%today%" md "%newfolder%\%today%"
cls&echo;Monitor……
for /f "delims=" %%a in ('dir /a-d/b/s "%oldfolder%\"') do (
    set "file=%%a"
    set "oldpath=%%~dpa"
    setlocal enabledelayedexpansion
    set "newpath=%newfolder%\%today%!oldpath:%oldfolder%=!"
    if not exist "!newpath!" md "!newpath!"
    echo;"!file!" --^> "!newpath!"
    copy /y "!file!" "!newpath!"
    del /a /f /q "!file!"
    endlocal
)
rem rd /s /q "%oldfolder%\"
>nul ping /n 2 0
goto loop
复制代码

Batcher

回复 1# edisonma

@echo off
REM 设置网络盘符
set "NetDrive=Z"
echo 获取当前系统日期（兼容不同的日期格式）
>"%temp%\DateCalculate.vbs" echo dt=date()
>>"%temp%\DateCalculate.vbs" echo s=right(year(dt),4) ^& "-" ^& right("0" ^& month(dt),2) ^& "-" ^& right("0" ^& day(dt),2)
>>"%temp%\DateCalculate.vbs" echo wscript.echo s
for /f %%a in ('cscript /nologo "%temp%\DateCalculate.vbs"') do (
    set Today=%%a
)
echo %Today%
echo 创建文件夹
md "%NetDrive%:\%Today%"
复制代码

先试试这样能否成功创建当天的文件夹？

edisonma

回复 3# Batcher


    是的，是你说的网络映射 比如 z盘

edisonma

不是网盘，我说的网盘是网络里面的另外一台电脑

Batcher

回复 1# edisonma


    你说的【网盘】是指类似百度网盘？还是通过映射网络驱动器把远程服务器上的某个盘符映射到本地，比如Z:\盘？

edisonma

如果批处理做不到生成虚拟U盘， 那 写一段自动负责本地盘文件（这个盘会实时新数据的），这个数据能定时拷贝到网络盘符里面，因为本地盘空间很快就满了，拷贝完之后，本地完了的数据清除掉，本地盘会继续新数据写入的，网络盘里面的命名每天按日期生成一个文件夹