[其他] 【已解决】BAT脚本批量修改某目录下几千个文件名

zhengwei007

我的目录下有几千个文件，文件顺序是1-1.jpg,1-2.jpg,1-3.jpg，2-1.jpg,2-2.jpg,2-3.jpg……
我想通过批处理，让这些文件名全部修改为如下顺序：
Shot00000.jpg
Shot00001.jpg
Shot00002.jpg
Shot00003.jpg
Shot00004.jpg
Shot00005.jpg

相当于让1-1.jpg改成了Shot00000.jpg。1-2.jpg改成了Shot00001.jpg……2-3.jpg改成了Shot00005.jpg
感谢各位大佬。

qixiaobin0715

简化一下楼上代码：

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1* delims=," %%i in (a.txt) do (
    if %%j geq 10 (
        set a=!a!3
    ) else if %%j leq -2 (
        set a=!a!1
        if "!a:~-7!"=="3333111" (
            if "!a:2=1!"=="1113333111" (
                set /a n=%%i-10+1
                echo,!n!-%%i
            )
        )
    ) else if %%j leq 6 (
        set a=!a!2
    ) else (
        set a=!a!4
    )
    set a=!a:~-9!
)
pause
复制代码

qixiaobin0715

这样与18楼代码相比要简单一些：

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1* delims=," %%i in (a.txt) do (
    if %%j geq 10 (
        set a=!a!3
    ) else if %%j leq -2 (
        set a=!a!1
        if "!a:~-7!"=="3333111" (
            if not "!a:~9!"=="" (
                set b=!a:~,3!
                set b=!b:2=!
                if "!b:1=!"=="" (
                    set /a n=%%i-10+1
                    echo,!n!-%%i
                )
            )
        )
    ) else if %%j leq 6 (
        set a=!a!2
    ) else (
        set a=!a!4
    )
    set a=!a:~-9!
)
pause
复制代码

qixiaobin0715

cmd本身就不适合处理较为复杂的或者数据量较大的问题，即使加入第三方。

aloha20200628

回复 24# qixiaobin0715

      其实众人给求助者的绝大部分代码都假定是处理小数据，dir和那些便于预装的第三方操作就顺便直接放在 for ... () 的命令表达式中，不用临时文件以免代码倒腾...
      个人经验是当被处理数据过千行就一定采用临时文件的方法，跳出 for...() 的狭窄 ‘管道井’，尤其是对硬件配置较低的实况，而一旦如此，那些被c/c++打造的第三方会充分发挥速度优势，是纯P代码远所不及的，因此能用此法叫第三方代劳越多，整个批处脚本的效率就会越高...

qixiaobin0715

回复 11# aloha20200628
实际上对于本题来说，只是处理几千条信息而已，效率问题可以忽略。
退一步来说，在for循环中反复调用第三方也会拖累一定的处理速度。在for循环外使用第三方生成临时文件，再用for循环读取临时文件可能效率会更高一些。

qixiaobin0715

回复 21# buyiyang
每次读取10行文本就跳转感觉有点浪费，这样是否要节约些：

@echo off
setlocal enabledelayedexpansion
set /a n=n1=n2=n3=p=0
:loop
set /a p+=1
setlocal
for /f "%skip%tokens=1-2 delims=," %%i in (a.txt) do (
    set /a n+=1
    if %%j leq 6 (
        if !n! leq 3 set /a n1+=1
        if !n! equ 1 set "s=%%i"
        )
    if %%j geq 10 if !n! geq 4 if !n! leq 7 set /a n2+=1
    if %%j leq -2 if !n! geq 8 set /a n3+=1
    if !n! equ 10 (
        rem echo,!n1!,!n2!,!n3!
        if !n1! equ 3 if !n2! equ 4 if !n3! equ 3 echo,!s!-%%i
        )
    if !n! equ 10 set /a n=n1=n2=n3=p=0
    )
endlocal
set "skip=skip=%p%"
if %p% lss 10 goto :loop
pause&exit
复制代码

qixiaobin0715

实际上20、21楼的代码都是迭代法，20楼是逐行错位迭代。虽然在这里与15楼的“if到底”的要求不是太合辙，看样子迭代法是解决此类问题的其中一个捷径。
如果要用迭代法的话还是原贴中那位大佬代码更简洁，直接原地迭代：

set a1=!a2!
set a2=!a3!
...
set a9=!a10!
set a10=%%b
if defined a1 if !a1! leq 6 if !a2! leq 6...
复制代码

后面部分和20楼差不多。

buyiyang

回复 15# qixiaobin0715


    这个也可以用迭代法

@echo off
setlocal enabledelayedexpansion
set /a n=n1=n2=n3=p=0
:loop
set /a p+=1
setlocal
for /f "%skip%tokens=1-2 delims=," %%i in (1.txt) do (
    set /a n+=1
    if %%j leq 6 (
        if !n! leq 3 set /a n1+=1
        if !n! equ 1 set "s=%%i"
        )
    if %%j geq 10 if !n! geq 4 if !n! leq 7 set /a n2+=1
    if %%j leq -2 if !n! geq 8 set /a n3+=1
    if !n! equ 10 (
        rem echo,!n1!,!n2!,!n3!
        if !n1! equ 3 if !n2! equ 4 if !n3! equ 3 echo,!s!-%%i
        endlocal&set "skip=skip=%p%"&goto :loop
        )
    )
pause&exit
复制代码

aloha20200628

回复 15# qixiaobin0715

幸亏能用一串 ‘逻辑与’ 的 if 句式
假设35个数用如下格式存于 1.txt
1,8
2,-8
3,5
4,0
5,25
6,30
7,18
8,50
9,-12
10,-22
11,-5
12,4
13,11
14,20
15,55
16,33
17,-22
18,-10
19,-3
20,10
21,9
22,5
23,0
24,-5
25,14
26,22
27,50
28,89
29,-9
30,-33
31,-12
32,-66
33,8
34,-9
35,8

@echo off &setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=, " %%a in (1.txt) do set/a "n+=1" &set "_%%a=%%b"
set/a "k=!n!-9"
for /l %%n in (1,1,!k!) do (
	set/a "m=%%n+9,i=1"
	for /l %%v in (%%n,1,!m!) do set "$!i!=!_%%v!" &set/a "i+=1"
	if !$1! leq 6 if !$2! leq 6 if !$3! leq 6 if !$4! geq 10 if !$5! geq 10 if !$6! geq 10 if !$7! geq 10 if !$8! leq -2 if !$9! leq -2 if !$10! leq -2 (
		echo,同时满足3个条件的10个连续数（行号）= {%%n-!m!}
	)
)
endlocal&pause&exit/b
复制代码

77七

回复 18# qixiaobin0715


   
谢谢大佬分享！确实太复杂了，和出题挑战区的数学题目一样，反正我暂时不想想这个。

qixiaobin0715

回复 16# 77七
烧脑的if判断语句！！！
可能会有bug。
x变量分别表示设定的连续数值出现的次数；
n变量分别表示实际的连续数值动态出现的次数；

@echo off
set /a x1=3,x2=4,x3=3
set /a n1=n2=n3=0
setlocal enabledelayedexpansion
for /f "tokens=1* delims=," %%i in (a.txt) do (
    if %%j geq 10 (
        if !n1! lss !x1! (
            set /a n1=n2=n3=0
        ) else (
            if !n3! neq 0 (
                set /a n1=n2=n3=0
            ) else (
                set /a n2+=1
                if !n2! gtr !x2! set /a n1=n2=n3=0
            )
        )
    ) else if %%j leq 6 (
        if !n2! equ 0 (
            set /a n1+=1
        ) else (
            if !n2! equ !x2! (
                if %%j leq -2 (
                    set /a n3+=1
                    if !n3! equ !x3! (
                        set /a m=%%i-10+1
                        echo,!m!-%%i
                        set /a n1=n3
                        set /a n2=n3=0
                    )
                ) else (
                    set /a n1=n3+1
                    set /a n2=n3=0
                )
            ) else (
                set /a n1=1
                set /a n2=0
            )
        )
    ) else (
        set /a n1=n2=n3=0
    )
)
pause
复制代码

还没想到更简单的方法，现在只能这样了。
写代码的过程中发现，考虑实际问题时和17楼的思路还是有很大的差异，上下左右都有牵扯，有一点考虑不到就会出问题。

qixiaobin0715

回复 16# 77七
是挺复杂的，我现在也没有写出来 。
但思路有了。
分别从上到下统计符合要求的数值连续出现的次数。
需要分级设定锚点：
第1级，如果出现不符合数值（小于10且大于6），所有的先前统计次数均要清零，从下一行开始重新统计；
第2级，对于出现大于等于10的数值。
          如果首次出现，向上追溯，如果最近3行不是连续数值小于等于6，所有的统计次数均要清零，重新统计；
          如果连续出现多于4次，所有的统计次数均要清零，重新统计；
第3级，对于出现小于或等于-2的数值的情况。
          如果首次出现，向上追溯，如果第2级未通过（即次数为1-3），所有的统计次数均要清零，将本次数值统计到小于等于6的次数中；
应当还有一些要考虑的细节，较为繁琐，不再一一罗列。大致就是这样。
可能还有更好的思路。

77七

回复 15# qixiaobin0715


   大佬，这个比重命名复杂多了，我写不出来。

qixiaobin0715

回复 13# 77七
既然这么喜欢if，给你找个素材练练手，大概是两三年前的一个帖子，由于关注度不大，原贴未找到。一个大佬用迭代法解决的，在这里设定就用“if到底”求解，文本如下：

1,8
2,-8
3,5
4,0
5,25
6,30
7,18
8,50
9,-12
10,-22
11,-5
12,4
13,11
14,20
15,55
16,33
17,-22
18,-10
19,-3
20,10
21,9
22,5
23,0
24,-5
25,14
26,22
27,50
28,89
29,-9
30,-33
31,-12
32,-66
33,8
34,-9
35,8
复制代码

前面是序号，后面是数值。
找出连续3个数值小于等于6；接着连续4个数大于等于10；再接着连续3个数小于等于-2，共10个连续数值。不止一组数值符合以上条件啊，重叠也算。找到后显示序号比如10-19。
要注意第一个条件的数值包含第三个条件的数值。
原贴都是连续3个数值，记得我当时是取巧解决的，这里第二个条件是连续4个数值，增加了一些难度。
没什么实际用处，只是练练手，博得一笑而已，别当回事。