[文本处理] [已解决]两个处理图片文件的bat脚本要一起使用要怎么修改？

Lekton

bat脚本：两个bat脚本要一起使用要怎么修改，一个是在根文件夹一个是在子文件夹
我的脚本如下：
-----------------------------------------------------------------------------------------------------------------------------------------------------------------

@echo off
rem 在多个文件夹里新建一个同名文件夹
title %#% +%@%%$%%$% %z%
cd /d "%~dp0"
set "folder=详情图"
for /f "delims=" %%a in ('dir /ad/b') do (
    md "%%a\%folder%\"
)
set "folder=主图"
for /f "delims=" %%a in ('dir /ad/b') do (
    md "%%a\%folder%\"
)
复制代码

# 以上这段是在根文件夹运行的，它对每个子文件夹都新建两个文件夹，一个“主图”一个“详情图”
-----------------------------------------------------------------------------------------------------------------------------------------------------------------

@echo off
mode con lines=3000
rem 根据文件夹名称中指定位置的字符串，将多个文件名称中含有相同字符串的文件剪切/移动到该文件夹内的指定子文件夹里
cd /d "%~dp0"
set "position=1-10"
for /f "tokens=1* delims=-" %%a in ("%position%") do set /a "n=%%a-1,m=%%b-%%a+1"
for /f "delims=" %%a in ('dir /ad/b') do (
set "fdname=%%~nxa"
setlocal enabledelayedexpansion
for /f "delims=" %%b in ('dir /a-d/b "*!fdname:~%n%,%m%!*"') do (
if "%~nx0" neq "%%~nxb" (
if not exist "%%a\%subfolder%\" (md "%%a\%subfolder%\")
echo;"%%b" --^> "%%a\%subfolder%\"
move "%%b" "%%a\%subfolder%\"
)
)
endlocal
)
echo;%#% +%$%%$% %z%
pause
复制代码

# 这一段就是原本放在子文件里面的，它自动识别关键词，再把图片拉进识别到一样关键词的文件夹进去，如识别到含有“主图”的图片它自动就拉到“主图”文件夹，识别到含有“详情图”的图片就拉到“详情图”文件夹里面去。
# 现在这两段要放在同一个“bat”里面。然后在根文件夹运行，语法要怎么修改呢
-----------------------------------------------------------------------------------------------------------------------------------------------------------------

Lekton

回复 3# Batcher


    感谢大神，完美解决 一百个赞

Batcher

回复 1# Lekton

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /ad') do (
    pushd "%%i"
    md "主图"
    md "详情图"
    move /y "*主图*" "主图\"
    move /y "*详情图*" "详情图\"
    popd
)
复制代码

请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/6lbb97qUOs1sTyKJfN0ZEQ

Lekton

我的根文件夹里面有很多个子文件夹，子文件夹里有很多图片，图片就包含有“主图”跟“详情图”