[其他] 求指教批处理怎样把图片地址写入到html文件？

sunshot

请问一下，我这里有什么错误吗？
输出的html没有名称，求指教

@echo off&SetLocal EnableDelayedExpansion
For /f "delims=" %%i in ('dir/b/a-d/on*.*') do (Set a=%%~pi
Set a=!a:\= !)
For %%i in (%a%) do Set b=%%i
::获取文件夹名
Set n=0
(
Echo ^<Html^>
Echo ^<Title^>
Echo %b%
Echo ^</Title^>
Echo ^<Body^>
For /r %%i in (*.jpg *.bmp *.gif *.png) do (Echo ^<Img Src="%%i" width="auto" height="auto"^>
Set n=1)
::将当前文件夹中所有的图片地址写入到html文件中。
Echo ^</Body^>
Echo ^</Html^>
)>"%b%.html"
If %n%==0 Msg * "当前文件夹中没有图片" & del %b%.html
If %n%==1 Start "" "%b%.html"
复制代码

zaqmlp

回复 5# sunshot

回复底下有写

sunshot

回复 4# zaqmlp


  感谢
怎么给你钱

zaqmlp

回复 3# sunshot

@echo off&cd /d "%~dp0"
for /d %%a in (*) do (
    (echo;^<Html^>
    echo;^<Title^>
    echo;%%~a
    echo;^</Title^>
    echo;^<Body^>
    pushd "%%a"
    for /r %%i in (*.jpg *.bmp *.gif *.png) do (
        echo;^<Img Src="%%i" width="auto" height="auto"^>
    )
    popd
    echo;^</Body^>
    echo;^</Html^>
    )>"%%~nxa.html"
)
pause
exit
复制代码

sunshot

回复 2# went

大神 感谢

还有一个问题， 有偿，我当前目录下有很多文件夹，每个文件夹里都有很多图片，怎么弄能把每个文件夹里的图片生成html
有偿

went

少个空格

dir /b /a-d /on *.*
复制代码