[文件操作] [已解决]求助批处理完成指定的搜索和复制任务，求大神帮忙，谢谢。

kingwilliamston

希望这个批处理文件能做到如下操作：
搜索photoshop.exe文件所在的目录，然后自动把这个批处理文件所在的目录中的一个子目录，复制到前面photoshop.exe
所在的目录中。

求助大神帮忙实现，谢谢！

kingwilliamston

十分感谢两位的大力支持，实现了目标。

went

test.bat
ansi编码

@echo off & cd /d "%~dp0"
REM 目标文件
set "tag_file=photoshop.exe"
REM 复制文件夹
set "copy_dir=B"
for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
	pushd "%%i:\" 2>nul && (
		echo 正在搜索 %%i:
		for /r %%a in ("*%tag_file%*") do (
			if /i "%%~nxa"=="%tag_file%" (
				echo %~dp0%copy_dir%\ --^> %%~dpa%copy_dir%\
				xcopy /ey "%~dp0%copy_dir%\" "%%~dpa%copy_dir%\" >nul 2>nul
			)
		)
		echo ----------------------
	)
	popd
)
pause&exit
复制代码

flashercs

<#*,:&cls
@echo off
cd /d "%~dp0"
powershell -C "Set-Location -LiteralPath ([Environment]::CurrentDirectory);. ([ScriptBlock]::Create((Get-Content -LiteralPath \"%~f0\" -ReadCount 0 | Out-String)))"
pause
exit /b
#>
($psoPhotoShop = Get-ChildItem -Path ('HKLM:\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall',
    'HKLM:\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall',
    'HKCU:\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall',
    'HKCU:\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall') -ErrorAction SilentlyContinue | `
    Get-ItemProperty -Name DisplayName, DisplayVersion, InstallLocation, UninstallString -ErrorAction SilentlyContinue |`
    Where-Object { $_.DisplayName -like '*photoshop*' } | Select-Object -First 1
)
if ($psoPhotoShop -and -not [string]::IsNullOrWhiteSpace($psoPhotoShop.InstallLocation)) {
  Copy-Item -Path B -Destination $psoPhotoShop.InstallLocation -Recurse -Verbose
} else {
  '找不到phtoshop安装路径'
}
复制代码

可能需要以管理员身份运行 bat. 保存为ANSI编码