小智BAT

回复 15# Batcher


    好奇怪，用iBAT调试时出错，双击运行没事，正常。不知道什么原因。

小智BAT

回复 12# terse


    你好，很感谢你为我解决问题，但现在我遇到一个问题就是我要输出的是前一个目录，该如何实现？

例如我安装目录改为d盘的文件夹时，字符串的值不再有WFOActive。但是有固定的“V4用户认证”，当我得到路径时那该如何返回上级目录并输出？

如得出C:\Program Files (x86)\WFOActive\V4用户认证\目录，我要的是上级目录C:\Program Files (x86)\WFOActive\，但这个目录是变动的

可也是D:\Program Files (x86)\WFOActive、也可以是F:\新建文件夹。求解决。

terse

字符给吃了 换个方法试

@echo off&setlocal enabledelayedexpansion
set "s=V4用户认证"
set "reg=reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Installer\Folders"
set "find=findstr/i \\%s%\\.*REG_SZ
for /f "tokens=*" %%i in ('%reg% 2^>nul^|%find%') do (
    set "var=%%i"
    set var=!var:\%s%\=^

!
    for /f "delims=" %%a in ("!var!") do if not defined str set "str=%%a"
)
if not defined str (echo,没有%s%目录)else echo,%str%
pause
复制代码

Batcher

回复 16# 小智BAT


    你把这个问题反馈给iBAT的作者看看吧

小智BAT

回复 18# terse

你好，麻烦再解决下这个问题。非常感谢你。。。
    如果注册表有字符串值
D:\新建文件夹\WFOActive
D:\新建文件夹\WFOActive\V4用户认证
C:\Program Files (x86)\WFOActive
C:\Program Files (x86)\WFOActive\V4用户认证
我要把“C:\Program Files (x86)\WFOActive\V4用户认证”和“D:\新建文件夹\WFOActive\V4用户认证”的上一级目录都输出，该怎么解决？

terse

回复 20# 小智BAT

@echo off&setlocal enabledelayedexpansion
set "s=V4用户认证"
set "reg=reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Installer\Folders"
set "find=findstr/i \\%s%\\.*REG_SZ
for /f "tokens=*" %%i in ('%reg% 2^>nul^|%find%') do (
    set "var=%%i"
    set var=!var:\%s%\=\%s%^

!
    for /f "delims=" %%a in ("!var!") do (
        if /i "%%~nxa" == "%s%" set /an+=1&set "$!n!=%%~dpa"
    )
)
if not defined n (echo,没有%s%目录)else for /l %%i in (1,1,!n!) do echo,!$%%i!
pause
复制代码

小智BAT

回复 21# terse


    是可以输出了。那该如何取得它们的上一级目录呢？

小智BAT

回复 21# terse


  能不能把两显示的分别以
echo %a%
echo %b%
显示吗，因为我要定义set waya=%a% set wayb=%b%

这个可以现实吗？

terse

回复 23# 小智BAT
你举例2个变量 如果是三个或三个以上呢 上面修正为 $1  - $n

小智BAT

回复 24# terse


    最多两个，一般不会有第三个变量出现，能不能定义为：a ，b分别输出啊？

我是小白，不会拆分你的代码。。。。

小智BAT

回复 24# terse


    如果是多个是可以定义为way1=，way2，way3.。。。。。
可以这样的吗？不过我着一般只是出现2个，不会有第三个的。

小智BAT

回复 24# terse


    已经确定是两个变量了。不会存在第三个了，请大神给个再给个方案。万分感谢！！

terse

回复 27# 小智BAT

@echo off&setlocal enabledelayedexpansion
set "s=V4用户认证"
set "reg=reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Installer\Folders"
set "find=findstr/i \\%s%\\.*REG_SZ
for /f "tokens=*" %%i in ('%reg% 2^>nul^|%find%') do (
    set "var=%%i"
    set var=!var:\%s%\=\%s%^

!
    for /f "delims=" %%a in ("!var!") do (
        if /i "%%~nxa" == "%s%" (
           if not defined a (set a=%%~dpa)else set b=%%~dpa
        )
    )
)
if not defined a (
   echo,没有%s%目录
)else echo %a%&if defined b echo %b%
pause
复制代码