[文本处理] 【已解决】求批量提取文件内容BAT代码？

meiszp

文件夹下有多个.txt文件，名字随意
101.txt
102.txt
201.txt
202.txt
……


逐个打txt文件，在下面位置提取数据
excluding mass coefficients

  MAIN ST. K = 0.134791E+06 [N/M]     X-C. ST. k = 0.485545E+05 [N/M]

  MAIN D.  C = 0.589759E+02 [NS/M]     X-C. D.  c = -.131594E+02 [NS/M]
  
*********************************************************************************

提取上面行中的红字数据写入out.txt
第1列文件名，第2～5列为图片中提取的数据，按1、2、3、4顺序写入

101        0.134791E+06        0.485545E+05        0.589759E+02        -.131594E+02
102        0.465204E+05        -.281788E+05        0.486467E+02        0.489242E+02
201        0.231737E+06        0.802880E+05        0.105552E+03        -.192042E+02
202        0.667682E+05        -.435220E+05        0.695443E+02        0.780624E+02
附件上传不了，试验用的文件
https://pan.baidu.com/s/1WWO7qBNrUT_zOM1chJ-1WQ?pwd=1nny

terse

@echo off&setlocal enabledelayedexpansion
(for /f "delims=" %%f in ('dir /b /a-d *.txt') do (
     set "exc="
     for /f "usebackq tokens=*" %%i in ("%%f") do (
          if defined exc (
               for /f "tokens=2,3delims==" %%a in ("%%i") do (
                    if "%%b" neq "" (
                         for %%A in ("%%a" "%%b") do (
                              for /f %%c in (%%A) do set "exc=!exc!	%%c"
                         )
                    ) else (
                         echo !exc!
                         set "exc="
                    )
               )
          )
          if /i "%%~xni" == "excluding mass coefficients" (set exc=%%~nf)
     )
))>out.txt 2>nul
pause
复制代码

77七

@echo off
chcp 65001 >nul
cd /d "%~dp0"
(for /f "delims=" %%x in ('dir /b /a-d *.txt ^|find /v "out.txt"') do (
	for /f "useback tokens=1-12" %%a in ("%%x") do (
		if /i "%%a%%b%%c" equ "excludingmasscoefficients" (
			set m=1
		) else if defined m (
			if /i "%%a%%b%%c" equ "MAINST.K" (
				set /p="%%~nx	%%e	%%k"<nul
			) else if /i "%%a%%b%%c" equ "MAIND.C" (
				echo=	%%e	%%k
				set m=
			)
		)
	)
))>"out.txt"
pause
复制代码

aloha20200628

回复 1# meiszp

输出结果文件为 out.txt.new，与被处理文件*.txt同目录
用楼主提供的4个示例文件测试通过...

@echo off &setlocal enabledelayedexpansion
(for /f "delims=" %%F in ('dir /b/s/a-d *.txt') do (
	set "v=%%~nF"
	for /f "tokens=1-4 delims==[" %%1 in ('findstr /ic:"MAIN ST. K =" /ic:"MAIN D.  C =" "%%F"^|more +2') do (
		set "v=!v!	%%2	%%4"
	)
	echo,!v: =!
))>out.txt.new
复制代码

hfxiang

回复 1# meiszp
用gawk（ http://bcn.bathome.net/tool/4.1.0/gawk.exe ）的解决办法如下：

gawk -v"OFS=\t" "/excluding mass coefficients/,/\*{60,}/{if(/MAIN/){A[++i]=$5;A[++i]=$11}if(/\*{60,}/)print substr(FILENAME,1,length(FILENAME)-4),A[1],A[2],A[3],A[4];next}{i=0}" *.txt>out.txt
复制代码

meiszp

回复 2# terse
谢谢大佬帮助。如果第1列不是文件名101而是文件里第5行的101，代码该怎么写？

meiszp

回复 3# 77七
谢谢热心帮助，运行代码显示" press any key to continue…"，out.txt为空。

meiszp

回复 4# aloha20200628
谢谢热心帮助，试验了下代码。如果文件夹下全是试验的txt文件，运行成功。
但如果有其他的txt文件，就会输出文件名。

meiszp

回复 5# hfxiang
谢谢热心帮助。

terse

回复 6# meiszp
是固定的第五行吗

aloha20200628

回复 8# meiszp

代码订正如下

@echo off &setlocal enabledelayedexpansion
(for /f "delims=" %%F in ('dir /b/s/a-d *.txt') do (
	set "v=%%~nF"
	for /f "tokens=1-4 delims==[" %%1 in ('findstr /ic:"MAIN ST. K =" /ic:"MAIN D.  C =" "%%F"^|more +2') do (
		set "v=!v!	%%2	%%4"
	)
	if "!v!" neq "%%~nF" echo,!v: =!
))>out.txt.new
复制代码

meiszp

回复 10# terse
是的，包含一行空白，是第5行，可以打开文件看看，第5行其实就是文件名称。

meiszp

回复 11# aloha20200628
完美，谢谢大佬！
如果还愿意的话可以再修改下代码

第1列不是文件名101而是文件里第5行的内容，代码该怎么写？
固定是第5行，可以打开txt看，第5行其实就是文件名。

aloha20200628

回复 13# meiszp

读取第5行还须删除前后空白字符...订正代码如下

@echo off &setlocal enabledelayedexpansion
(for /f "delims=" %%F in ('dir /b/s/a-d *.txt') do (
	(call :get5 "%%F" v5) &set "v=!v5!"
	for /f "tokens=1-4 delims==[" %%1 in ('findstr /ic:"MAIN ST. K =" /ic:"MAIN D.  C =" "%%F"^|more +2') do (
		set "v=!v!	%%2	%%4"
	)
	if "!v!" neq "!v5!" echo,!v: =!
))>out.txt.new
exit/b
:get5
   for /f "usebackq skip=4 tokens=1 delims=	 " %%s in ("%~1") do (set "%~2=%%s"&exit/b)
   exit/b
复制代码

77七

3楼代码使用楼主提供的文件，我这里测试结果正确。
根据楼主最新需求，以目标固定在文本第5 294 296行为规律，再写一个。

@echo off
chcp 65001 >nul
cd /d "%~dp0"
(for /f "delims=" %%x in ('dir /b /s /a-d *.txt') do (
	if "%%~nxx" neq "out.txt" (
		for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%x" ^|findstr /rb "\[5\] \[294\] \[296\]"') do (
			if not defined str (
				call :1 %%b
			) else (
				call :2 "%%b"
			)
		)
		call echo %%str%%
		set str=
	)
))>out.txt
pause & exit

	:1
	set str=%*
	exit /b
	:2
	for %%c in (%~1) do (
		if "%%~xc" neq "" (
			call set str=%%str%%	%%~nxc
		)
	)
	exit /b
复制代码