[系统相关] 批处理如何将计算机名改为MAC地址-兼容win7和win10

gxqzlsyls

各位大神！
如何将计算机名改为MAC地址，需要兼容win7和win10，站里找的感觉不接近，要不就是看不懂。
还请大家帮帮忙，不胜感激！

yakeyun

回复 4# 窄口牛

如果主机存在多张网卡，多个MAC地址的，可以用下面代码先获取到当前联网的MAC信息，然后再修改为其MAC名称。
缺点是如果没有联网，就获取不到联网的网卡MAC值，无法修改。

@echo off&setlocal enabledelayedexpansion
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
set ons=TRUE
for /f "tokens=* " %%a in ('wmic nic get  macaddress ^,NetEnabled  ^|find /i "%ons%"') do set netdata=%%a
for /f "tokens=1-6 delims=:" %%b in ('echo %netdata% ^|find /i ":"') do set macdata=%%b-%%c-%%d-%%e-%%f-%%g
for /f "tokens=1 delims=^ " %%m in ('echo %macdata%') do set pcname=%%m
echo 当前联网网卡MAC为：%pcname%
wmic computersystem where "name='%computername%'" call rename "%pcname%"    >nul 2>nul
echo,
echo,
echo 一键修改完成！需要重启后方可生效，重启请回车继续。
echo,
echo,
pause>nul
shutdown -r -t 0
exit
复制代码

gxqzlsyls

回复 8# yakeyun


    测试OK！万分感谢

yakeyun

回复 6# gxqzlsyls

试下看看，set数值调用，需要开延迟变量。

@echo off&setlocal enabledelayedexpansion
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
cd /d "%~dp0"
for /f "tokens=1,*" %%l in ('getmac ^|find /i "-"') do set pcname=%%l
wmic computersystem where "name='%computername%'" call rename "%pcname%"  >nul 2>nul
echo 一键修改完成！需要重启后方可生效，重启请回车继续。
pause>nul
shutdown -r -t 0
exit
复制代码

idwma

powershell "start -verb runas powershell{(gwmi win32_computersystem).rename((gwmi Win32_NetworkAdapter|?{$_.NetEnabled}).MACAddress.replace(':','-'))}"
复制代码

gxqzlsyls

回复 2# yakeyun


按照你的方法测试，win7蓝屏，win10假死需要强制关机，但能修改成功，不过这样不是想要的效果。
根据你的方法我稍微改了一下，用wimc自动的没有修改成功，但手动输入修改的话又没问题。很奇怪！麻烦帮看下，如下：
自动修改：
@echo on
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
cd /d "%~dp0"
for /f "tokens=1,*" %%l in ('getmac ^|find /i "-"') do set pcname=%%l
wmic computersystem where "name='%computername%'" call rename %pcname%
pause>nul 2>nul

手动修改：
@echo on
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
cd /d "%~dp0"
set /p pcname=请输入物理网卡地址：
wmic computersystem where "name='%computername%'" call rename %pcname%
pause>nul 2>nul

gxqzlsyls

回复 4# 窄口牛


    抱歉，不需要搞那么复杂

窄口牛

多网卡咋办？感觉还是按部门改计算机名字好些，IP按部门分配，各部门备份一个到两个IP地址。

gxqzlsyls

回复 2# yakeyun


   多谢，我测试下

yakeyun

回复 1# gxqzlsyls
已知Win11会激活系统BUG，修改完系统无法重启，关机，或者启动程序。需要物理键重启，方可恢复正常。
Win10和7需要自测

@echo off&setlocal enabledelayedexpansion
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("""%~f0""","::",,"runas",1)(close)&exit /b
for /f "tokens=1,*" %%l in ('getmac ^|find /i "-"') do set name=%%l
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\ComputerName\ActiveComputerName" /v ComputerName /t reg_sz /d %name% /f
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f 
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v Hostname /t reg_sz /d %name% /f 
cls
echo 一键修改完成！需要重启后方可生效，重启请回车继续。
pause>nul
shutdown -r -t 0
exit
复制代码