[文件操作] [已解决]批处理怎么查询全盘内的mp3文件呢？详情内询。

慕夜蓝化

之前写的使用dir查询全盘内的文件代码
如下：
code1

@echo off
set "num=0"
set "str=c d e f g h i j k l m n o p q r s t u v w x y z"
for %%i in (%str%) do (
        if exist %%i: for /f "delims=" %%a in ('dir /s/b/l/aa-s-h-r/on %%i:\*mp3') do (
    set /a num=num+1
    )
)
echo 全盘mp3总数量为：%num%
pause
复制代码

>_< 可是这个真的很慢 .
然后就想 因为 for /r 比较快嘛
那就用for /r 来代替dir吧
于是：
code2

@echo off
set "n=0"
set "dri=c d e f g h i j k l m n o p q r s t u v w x y z"
for %%i in (%dri%) do (
    if exist %%i: for /r %%i: %%a in (*mp3) do (
        set /a n=n+1
    )
)
echo  全盘mp3总数量为：%n%
pause
复制代码

= =
窗口一闪就没了。。。

然后改：
code3

@echo off
setlocal enabledelayedexpansion
set "n=0"
set "dri=c d e f g h i j k l m n o p q r s t u v w x y z"
for %%i in (%dri%) do (
    set "sri=%%i:"
    if exist !sri! for /r !sri! %%a in (*mp3) do (
        set /a n=n+1
        echo %%~xa
    )
)
echo !n!
pause
复制代码

echo %%~xa 检验是否通过
、 还是不行啊 .
然后就找问题，组合代码的都分开来，用echo 来显示是否通过。
最后发现问题 出在了 for /r 那里
便截取for /r 那段代码单独实验
= =可以用啊。。。
加上变量也能用啊

@echo off
set "n=0"
set "dri=d:"
for /r %dri% %%i in (*mp3) do set /a n+=1
echo %n%
pause
复制代码

。。。
到这时候 已经考虑到了 是不是 for /r 后面的 !sri! 出了问题
然后 干脆拿掉 !sri!
好了= =
最起码找到了问题
最后 又把 !sri! 替换为指定的盘符。
结果也如实根据卷的多少以及当前卷下文件的数量显示了相应的数字。
现在只想快些知道，到底哪里出现了问题，为什么for /r 后面的变量没有被引用？
应该怎么改呢？
还有第二段代码又出现了什么问题？
求解！拜托了。

DAIC

@echo off
set "n=0"
set "dri=c d e f g h i j k l m n o p q r s t u v w x y z"
for %%i in (%dri%) do (
    if exist %%i: (
        pushd %%i:\
        for /r %%a in (*.mp3) do (
            set /a n+=1
        )
        popd
    )
)
echo 全盘mp3总数量为：%n%
pause
复制代码

CYUYAN09

@echo off
setlocal enabledelayedexpansion
set "n=0"
set dri=D
for %%i in (%dri%) do (
        if exist %%i: for /r D: %%a in (*.mp3) do (
                echo %%a
                set /a n+=1
        )
)
echo  全盘mp3总数量为：%n%
pause
这个就能过滤出来。但是换成%%i就不行了。我感觉是语法问题，这个正在查找中....

apang

可以考虑用临时文件方案，大概也许差不多会快一点

@echo off
set "dri=c d e f g h i j k l m n o p q r s t u v w x y z"
(for %%i in (%dri%) do (
        if exist %%i:\ dir /a-d /b /s %%i:\*.mp3
))>$
for /f %%a in ('find /c /v ""^<$') do set "n=%%a"
echo 全盘mp3总数量为：%n%
pause
复制代码

CYUYAN09

回复 2# DAIC


   您好，没看懂你的 pushd作用是什么啊？能解释一下吗？

DAIC

回复 5# CYUYAN09


可以先查看一下帮助信息：
pushd /?

慕夜蓝化

回复 2# DAIC


    窗口一闪就没了 = =
不过，通过这个想法，我改了一下，那就是通过pushd 或者 cd /d 跳转的办法 。
不需要在for /r 后面添加任何驱动器号或者路径。
code
@echo off
set "n=0"
set "dri=c d e f g h i j k l m n o p q r s t u v w x y z"
for %%i in (%dri%) do (
    if exist %%i: pushd %%i:
        for /r %%a in (*mp3) do (
    set n+=1
    echo %%a >>mp3flie.txt
   )
)
echo 全盘mp3总数为：%n%
pause
相比较于dir好了不止一点半点。而且硬盘全程无杂音，很好用。
只不过，因为无法设置查询的文件属性，导致列出的文件比dir多了不少。

慕夜蓝化

回复 4# apang


    嗯嗯，真的很棒，看了一下代码，果然很厉害 ；
我曾经使用dir /s/b/l/aa-s-h-r/on d:\*mp3|find /v /c "" 来获得当前路径下的mp3文件数量，
但一直不知道该怎么应用在for语句中使其作用于其他盘符并显示总文件数量。
这样一来就可以解决问题啦
而且使用起来也特别流畅。~~~(>_<)~~~ 赞赞赞！！！

慕夜蓝化

回复 3# CYUYAN09

恩，就是这样，虽然通过其他方案可以解决问题，但总是解决不了这个为什么无法运行的话，就像个疙瘩一样- -
希望早些弄明白是怎么回事。

CYUYAN09

回复 2# DAIC


    您好，您这个好像运行不了啊

DAIC

回复 10# CYUYAN09


    代码已经更新，你再试试。

shelluserwlb

全盘查找mp3文件。 查找完成后生成mp3文件清单。

@echo off
set "n=0"
set "dri=c d e f g h i j k l m n o p q r s t u v w x y z"
if exist mp3flie.txt del mp3flie.txt

echo 正在查找mp3文件，请稍候...
for %%i in (%dri%) do (
    if exist %%i: call :1 %%i
)
echo 全盘mp3总数量为：%n%
pause
goto :eof

:1
for /r %1: %%a in ("*.mp3") do (
    set /a n+=1
    echo %%a >>mp3flie.txt
)
goto :eof
复制代码

DAIC

回复 12# shelluserwlb

优化第一步：

@echo off
set "n=0"
set "dri=c d e f g h i j k l m n o p q r s t u v w x y z"
if exist mp3flie.txt del mp3flie.txt

echo 正在查找mp3文件，请稍候...
for %%i in (%dri%) do (
    if exist %%i: call :1 %%i
)
echo 全盘mp3总数量为：%n%
pause
goto :eof

:1
REM 把重定向放到for循环外面可以提高代码执行效率
(for /r %1: %%a in ("*.mp3") do (
    set /a n+=1
    echo %%a
))>>mp3flie.txt
goto :eof
复制代码

优化第二步：

@echo off
set "n=0"
set "dri=c d e f g h i j k l m n o p q r s t u v w x y z"
REM 由于在最外层for循环外面做重定向，下面这个判断可以省略
REM if exist mp3flie.txt del mp3flie.txt

echo 正在查找mp3文件，请稍候...
REM 把重定向尽可能的往外移
(for %%i in (%dri%) do (
    if exist %%i: call :1 %%i
))>mp3flie.txt
echo 全盘mp3总数量为：%n%
pause
goto :eof

:1
for /r %1: %%a in ("*.mp3") do (
    set /a n+=1
    echo %%a
)
goto :eof
复制代码

优化第三步：

@echo off
set "n=0"
set "dri=c d e f g h i j k l m n o p q r s t u v w x y z"
REM 由于在最外层for循环外面做重定向，下面这个判断可以省略
REM if exist mp3flie.txt del mp3flie.txt

echo 正在查找mp3文件，请稍候...
REM 把重定向尽可能的往外移
(for %%i in (%dri%) do (
    if exist %%i: call :1 %%i
))>mp3flie.txt

for /f %%i in ('type mp3flie.txt^|find /c /v ""') do (
    set "RowNum=%%i"
)
echo,%RowNum%
echo 全盘mp3总数量为：%RowNum%
pause
goto :eof

:1
for /r %1: %%a in ("*.mp3") do (
    REM 假设总共有十万个mp3文件，那么就要做十万次计算，可以把它拿到for循环外面去
    REM set /a n+=1
    echo %%a
)
goto :eof
复制代码

ygqiang

回复 13# DAIC


    你的最后第3个这个优化代码。
与下面这个对比。

为啥下面的多出来1个mp3文件？

@echo off
set "dri=c d e f g h i j k l m n o p q r s t u v w x y z"
(for %%i in (%dri%) do (
        if exist %%i:\ dir /a-d /b /s %%i:\*.mp3
))>$.txt
for /f %%a in ('find /c /v ""^<$.txt') do set "n=%%a"
echo 全盘mp3总数量为：%n%
pause
复制代码

DAIC

回复 14# ygqiang


    你分别打开两个txt文件，看看到底是多少个吧。