[文本处理] 批处理怎样以特定方式输出文本字符？

er8852973

在hh.txt中，存在几行字符 我想一次输出相邻的两个字符 但怎么就是做不到呢

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%i in (hh.txt) do (
set a=%%i
for  %%i in (!a!) do (
set b=!a:~0,2!
echo !b!
set a=!a:~2!
)
pause>nul
)
pause
复制代码

真的想不通以上代码错在何处 请指教！

tmplinshi

for  %%i in (!a!) do ( 这句中，如果 !a! 里含有“?”或“*”，for 是去查找文件而不是处理字符串，找不到文件的话，这个 for 里面的语句不会执行。

CrLf

for  %%i in (!a!) do ( 这句中，如果 !a! 里含有“?”或“*”，for 是去查找文件而不是处理字符串，找不到文件的话，这个 for 里面的语句不会执行。
tmplinshi 发表于 2011-4-1 20:33

以前还没注意过这个，看来以后要当心了

broly

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%i in (hh.txt) do (
  set "a=%%i"
  for /l %%j in (0 2 65534)  do (if not "!a:~%%j,2!"=="" echo !a:~%%j,2!)
)
pause
复制代码

CrLf

看不懂楼主的代码，为什么要用多余的for？

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%i in (hh.txt) do (
set a=%%i
echo !a:~0,2!
set a=!a:~2!
pause>nul
)
pause
复制代码

hanyeguxing

楼主首先要说明具体要做什么？

er8852973

我是lz  我的代码的目的就是输出文字 我打个比方吧 比如下面的文字
“我初学批处理我是菜鸟请大家多指教”
我想让上面的字符这样输出
“我初 学批 处理 我是 菜鸟 请大 家多 指教”
就是每两个字一起输出就行 中间用空格或者换行隔开都行

er8852973

5楼的朋友 我用两个for是想一个用来选取一段文字的每一行 另一个for对选出的行进行逐字的处理 不知道我的思路对不 呵呵  请指教

wc726842270

4# broly

4L能否说下范围为什么是0到65534之间。
PS：希望4L能给予答复

CrLf

65534太多了，一个变量最多8192字节

wc726842270

呵呵，仅是想上BROLY再上一次线。很久没看见了，这个应该是一行的最大字节，至于字符那好像要看是什么格式的文本了

tmplinshi

@echo off
for /f "delims=" %%a in (a.txt) do (
    set s=%%a
    SetLocal EnableDelayedExpansion
    if "!s:~2,1!" == "" (
        rem 如果字符数小于 3，则直接输出
        echo !s!
    ) else (
        rem ---------- 计算字符个数 ----------
        set /a a = 8189, c = 0
        for /l %%a in (1 1 13) do (
            set /a "b = (a - c) / 2 + c"
            for %%b in (!b!) do (
                if "!s:~%%b,1!"=="" (set a=!b!) else set c=!b!
            )
        )
        rem ---------- / 计算字符个数 ----------
        for /l %%a in (!a! -2 1) do echo,!s:~-%%a,2!
        EndLocal
    )
)
pause
复制代码

broly

9# wc726842270


呵呵，并没有什么特别的意思，就是凑一个差不多的数字。

er8852973

对了 能不能帮我看看我的代码错在哪里啊

er8852973

还要谢谢12楼的朋友 你的代码实现了我的要求 但我的代码错在哪里 帮我看看呗 谢了啊