[注册表类] 【已解决】批处理怎么读取注册表字符串值名称并只取两个不同的输出

小智BAT

我想通过注册表查找
HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Installer\Folders中的字符串值名称是否包含WFOActive
并输出该完整的字符串值名称，其中字符串值名称有多个包含“WFOActive”
如有多个字符串值名称如下：
C:\Program Files (x86)\WFOActive\V4用户认证\
E:\V5认证\WFOActive\V4用户认证\
E:\V5认证\WFOActive\
C:\Program Files (x86)\WFOActive\
我需要输出“C:\Program Files (x86)\WFOActive\”和“E:\V5认证\WFOActive\”上一级目录就好，其他不要输出。如何解决？
如果没有找到则提示没有安装该软件。

注意：如果安装在d盘，其字符串值名称会改为d盘的路径名称。

terse大神给出了输出一个的方法：

@echo off&setlocal enabledelayedexpansion
set "s=V4用户认证"
set "reg=reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Installer\Folders"
set "find=findstr/i \\%s%\\.*REG_SZ
for /f "tokens=*" %%i in ('%reg% 2^>nul^|%find%') do (
    set "var=%%i"
    set var=!var:\%s%\=\%s%^

!
    for /f "delims=" %%a in ("!var!") do (
        if /i "%%~nxa" == "%s%" (
           if not defined a (set a=%%~dpa)else set b=%%~dpa
        )
    )
)
if not defined a (
   echo,没有%s%目录
)else echo %a%&if defined b echo %b%
pause
复制代码

感谢大神帮忙
感谢批处理论坛

terse

最后你可加个目录判断

@echo off
set "s=vc"
set "reg=reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Installer\Folders /f \%s%\ /t REG_SZ"
set "find=findstr/ic:\\%s%\\"
for /f "tokens=*" %%i in ('"%reg%|%find%"') do set str=%%~dpi
if defined str (echo(%str%) else echo,没有安装%s%软件
pause
复制代码

小智BAT

回复 2# terse

你这个代码不行啊，vc是输出了，但是把vc改为wfo就一闪而过了。。。。。。是不是哪错了？而且这个查找路径定在C盘了，如果不是安装在C盘呢？

terse

回复 3# 小智BAT
这个是查找注册表的 不是针对C盘的  既然vc可以 那会不会注册表里路径问题
是路径括号问题
变更下

@echo off
set "s=WFOActives"
set "reg=reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Installer\Folders /f \%s%\ /t REG_SZ"
set "find=findstr/ic:\\%s%\\"
for /f "tokens=*" %%i in ('"%reg%|%find%"') do (
    for /f "tokens=*" %%a in ("%%i\..") do if "%%~nxa" == "%s%" set "str=%%~fa\"
)
if not defined str (echo,没有安装%s%软件)else echo(%str%
pause
复制代码

小智BAT

回复 4# terse


  发现一个问题，直接双击是可以，但是在iBAT里面调试出现

不知道什么原因。

小智BAT

回复 4# terse


    那该如何修改？？

terse

回复 6# 小智BAT
上面已修正 不知道是取最后含有 WFOActive 还是其他条件
错误提示 加个屏蔽吧  2>nul

小智BAT

回复 7# terse


    win7测试没问题了，可是xp下运行却出现
错误：命令行参数太多

terse

回复 8# 小智BAT
XP

@echo off
set "s=WFOActive"
set "reg=reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Installer\Folders"
set "find=findstr/ic:\\%s%\\
for /f "tokens=*" %%i in ('%reg% 2^>nul^|%find%^|findstr/ic:REG_SZ') do (
    for /f "tokens=*" %%a in ("%%i\..") do if "%%~nxa" == "%s%" set "str=%%~fa\"
)
if not defined str (echo,没有安装%s%软件)else echo(%str%
pause
复制代码

小智BAT

回复 9# terse


    xp下不行，说没找到安装软件。

小智BAT

回复 9# terse


    能不能一起兼容xp和win7的？

terse

回复 10# 小智BAT
什么情况 刚刚xp 测试可以 现在WIN7也行

草 这里第三行 最后多个 S   ...\Folderss"

小智BAT

回复 12# terse


   单单这个文件就行了，可是我套用进入我之前写的bat就不行了。提示显示没安装软件。但单但你命令就行，好奇怪啊。

小智BAT

回复 12# terse


    能不能换个写法，因为我复制文件到找到的目录的。

Batcher

回复 13# 小智BAT


    完整代码发出来看看