批处理之家 » BAT求助&讨论 » 请问批处理如何把当前文件夹里所有文件，加上修改日期的前缀呢

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

返回列表发帖

Rank: 1

帖子: 3
积分: 15
技术: 0
捐助: 0
注册时间: 2023-9-14

1楼 跳转到 » 正序看帖

字体大小: tT

发表于 2023-9-14 15:18 | 只看该作者

[日期时间] 请问批处理如何把当前文件夹里所有文件，加上修改日期的前缀呢

我自己写了一个bat脚本，
但是运行脚本后，会丢掉修改日期的年和月，只有日，时，分。请问是哪里出的问题呢，谢谢！

@echo off
setlocal enabledelayedexpansion

for %%F in (*) do (
    rem 获取文件的最后修改日期和时间
    for %%a in ("%%~tF") do (
        set "datetime_str=%%~na"
    )

    rem 去掉日期和时间中的空格和冒号，只保留数字部分
    set "formatted_datetime=!datetime_str: =!"
    set "formatted_datetime=!formatted_datetime::=!"
    
    rem 重命名文件
    ren "%%F" "!formatted_datetime!_%%F"
)

endlocal
复制代码

Rank: 1

帖子: 3
积分: 15
技术: 0
捐助: 0
注册时间: 2023-9-14

6楼

发表于 2023-9-14 20:25 | 只看该作者

搞定了，谢谢大家。

@echo off
setlocal enabledelayedexpansion

for %%F in (*) do (
    if "%%F" neq "%0" (
        set "datetime_str=%%~tF"
        rem 去掉日期和时间中的空格、冒号、斜线，只保留数字部分
        set "formatted_datetime=!datetime_str: =!"
        set "formatted_datetime=!formatted_datetime::=!"
        set "formatted_datetime=!formatted_datetime:/=!"
        ren "%%F" "!formatted_datetime!_%%F"
    )
)
复制代码

Rank: 12

帖子: 14935
积分: 46142
技术: 857
捐助: 745
注册时间: 2008-6-9

5楼

发表于 2023-9-14 16:36 | 只看该作者

回复 1# nova636

执行这个代码：

@echo off
setlocal enabledelayedexpansion
for %%F in (*) do (
    echo %%~tF
    pause
    for %%a in ("%%~tF") do (
        set "datetime_str=%%~na"
        echo !datetime_str!
        pause
    )
)
复制代码

可以发现结果如下：

2023/09/08 13:51
请按任意键继续. . .
08 13:51
请按任意键继续. . .

内层for循环认为斜线左侧的是文件夹，只有斜线最右侧的是文件名，所以%%~na只能获取到【日时分】

在你的代码基础上修改如下：

@echo off
setlocal enabledelayedexpansion
for %%F in (*) do (
    if "%%F" neq "%0" (
        set "datetime_str=%%~tF"
        REM 去掉日期和时间中的空格、冒号、斜线，只保留数字部分
        set "formatted_datetime=!datetime_str: =!"
        set "formatted_datetime=!formatted_datetime::=!"
        set "formatted_datetime=!formatted_datetime:/=!"
        ren "%%F" "!formatted_datetime!_%%F"
    )
)
复制代码

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

Rank: 5 Rank: 5

帖子: 835
积分: 1163
技术: 115
捐助: 0
注册时间: 2021-8-26

4楼

发表于 2023-9-14 16:22 | 只看该作者

日期格式问题?
例如英文系统默认日期连接符是斜杠("/") 2023/09/14

Rank: 6 Rank: 6

帖子: 1702
积分: 2790
技术: 342
捐助: 50
注册时间: 2022-9-18

3楼

发表于 2023-9-14 16:15 | 只看该作者

@echo off
setlocal enabledelayedexpansion

for %%F in (*) do (
    rem 获取文件的最后修改日期和时间
    echo %%~tF
    for %%a in ("%%~tF") do (
        set "datetime_str=%%~na"
        echo set "datetime_str=%%~na"
    )
	pause
    rem 去掉日期和时间中的空格和冒号，只保留数字部分
    set "formatted_datetime=!datetime_str: =!"
    set "formatted_datetime=!formatted_datetime::=!"
    
    rem 重命名文件
    ren "%%F" "!formatted_datetime!_%%F"
)

endlocal
pause
复制代码

bat小白，请多指教！谢谢！

Rank: 4

帖子: 302
积分: 448
技术: 2
捐助: 0
注册时间: 2015-4-10

2楼

发表于 2023-9-14 15:40 | 只看该作者

我有个现成的年月日时分秒的代码，给你参考。没有点

@echo off
echo.
echo 年-月-日-小时-分钟-秒
set datevar1=%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%%time:~6,2%
echo "%datevar1%.jpg"
echo.
echo 年-月-日
set datevar2=%date:~0,4%%date:~5,2%%date:~8,2%
echo "%datevar2%.jpg"
echo.
echo 小时-分钟-秒
set datevar3=%time:~0,2%%time:~3,2%%time:~6,2%
echo "%datevar3%.jpg"
echo.
echo.
复制代码