[网络连接] 批处理怎样测试与子公司网络连通性？

hy_access

目的如下：
   ping和tracert测试与子公司的连通性，得出网络是否连通以及数据包走向。（ping和tracert分不分开倒是无所谓的）

需求介绍：
现在处的位置是总公司，子公司通过VPN连接到总公司，需要在办公段各时段使用ping测试与子公司的网络连通性，tracert测试数据包的走向。因为公司是双线接入，即：电信和网通。 需要监控的是 网络是否连通 还有网络的延迟（time值）等因素。以此为依据来优化网络。

其实我已经有一个测试的批处理，就是在本论坛求助的，现在可能无法满足需求，如下：
@echo off&setlocal enabledelayedexpansion
for /f "tokens=1* delims=：" %%a in (地址簿.txt) do (
      set "ip=%%b"&echo %%a>>ping.txt
      for %%i in (!ip!) do (
               echo ping结果&echo ;
               ping %%i>>ping.txt
))
希望各位高手不吝赐教，帮小弟一把。
PS：我是去年的注册会员，因为工作原因，很长时间没有到论坛来了。。着实感到抱歉，希望能加入技术讨论群，我已经申请入群，不过还没回应。希望能和大家一起学习讨论批处理技术。谢谢！

hy_access

首先谢谢 TX_kakashi  慷慨相助。实现的功能是我想要的，但是能不能微调一下,可能更完善：
输出ping回应：Reply from 172.16.0.251: bytes=32 time=5ms TTL=255（之所以要这样主要是看TIME值）
将P处理得到的结果输出到文本文档内或EXCEL内。
PS：我只会简单的网管测试命令。深一点的P处理没怎么接触过。日后慢慢学习！希望路过大大不吝赐教。。。


谢楼上。TX_kakashi    、 请斑竹结贴。

[ 本帖最后由 hy_access 于 2010-8-9 14:13 编辑 ]

TX_kakashi

不知道怎么用tracert怎么检测，所以把所有tracing的输出都显示出来了。地址文件格式为每行一个地址。
重新修改了一下，现在把ping的回显打开了，并把所有检查的数据都输出到ipLog.txt里。输出内容没做筛选，可能有点乱。有别的需要的话pm我就行。

@echo off
set "connection=DISCONNECTED"
set "traceReq=false"
title %date%
:bof
set /p myfile=[把地址文件拖到这里并按Enter]
if not exist %myfile% goto bof
echo.
echo %date%%time%>ipLog.txt
for /f "delims=" %%a in ('type %myfile%') do call :ipCheck %%a
echo.
echo 检测完成，按任意键退出!
pause>nul
exit 
:ipCheck
title ^>^>^>Pinging [%~1]^<^<^<
ping %~1>pingTemp
type pingTemp | find /i "lost = 4" >nul 2>nul
if /i {%errorlevel%}=={1} set "connection=connected" & set "traceReq=true"
type pingTemp
if {%traceReq%}=={false} goto finishCheck
title [%~1 STATUS:%connection%] ^>^>^>Tracing...Please wait...^<^<^<
tracert /d %~1>traceTemp
more +4 traceTemp
:finishCheck
echo.
type pingTemp>>ipLog.txt 2>nul
type traceTemp>>ipLog.txt 2>nul
echo ===============================================>>ipLog.txt
echo.>>ipLog.txt
echo ===============================================
::resetEverything
title %date%
set "traceReq=false"
set "connection=DISCONNECTED"
del pingTemp>nul 2>nul
del traceTemp>nul 2>nul
exit/b
复制代码

[ 本帖最后由 TX_kakashi 于 2010-8-9 13:58 编辑 ]

hy_access

各位大大。我在线等。。。！有什么疑问尽管回帖提