批处理找1-100以内的所有勾股数？

youxi01

勾股数即符合勾股定律(勾三股四弦五）的数。
通俗的说就是两个数的平方和等于另外一个数的平方
如：3^2+4^2=5^2

foxJL

@echo off
set x=1
set /p max=打印出多少以内的勾股弦组合（勾^>3）：
:x
set /a x+=2,s=x*x,y=s/2,z=y+1
echo %x%,%y%,%z%
if %x% lss %max% goto x
pauseCOPY

foxJL

上面的代码算的不够全面.

[ 本帖最后由 foxJL 于 2008-3-23 15:48 编辑 ]

more

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1,1,100) do (
for /l %%b in (%%a,1,100) do (
for /l %%c in (%%b,1,100) do (
set /a aa=%%a*%%a+%%b*%%b
set /a ab=%%c*%%c
if !aa!==!ab! echo %%a %%b %%c
)
)
)
echo.&pauseCOPY

随风

4楼方法不错，稍加改进，不用临时文件，并取消对临时文件的循环次数。同时过滤掉了重复的数
:

@echo off&setlocal EnableDelayedExpansion
for /l %%a in (1 1 100) do (
  set /a a%%a=%%a*%%a
  set t!a%%a!=%%a
)
  for /l %%a in (1 1 100) do (
  for /l %%b in (%%a 1 100) do (
  set /a c=%%a*%%a+%%b*%%b
  if defined t!c! (
  call echo %%a %%b %%t!c!%%
  set /a abc+=1
)))
echo.&echo 共有 %abc% 个
echo.&pauseCOPY

[ 本帖最后由 随风 于 2008-3-28 20:56 编辑 ]

lhjoanna

恩，第一个for循环是把100以内的所有的数的平方与变量t!a%%a!对应起来吧？然后只要两个数相加的平方已经定义过，就是勾股数了。是这样理解吧？

keen

不能避免重复的，例如：3^2+4^2=5^2    4^2+3^2=5^2，请高手指正！

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 100) do (
    set /a s1=%%i*%%i
        for /l %%j in (1 1 100) do (
            set /a s2=%%j*%%j
            set /a s3=!s1!+!s2!    
                for /l %%k in (1 1 100) do (
                    set /a s4=%%k*%%k
                    if "!s4!"=="!s3!" echo %%i^^^^2+%%j^^^^2=!s4!
)
)
)
pauseCOPY

[ 本帖最后由 keen 于 2009-4-2 13:54 编辑 ]

sjzong

这个题目如果用三个循环的话，那效率是比较低。先是kclmx先引入临时文件，然后是随风进行改进，厉害，随风版主的代码效率高多了！

pusofalse

下一层for的起始值换成上一层for中递增的值试下。

defanive

这个题目，不用递归法吧，效率低。。。
感觉最自然就是循环a，分解质因数，然后解方程求出b，c。。。
并且令b<a时才显示出来，就可以避免重复，而且应该所有都能罗列了吧。。。

keen

11楼的想法跟我今天才想到得一样。避免了重复。修改9楼代码如下：

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 100) do (
    set /a s1=%%i*%%i
        for /l %%j in (%%i 1 100) do (
            set /a s2=%%j*%%j
            set /a s3=!s1!+!s2!
                for /l %%k in (1 1 100) do (
                    set /a s4=%%k*%%k
                    if "!s4!"=="!s3!" echo %%i^^^^2+%%j^^^^2=!s4!
)
)
)
pauseCOPY

但是效率还是低下，期待高手给出效率高的代码。

[ 本帖最后由 keen 于 2009-5-12 18:54 编辑 ]

plp626

真正的秒杀：

@echo off&if not %1.==. call%*&exit/b:: Code By plp626
title 输出任意多的互质（素）的勾股数&echo 稍等...
set MAX=30  &rem ::1000的开平方为31.6，这里设定MAX为30，就已经遍历1000以内的勾股质数
set "_isprime=set #r=+&for /l %%a in (1 1 6)do if ^!#r^! neq 0 (set/a #r=#1%%#2,#1=#2,#2=#r) else set ans=!#1!"
for /f "delims=" %%a in ('%~s0 :rtnum^|sort')do echo.%%a
pause&exit/b
:rtnum
setlocal enabledelayedexpansion&set "s=        "
for /l %%n in (1 1 %MAX%)do (set/a tp=%%n+1
for /l %%m in (!tp! 2 %MAX%)do (set #1=%%m&set #2=%%n&%_isprime%
        if !ans! equ 1 (set/a mm=%%m*%%m,nn=%%n*%%n,a=mm-nn,b=2*%%m*%%n,c=mm+nn
                set a=%s%!a!&set b=%s%!b!&set c=%s%!c!
        if !a! lss !b! (echo !a:~-7! !b:~-7! !c:~-7!) else echo !b:~-7! !a:~-7! !c:~-7!
)))
exit/b

[ 本帖最后由 plp626 于 2009-10-15 14:46 编辑 ]

Seter

可恶的plp...居然抢了我的位置...话说这个解法我似乎看到过...就是对于任意数字m,n,m^2+n^2,m^2-n^2,2mn为勾股数...
不过我自己曾经也研究过勾股数的计算...我做个效率低点的

[ 本帖最后由 Seter 于 2009-10-15 19:30 编辑 ]

poxi

新手来了.........试了一下...弄出来好多，，ms去了重....
答：

@echo off
setlocal EnableDelayedExpansion
for /l %%a in (1,1,100) do (
set zs1=%%a
set /a m1=!zs1!*!zs1!
for /l %%b in (!zs1!,1,100) do (
set zs2=%%b
set /a m2=!zs2!*!zs2!
for /l %%c in (!zs2!,1,100) do (
set zs3=%%c
set /a m3=!zs3!*!zs3!
set /a ds=!m1!+!m2!
if !ds! equ !m3! echo !zs1! !zs2! !zs3!
)
)
)
pauseCOPY

===============
对了的话要奖励...........end；

尘丶

@echo off&setlocal enabledelayedexpansion
set /p num=输入多少以内的勾股数:
for /l %%a in (3,1,%num%) do (
    for /l %%b in (4,1,%num%) do (
        for /l %%c in (5,1,%num%) do (
            set /a num1=%%a*%%a 
            set /a num2=%%b*%%b
            set /a num3=%%c*%%c  
            set /a num4=!num1!+!num2!
            if !num3!==!num4! echo;%%a,%%b,%%c
)
) 
)
pauseCOPY

终于能写一道数学批处理了。