[文本处理] 批处理怎样查找第二次出现的字串并替换为换行？

lj84831253

假设1.txt文本里边的内容为：
<a herf=11111111
<a herf=hsvkvfb<a herf=333333
<a herf=4444444
<a herf=hdhakdhad<a herf=bfsfkfsf<a herf=skfhsjfj
要求替换后1.txt里边的内容为：
<a herf=11111111
<a herf=hsvkvfb
<a herf=333333
<a herf=4444444
<a herf=hdhakdhad
<a herf=bfsfkfsf
<a herf=skfhsjfj


也就是说如果一个文本行里边如果有两个或两个以上的<a herf=，则在该行的第二个<a herf=开始以及之后的所有<a herf=前面加上换行符。

CrLf

另类思路，速度很快：

@echo off&setlocal enabledelayedexpansion
set hh=^


(for /f "delims=" %%a in (a.txt) do (
	set tmp=%%a
	for %%b in ("!hh!") do echo !tmp:^<a herf=%%~b^<a herf!
                rem 换行符必须绕过对语句进行划分的预处理阶段，所以需要开启变量延迟，并通过for实现嵌套
))>tmp
::将所有“<”替换为“换行<”
(for /f "delims=" %%a in (tmp) do echo %%a)>a.txt
::去除多余空行
复制代码

lvsehuaxue

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do call :out "%%i"
pause   
:out
set "v=%~1"
:r
for /f "tokens=1* delims=<" %%i in ("!v!") do (
    echo ^<%%i
    if "%%j" neq "" set "v=%%j"&goto :r
)
复制代码

Batcher

能否把数据更新到顶楼？

lj84831253

原帖由 hanyeguxing 于 2010-6-12 09:54 发表
先备份原文件！
方法1，纯P（在必要的时候，将代码中的#替换成文本中其他不使用的字符）：@echo off
(for /F "delims=" %%a in (1.txt) do (set a=%%a
setlocal enabledelayedexpansion
set "a=!a:2.txt
(for / ...

大侠你下我附件试试，，谢谢。

lj84831253

为什么我测试这个1.txt不成功呢？

CUer

sed -i -r "s/(.)(<a herf)/\1\n\2/g" 1.txt
复制代码

hanyeguxing

先备份原文件！
方法1，纯P（在必要的时候，将代码中的#替换成文本中其他不使用的字符）：

@echo off
(for /F "delims=" %%a in (1.txt) do (set a=%%a
setlocal enabledelayedexpansion
set "a=!a:<a herf=&echo.#a herf=!"&call:a "!a!"
Endlocal))>2.txt
(for /F "delims=" %%a in (2.txt) do (set a=%%a
setlocal enabledelayedexpansion
set "a=!a:#=<!"&echo.!a!
Endlocal))>1.txt
del 2.txt&exit
:a
echo.%~1
复制代码

方法2，使用第三方工具如fr、sed、gawk等：
将所有的“<a herf=”替换为“回车换行符+<a herf=”，然后删除空行。

[ 本帖最后由 hanyeguxing 于 2010-6-12 15:17 编辑 ]