【练习-046】批处理逆转整数二进制位的顺序

lhjoanna

目的：练习批处理的位操作
要求：1、输入一个整数value，编程实现把value的二进制位模式从左到右变换。
           2、程序不依赖于你的机器上整数的字长，具有可移植性。
举例：输入25，在32位机器上，二进制位:00000000000000000000000000011001，编程使之变成-1744830464，
          二进制为:10011000000000000000000000000000。
加分：完成要求一，加五分；两个都完成，加十分。

[ 本帖最后由 lhjoanna 于 2009-4-26 18:17 编辑 ]

随风

用位运算来解决,?一点思路都没有...

lhjoanna

呵，就是把整数的二进制位按逆序重排一遍，就是要用到 <<  >>  &   |   这几个运算符了。

batman

先来个非位运算的：

@echo off&setlocal enabledelayedexpansion
set /p var=请输入一个整数：
if %var% lss 0 set "-=a"&set "var=%var:~1%"
for /l %%a in (1,1,32) do (
    if !var! geq 1 (
       set /a yu=var%%2,var/=2
       if defined - set /a yu=1-yu
       set "num=!num!!yu!"
       ) else (
       set "num=!num!0"
    )
)
echo %num%
pause>nul
复制代码

[ 本帖最后由 batman 于 2009-4-27 00:19 编辑 ]

netbenton

@echo off&setlocal enabledelayedexpansion
:lp
(set n=
set o=
set s=
set ns=
echo.
set /p n=输入一个整数：)
(if "%n%"=="" goto :eof
for /l %%a in (1,1,32) do (
        set/a m=n%%2,n=n^>^>1
        set s=!s!!m:~-1!
        set o=!m:~-1!!o!
        set/a ns=^(ns^<^<1^)+m
)
echo 正二进制：!o!   {%n%}
echo 逆转输出：!s!   {!ns!}
goto :lp)
复制代码

[ 本帖最后由 netbenton 于 2009-4-27 00:36 编辑 ]

netbenton

要求二，应该也要定个位数吧，要么64,要么128,
不然，又怎么逆转呢？

lhjoanna

Re：netbenton
这就体现出程序的可移植性了，在你不知道程序将在何种机器上运行的时候，如何能使之适应不同的机器？望兄继续斟酌！

batman

再来，还是非位运算版的：

@echo off&setlocal enabledelayedexpansion
set /a n=1
:lp
set /a n*=2,we+=1
if %n% neq 0 goto lp
set /p var=请输入整数：
if %var% lss 0 set "-=1"&set "var=%var:~1%"
for /l %%a in (1,1,%we%) do (
    if !var! geq 1 (
       set /a yu=var%%2,var/=2
       if defined - set /a yu=1-yu
       set "num=!num!!yu!"
       ) else (
       set "num=!num!0%-%"
    )
)
if defined - call :loop
echo %str%%num%
pause>nul&goto :eof
:loop
set "a=%num:~,1%"
set /a a+=1&if !a! equ 2 set /a a=0
set "str=!a!%str%"&set "num=%num:~1%"
if %a% equ 0 goto loop
复制代码

lhjoanna

在batman的代码中，可移植性体现在事先求得目标机器的位数，这是一种思路，但毕竟影响了程序一定的效率。如何能在尽量不影响程序效率的前提下同时实现两个要求是要考虑的问题。
    提示：采用位操作很高效，在移位的同时隐含机器位数的判断。

pusofalse

发个以前写的，感觉复杂了好多，只是转2进制

@Echo Off
Set /p num=Input:
Call :ToBinary %num% sBinaryString
Echo %sBinaryString%
Pause & Exit /b

:ToBinary numeric, ByRef sBinaryString
SetLocal ENABLEEXTENSIONS
Set "sResult="
Set /a iTopBit = 0, iUnsignedNumber = %~1 "&" 0x7FFFFFFF
If %~1 lss 0 (set /a iTopBit = 1)
If %~1 gtr 0x7fffffff (set /a iTopBit = 1)

:LoopToBinary ###INTERNAL-USED-ONLY###
Set /a iTempNum = iUnsignedNumber "&" 1, iUnsignedNumber ">>=" 1
Set "sResult=%iTempNum%%sResult%"
If %iUnsignedNumber% gtr 0 (goto :LoopToBinary)
EndLocal & Set "%2=%iTopBit%%sResult%" & Exit /b 0
复制代码

[ 本帖最后由 pusofalse 于 2009-4-27 09:49 编辑 ]

lhjoanna

Re：Pusofalse
         兄的代码还可再精简，在正数时输出最好补全后面的0，负数时忘记逆转了吧?

zqz0012005

@echo off
set num=25
set /p "num=Input:\>"
:lp
set /a "bit = num >> n & 1"
set binary=%bit%%binary%
set reverse=%reverse%%bit%
set /a "num2 = num2 << 1 | bit"
set /a "n += 1", "check = 1<<n"
if %check% neq 0 goto lp
echo num	:	%num%
echo binary	:	%binary%
echo reverse	:	%reverse%
echo decimal	:	%num2%
pause
复制代码

不知道怎样才能不涉及对字长的判断。

lhjoanna

Re:zqz
     呵，兄已经完成了两个要求，此句 if %check% neq 0 goto lp  保证只要%check%不为0就继续循环，这就使循环的次数与机器的字长无关！

[ 本帖最后由 lhjoanna 于 2009-4-27 12:01 编辑 ]

zqz0012005

感觉这样还是与字长有关啊（虽然没有直接使用字长，但还是要判断的）。我是想，如果不考虑写出数字的二进制形式，能不能通过较为简单的方法（不要goto循环），几步就能得出逆转结果。

又觉得，位运算应该必然与字长有关吧。

[ 本帖最后由 zqz0012005 于 2009-4-27 12:15 编辑 ]

lhjoanna

对于具体的某台机器，当然会与字长有关。机器的字长不同，那么逆转后的结果就不同。这也就是采用goto而不是for的原因，这也是兼顾效率与可移植性的方案。
    不知兄所说的不用二进制位几步就可以得出的是什么方法，有什么思路?我觉得位运算已经是几步就可以逆转，当然是要进行循环的。

@echo off
 set /p "value=INPUT:"
 set /a i=1,answer=0
:begin
 set /a "answer<<=1,b=value&1"
 set /a "answer|=b,value>>=1,i<<=1"&set "binary=%binary%%b%"
 if %i% neq 0 goto begin
 echo Decimal:%answer% &echo Binary :%binary%
 pause>nul
复制代码