[文本处理] [已解决]批处理用echo写入文本出现问题

LTSC1809

我做了个某游戏启动器，其中如果bat所在的文件夹下没有YSFI.ldt这个文件那么他会自动搜索文件路径，然后让你输入一些内容最后把这些内容全部写入到一个文本中，但是现在发现生成的文件是空白的，我把那个echo %yscon%>%cd%\YSFI.ldt那行的%yscon%加上双引号变成"%yscon%"，这次文件不是空白了，但是内容被双引号包裹了，我希望去掉双引号又能把内容写入进去，谢谢，代码如下：

@echo off
:mks
title Hello Genshin! Lancher-The First Edition
color F0
echo Hello Genshin! Lancher 第一版
echo.
if not exist %cd%\YSFI.ldt goto FYF
for /f "delims=; tokens=1" %%i in (%cd%\YSFI.ldt) do set ysfivr=%%i
for /f "delims=; tokens=2" %%n in (%cd%\YSFI.ldt) do set to=%%n
for /f "delims=; tokens=3" %%m in (%cd%\YSFI.ldt) do set wait=%%m
:star
echo 键入"star"并回车来启动游戏;输入"help"来获取帮助以及更多指令操作：
set /p star=^>
if %star% equ fi echo %ysfivr%
if %star% equ find goto FYFzy
if %star% equ help goto help
if %star% equ down start https://ys.mihoyo.com/
if %star% equ star goto startys 
echo 无效输入
pause
goto star
:startys
echo 正在启动游戏:
echo 运行：游戏exe主文件【%ysfivr%】
"%ysfivr%"
echo 游戏已退出或启动失败
pause
exit
:FYFzy
echo 这将花费几分钟的时间并且将会清空原本的YSFI.ldt，你确定要搜索文件吗？
set /p yn=（Y/N）:
if %yn% equ Y goto FYF
cls
goto mks
:FYF
echo 正在搜索游戏主文件...
set "FileName=YuanShen.exe"
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
if /i "%%~nxb" equ "%FileName%" (
set YSFIV=%%b
set a=1
)
)
)
)
if not defined a (echo 未找到游戏路径，请自行下载。
echo 官网：
echo https://ys.mihoyo.com/
echo 三秒后自动为你打开
timeout 3
start https://ys.mihoyo.com/
pause
exit)
echo 找到文件:
echo %YSFIV%
echo 配置文件被清空，需要写入：
echo ●启动超时的指定时间
set /p tio=请输入-我们不建议您输入4以下的数字，这很有可能造成误判（单位为秒）:
echo ●游戏退出检测间隔时间
set /p waitt=请输入-较高的值有助于快速反应，但是这会造成更高的性能开销（单位为秒）:
echo ●游戏文件的路径
set yscon=%YSFIV%;%tio%;%waitt%
echo %yscon%>%cd%\YSFI.ldt
echo 配置文件 已经保存成功
echo 请重启启动器...
pause
exit
:help
cls
echo ===帮助部分===
echo 这个启动器还在开发中，bug巨多，还请谅解呢qwq
echo 如果启动时报毒，那就是因为米哈游的谜之反作弊组件，不用管，点允许就行
echo ===命令===
echo down-帮你用浏览器打开原神官网
echo fi-显示游戏主文件路径
echo find-重新搜索游戏
goto mks
复制代码

BingjianREMIX

回复 1# LTSC1809


    >%cd%\YSFI.ldt echo %yscon%

Batcher

回复 1# LTSC1809


第65行改成这样试试：

>"%cd%\YSFI.ldt" echo,%yscon%
复制代码

LTSC1809

已经解决，感谢大家的支持