[文本处理] [已解决]求大神对批处理优化、勘误

zldarwin

近日通过论坛帮助，解决了多年的兼容性设置问题（站内链接），感谢 Batcher 的专业解答。

随后补充细节，虽测试正常，仍怕隐藏致命问题，仍想继续完善，诚邀大神们指正。

看看能否“优化语句语法、精简代码、使逻辑顺序更合理”等。

批处理用于执行自解压安装包后的自动设定。

::
::旨在优化电子课堂安装流程
::

@echo off

set AppName=幼幼版3~4岁D.exe
set CompLayer=~ WIN7RTM
set Folder=幼幼版3~4岁D

::创建自定义桌面快捷方式
set qbmname=创意阅读(上)2~3岁 D.lnk
set qbmexec=%~dp0幼幼版3~4岁D.exe
mshta VBScript:Execute("Set a=CreateObject(""WScript.Shell""):Set b=a.CreateShortcut(a.SpecialFolders(""Desktop"") & ""\%qbmname%""):b.TargetPath=""%qbmexec%"":b.WorkingDirectory=""%~dp0"":b.Save:close")

::检测系统版本后，安装不同版本Adobe Air
for /f "delims=" %%i in ('ver') do (
    set "version=%%i"
)
set "version=%version:~-9,3%"
if "%version%" equ "6.1" (
    echo Windows 7
    start %Folder%\adobeAirV32.exe
) else (
    echo Windows 10/11
    ::Win10/Win11下，设置系统兼容性
    reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers" /v "%~dp0%AppName%" /t REG_SZ /d "%CompLayer%" /f
    start %Folder%\adobeAirV29.exe
)

::打开官网登录页
start http://www.magepark.cn/login/
复制代码

zldarwin

回复 2# Batcher


   
收到，感谢 Batcher ~

Batcher

回复 1# zldarwin

set "AppName=幼幼版3~4岁D.exe"
复制代码

set命令使用双引号的好处：
1、避免字符串里面有特殊字符导致出错。
2、避免行尾不小心出现多余空格导致出错。

start "" "%Folder%\adobeAirV29.exe"
复制代码

start命令使用双引号的好处：
避免路径中包含空格或特殊字符导致出错。