[文件操作] 批处理自动按照日期备份多个文件夹里面的文件

司马光2008

之前写了一个批处理命令，按照日期自动备份某个文件夹里面的文件，现在需要多备份 E:\45678和F:\5588和F:\376
请问如何增加E:\45678和F:\5588和F:\376  这三个文件夹也执行E:\12345 这个备份的命令

之前命令：

@ECHO OFF&setlocal enabledelayedexpansion
set "SrcDir=E:\12345"
cd /d "%SrcDir%"
for /f "tokens=1-3 delims=" %%a in ('dir /a-d/b') do (
	set "write_date=%%~ta"
	set "write_date=!write_date:/=!"
	set "write_date=!write_date:~0,8!"
	if not exist !write_date! md "!write_date!"
	move /y "%%a" "!write_date!"
)
复制代码

司马光2008

谢谢各位的帮忙

qixiaobin0715

@echo off
set SrcDir="E:\12345" "E:\45678" "F:\5588" "F:\376"
setlocal enabledelayedexpansion
for %%i in (%SrcDir%) do (
    pushd %%i
    for /f "tokens=1-3 delims=" %%a in ('dir /a-d/b') do (
        set "write_date=%%~ta"
        set "write_date=!write_date:/=!"
        set "write_date=!write_date:~0,8!"
        if not exist !write_date! md "!write_date!"
        move /y "%%a" "!write_date!"
    )
    popd
)
pause
复制代码

Batcher

回复 1# 司马光2008


把你代码里面的第2、3行换成这样试试：

for %%i in (E:\12345 E:\45678 F:\5588 F:\376) do (
    set "SrcDir=%%i"
    call :ExecMove
)

:ExecMove
cd /d "!SrcDir!"
复制代码