[系统相关] 【已解决】bat或者VBS能不能实现：禁用声卡，然后启用声卡（第三方也行）？谢谢

yyz219

已解决，重启声卡.bat：
@echo off

::【重启声卡（禁用1次）（启用2次）——经过多次实验证明】
devcon disable *DEV_1C20* >nul 2>nul
devcon enable  *DEV_1C20* >nul 2>nul
devcon enable  *DEV_1C20* >nul 2>nul

exit
*********************************
不知道有没有更科学的方法？
***********************************************
原来的问题：
bat或者VBS能不能实现：禁用声卡，然后启用声卡（第三方也行）？谢谢

buyiyang

@echo off
fltmc>nul||mshta vbscript:CreateObject("Shell.Application").ShellExecute("%~s0",,,"runas",1)(window.close)&&exit
for /f "tokens=2 delims==" %%i in ('wmic path Win32_SoundDevice get name /value') do set /a n+=1&call echo, [%%n%%]%%i&call set _s%%n%%=%%i
for /l %%i in (1,1,%n%) do call set c=%%c%%%%i
CHOICE /C %c% /M "选择声卡"
call set name=%%_s%errorlevel%%%
for /f "tokens=2 delims==" %%i in ('wmic path Win32_SoundDevice where "name='%name%'" get PNPDeviceID /value') do set "pnpid=%%i"
set "pnpid=%pnpid:amp;=%"
CHOICE /C de /M "disable或enable"
if %errorlevel% equ 1 pnputil /disable-device "%pnpid%"
if %errorlevel% equ 2 pnputil /enable-device "%pnpid%"
pause
复制代码

jyswjjgdwtdtj

Option Explicit

Dim colItems, objItem, strComputer, arrServiceList, strServiceName

strComputer = "." '本地计算机

' 获取 “Windows Audio” 服务对象
Set colItems = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _
    strComputer & "\root\cimv2").ExecQuery("SELECT * FROM Win32_Service WHERE Name='Audiosrv'")

For Each objItem in colItems
    ' 停止并禁用 “Windows Audio” 服务
    objItem.StopService()
    objItem.ChangeStartMode("Disabled")
Next

' 释放对象
Set objItem = Nothing
Set colItems = Nothing
复制代码

ai写的 不敢保证正确性
我自己不敢试

话说ai特别喜欢sendkeys？和类似的api