[网络连接] 请问批处理如何实现adsl拨号并过滤重复IP？

hulala

请问批处理如何实现adsl拨号并过滤重复IP？
24小时不使用重复ip，拨号后检查到使用过的IP，等待几秒后自动重新拨号。
给出成品留下收款码！

locoman

谢谢无私分享，收藏学习。

zaqmlp

回复 9# hulala

/*&cls
@echo off&setlocal enabledelayedexpansion
set "name=宽带连接"
set "user=用户名"
set "password=宽带密码"
set "sleep=30"
set "output=IP.ini"

cd /d "%~dp0"
if exist "%output%" (
    for /f %%a in ('type "%output%"') do set _#%%~a=1
)
:loop
set "ip="
rasdial "%name%" /disconnect
rasdial "%name%" "%user%" "%password%"||goto loop
>nul ping /n 3 0
for /f %%a in ('cscript -nologo -e:jscript "%~f0"') do set ip=%%a
:break
if defined ip (
    echo;%ip%
    if not defined _#%ip% (
        set _#%ip%=1
        >>"%output%" echo;%ip%
        goto end
    )
)
timeout /t %sleep% /nobreak
goto loop
:end
pause
exit
*/
var http=new ActiveXObject('Msxml2.ServerXMLHTTP');
http.open('GET', 'http://ip.42.pl/raw', false);
http.send();
var html=http.responseText;
var m=html.match(/(?:\d+\.){3}\d+/);
if(m){WSH.echo(m[0]);}
复制代码

hulala

回复 6# zaqmlp


    http://ip.42.pl/raw
这也行，哪个快用哪个

hulala

回复 6# zaqmlp


    https://api.ipify.org/?format=json
或者你对接这个

hulala

回复 6# zaqmlp


    不是的，去ip138.com看不是的

zaqmlp

回复 5# hulala

你的宽带ip就是10呀，你说的ip是什么ip，怎么查看的

hulala

回复 4# zaqmlp

zaqmlp

回复 3# hulala
连接后，打开一个cmd窗口，执行ipconfig，截图看看

hulala

回复 2# zaqmlp


    获取到的ip是内网ip，10开头的，不是外网ip

zaqmlp

@echo off&setlocal enabledelayedexpansion
set "name=宽带连接"
set "user=用户名"
set "password=宽带密码"
set "sleep=30"
set "output=IP.ini"

cd /d "%~dp0"
if exist "%output%" (
    for /f %%a in ('type "%output%"') do set _#%%~a=1
)
:loop
set "ip="
rasdial "%name%" /disconnect
rasdial "%name%" "%user%" "%password%"||goto loop
>nul ping /n 3 0
set "f="
set "ip="
for /f "delims=" %%a in ('ipconfig') do (
    set "line=%%a"
    if defined f (
        if "!line:IPv4 地址=!" neq "!line!" (
            for /f "tokens=1* delims=:" %%b in ("%%a") do (
                for /f %%d in ("%%~c") do set "ip=%%~d"
            )
            goto break
        )
    )
    if "!line:%name%=!" neq "!line!" (
        set f=1
    )
)
:break
if defined ip (
    echo;%ip%
    if not defined _#%ip% (
        set _#%ip%=1
        >>"%output%" echo;%ip%
        goto end
    )
)
timeout /t %sleep% /nobreak
goto loop
:end
pause
exit
复制代码