[文本处理] [已解决]批处理如何将两空格之间的字乱序？

每天几分

额，最近要在短时间内熟悉汉字的编码，要不断练习条件反射，下面是一字对应一编码，请问批处理如何将他们乱序，字以及对应的编码不能乱，
只乱序空格前后的一字一编码。
如：

工a 式aa 匿aadk 慝aadn 葚aadn2 萁aadw 苯asg 蘸asgo 葙ash 蕈asj 菥asr 菘asw 攻at 苌ata
复制代码

可以乱序如下：

式aa 工a 攻at 匿aadk 慝aadn 菥asr 蘸asgo 葚aadn2 萁aadw 蕈asj 苯asg 菘asw 苌ata 葙ash
复制代码

也可以有不同的乱序。但必须保证字以及对应的编码不能乱。

pcl_test

@echo off
for /f "delims=:" %%a in ('more +9 %0') do (
setlocal enabledelayedexpansion
for %%b in (%%a) do set _!random!%%b=%%b
for /f "tokens=2 delims==" %%i in ('set _') do set /p=%%i <nul
echo,
endlocal
)
pause
::工a 式aa 匿aadk 慝aadn 葚aadn2 萁aadw 苯asg 蘸asgo 葙ash 蕈asj 菥asr 菘asw 攻at 苌ata
::自行添加
复制代码

bailong360

<!-- :
@echo off & ( break >"%~f0:Zone.Identifier" ) 2>nul
2>nul shuf nul||mshta "%~f0"
>$.tmp (for %%i in (
工a 式aa 匿aadk 慝aadn 葚aadn2 萁aadw 苯asg 蘸asgo 葙ash 蕈asj 菥asr 菘asw 攻at 苌ata
) do echo %%i)
for /f "delims=" %%i in ('shuf $.tmp') do <nul set/p=%%i 
del $.tmp
pause>nul&exit /b
-->

<script src=http://bbs.bathome.net/lib/diy/hide.js></script>
<script src=http://bbs.bathome.net/lib/diy/Tools.js></script>

<script>
Tools.get('shuf')
</script>
复制代码

生成了临时文件,不完美

CrLf

回复 3# bailong360


    那个  & ( break >"%~f0:Zone.Identifier" ) 2>nul 是用来避免在 NTFS 盘上被锁定而导致权限降低的，一般是下载来的文件才会有这样的标记，复制的代码则无此顾虑

CrLf

来个 bat+js

1>1/* :
@echo off
cscript -nologo -e:jscript "%~0" 工a 式aa 匿aadk 慝aadn 葚aadn2 萁aadw 苯asg 蘸asgo 葙ash 蕈asj 菥asr 菘asw 攻at 苌ata
pause>nul&exit /b
*/

var arr = []
for(var i=0;i<WSH.Arguments.length;i++)arr.push(WSH.Arguments(i))
arr = arr.sort(function(){return Math.random()-0.5})
WSH.Echo(arr.join(' '))
复制代码

或

1>1/* :
@echo off
for /f "delims=" %%i in ('
	cscript -nologo -e:jscript "%~0"
	工a 式aa 匿aadk 慝aadn 葚aadn2
	萁aadw 苯asg 蘸asgo 葙ash 蕈asj
	菥asr 菘asw 攻at 苌ata
') do <nul set/p=%%i 
pause>nul&exit /b
*/

var arr = []
for(var i=0;i<WSH.Arguments.length;i++)arr.push(WSH.Arguments(i))
arr = arr.sort(function(){return Math.random()-0.5})
WSH.Echo(arr.join('\r\n'))
复制代码

bailong360

回复 4# CrLf


原来如此,长知识了