[文件操作] [已解决]BAT遍历批量替换文件名中的字符串

loquat

依葫芦画瓢画了三个都不成功。求解。
要求为遍历批量替换jpg文件中的中文括号为英文中括号。
结果见5#，6#，7#

@echo off
cd /d "%1"
for /f "delims=" %%i in ('dir *.jpg /s /b /a-d') do 
(set f = %%i
    set f = %%f:【=[%%
    set f = %%f:】=]%
    ren "%%i" "%%f%%"
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /r "%1" %%a in (*.jpg) do (
    set f = %%a
    set f = !f:【=[!
    set f = !f:】=]!
    ren "%%a" "!f!"
)
pause
复制代码

@echo off
if "%~1"=="" echo 请拖拽文件夹&pause&goto :eof
if not exist "%~1\" echo 请拖拽文件夹&pause&goto :eof
for /f "delims=" %%a in ('dir /a-d /b /s "%~1\*.jpg"') do
(
   for %%b in ("%%dpa..") do
   (
      set f = %%a
      set f = %%f:【=[%%
      set f = %%f:】=]%%
      ren "%%b" "%%f%%"
   )
)
pause
复制代码

请高人指点一下这三段代码的问题都在哪里。。。

terse

第二段 应可行

    set "f=%%a"
    set "f=!f:【=[!"
    set "f=!f:】=]!"
    ren "%%a" "!f!"
复制代码

loquat

回复 2# terse

@echo off
setlocal enabledelayedexpansion
for /r "%1" %%a in (*.jpg) do (
    set "f=%%a"
    set "f=!f:【=[!"
    set "f=!f:】=]!"
    ren "%%a" "!f!"
)pause
复制代码

似乎还是不行。。。提示找不到文件，不知道怎么扩展到完整的路径。

loquat

可否使用
ren *【*.jpg *[*.jpg
ren *】*.jpg *]*.jpg

loquat

两种方案都搞定

@echo off
setlocal enabledelayedexpansion
for /r %1 %%a in (*.jpg) do (
set "t=%%~nxa"
set "t=!t:【=[!"
set "t=!t:】=]!"
ren "%%a" "!t!"
)
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir %1\*.jpg /s /b /a-d') do (
set "f=%%~nxi"
set "f=!f:【=[!"
set "f=!f:】=]!"
ren "%%i" "!f!"
)
复制代码

loquat

去掉变量延迟。

@echo off
for /f "delims=" %%i in ('dir %1\*.jpg /s /b /a-d') do (
set "f=%%~nxi"
call set f=%%f:【=[%%
call set f=%%f:】=]%%
call ren "%%i" %%f%%
)
复制代码

loquat

临睡前解决4#方案，初学就不管效率了，呵呵
这个代码好像不行

@echo off
for /f "delims=" %%a in ('dir /s /b /a:d') do (
call cd /d "%%a%%"
ren *【*.jpg *[*.jpg
ren *】*.jpg *]*.jpg
)pause
复制代码

loquat

用好for和变量延迟，很重要

loquat

其实我还有个问题。
%1和%~1到底谁的通用性好？
是不是一样的通用性？%~1的效用就是删除引号。
而%1本身就是自带引号的。